Réaliser une somme de personne

Bonjour,

Je fais partie d’une association qui est ouverte une fois par semaine. J’ai une liste de membres (environ 200 personnes).

Je note les présences chaque semaine de qui est venu et je voudrais faire la somme du nombre de personnes ayant fréquenté l’association au moins une fois dans le mois.

Ci-joint, une feuille Excel réalisant ce que je veux, mais je passe par une colonne intermédiaire ce que je voudrais éviter. Même si la colonne peut être facilement masquée.

Cordialement,

Merci

Bonjour,

Peut être avec sommeprod en sélectionnant toute la plage de cellules concernées par les présences

Quelque chose comme ça:

=SOMMEPROD((B6:E10=1)*1)

ou plus abordable avec NB.SI

=NB.SI(B6:E10;1)

cordialement

ddetp88

Bonjour, ddetp88 ,sebou66

une méthode à tester avec un double-clic qui insère le chiffre 1

les formules des totaux, sont toutes simples

Amicalement

Pierrot

Merci ddetp88 et pierrot,

Mais j'ai du mal m'expliquer.

pour répondre à pierrot:

la ligne 4 correspond aux jours du mois donc le 4 janvier, le 11 janvier etc...

Sinon je ne cherche pas à écrire 1 lors d'un double click et encore moins utiliser des macros.

Sinon je ne veux pas trouver 8 avec

=SOMMEPROD((B6:E10=1)*1) (Solution ddetp88)

ou

=NB.SI(B6:E10;1) (Solution ddetp88)

ou même

=SOMME(F6:F25) (Solution pierrot)

Car, je ne cherche pas à faire la somme des totaux par semaine, c'est à dire pour janvier, je ne veux pas obtenir 8 mais 4

mais je veux faire 1+1+1+1+0

je m'explique :

Marcel est venu 2 fois ca vaut 1

Julien est venu 1 fois ca vaut 1

Laurent est venu 1 fois ca vaut 1

Matthieur est venu 4 fois ca vaut 1

et François n'est pas venu en janvier donc ca vaut 0.

Avec cette méthode, je sais que sur mes 5 membres 4 sont venus dans le mois de Janvier et 3 en février etc..

Dans la vrai version, j'ai plus de 200 noms. Donc plus long.

Je ne sais pas si quelqu'un pourra m'apporter une solution autre que celle que j'ai proposer à savoir l'ajout d'une colonne F supplémentaire que je masque pour la visibilité

Bonjour,

Je n'avais pas tout compris.

En tout cas si les colonnes F et K peuvent rester, la formule qui pourrait apporter la solution à ton problème est:

=SI(NBVAL(B6:E6)>=1;1;0)

Tiens nous au courant

ddetp

Bonjour

J'ai nommé Noms la formule

=DECALER(Feuil1!$A$6;;;NBVAL(Feuil1!$A$6:$A$300))

Qui représente la plagedes noms en colonne A

Formule en B3 à copier-coller sur les autres mois

=SOMMEPROD(N(NB.SI(DECALER(B$5:E$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0))

Cordialement

Merci à tous.

Merci à Amadéus.

C'est exactement ce que je veux faire.

Je ne savais pas qu'on pouvait rajouter ses propres fonctions dans Excel et j'aurais jamais trouvé la formule que vous m'avez sortis.

J'arrive en gros à la comprendre, je vais sans doute faire plusieurs exercices employant ses fonctions.

En tout c'est parfait.

PS: Toujours plus

Est-il possible facilement de créer une formule presence qui prendrait en paramètre B$5:E$5.

Du coup au lieu chaque mois d'avoir =SOMMEPROD(N(NB.SI(DECALER(B$5:E$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0))

avoir =presence(B$5:E$5).

C'est juste un petit bonus

Bonjour

pourquoi

=presence(B$5:E$5) ? Cela ira pour janvier, mais pas sur février.

=Presence serait plus approprié

Exemple et explication dans la zone de texte Rose

Cordialement

Bonjour,

Pour m'expliquer,

le presence(B$5:E$5) ou B$5:E$5 est l'étendue de là où on veut faire la somme

donc pour février on aurait bien-sur =presence(G$5:J$5).

Sinon je ne comprend comment ca marche.

Car si je mets cette formule en G3

=SOMMEPROD(N(NB.SI(DECALER(Feuil1!B$5:E$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0))

Ca me donne le résultat de Janvier.

Alors qui si je mets =SOMMEPROD(N(NB.SI(DECALER(Feuil1!G$5:J$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0)) dans Presence

et en G3 je mets =Presence ca me donne le résultat de février, pourtant la formule n'a pas changé.

Autre soucis, en Mars j'ai 5 dimanches et donc il me prend la somme que des 4 premiers avec =Presence mais si je mets

=SOMMEPROD(N(NB.SI(DECALER(Feuil1!L$5:P$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0))

Alors peut être je me fais de fonction Presence, et Presence2 ou la deuxième marchera pour quand il y a 5 dimanche.

Il n'y aurait pas moyen de récupérer direcment l'étendue de la où on fait la somme,

c'est à dire si je mets =Presence en G3, la formulaire sait que G3 est fusionner jusqu'à J3 et se servir de ca pour les calculs.

Alors peut être que je cherche trop compliquer et =Presence et =Presence2 me suffirai.

Merci en tout cas pour toutes vos réponses

Bonjour

On peut trouver plein de solutions à ce problème.

La plus simple, si tu as toujours une colonne vide entre tes mois, c'est d'élargir sur 5 colonnes dans la formule qui devient pour Presence:

=SOMMEPROD(N(NB.SI(DECALER(Feuil1!B$5:F$5;LIGNE(INDIRECT("1:"&NBVAL(Noms)));;1;);">"&0)>0))

et qui répond dans tous les cas avec 4 ou 5 colonnes.

Cordialement

Bonjour,

Je vais sans doute faire comme ça.

Je vais mettre tous les mois à 5 colonnes.

Comme d'une année sur l'autre les mois à 5 dimanches ne sont pas forcément les mêmes.

Ca permettra de rester facilement adaptable d'une année sur l'autre.

Dommage qu'on puisse pas noter les réponses car la, je mettrai un 30/20

Merci et bonne continuation