Pivottable avec un fichier correct

Bonjour,

J'aimerais faire changer le champ date de mon pivottable en fonction d'une cellule dans lequel l'utilisateur introduit une date ...

James 007 m'a déjà aidé ce matin mais le fichier que je joignais ne permettait pas de faire grand chose ... Je l'ai donc adapté pour plus de realisme. Quelqu'un peut jeter un oeil ?

La macro utilisée :

Sub Macro2()

'

' Macro2 Macro

'

Dim requesteddate As Date

requesteddate = Sheets("Sheet1").Range("C2")

'

ActiveSheet.PivotTables("PivotTable1").PivotFields("date").CurrentPage = _

"(All)"

With ActiveSheet.PivotTables("PivotTable1").PivotFields("date")

.PivotItems("requeteddate").Visible = True .PivotItems("requesteddate - 1 ").Visible = True

End With

End Sub

Personne ? Pourtant je vous assure je peux pas faire plus clair ... Et apparemment c'est vraiment facile ...

Je renonce Je demanderai aux utilisateurs de sélectionner la date et puis c'est tout

Merci quand même le forum et bonne journéééééééééééééééé !!!

A très vite ( a ne pas en douter :p )

Bonsoir,

Voir fichier.

On ne peut pas (je ne sais pas) filtrer dans un champ de page.

A te relire.

Cdlt.

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim dStart As Date, dEnd As Date
Dim pt As PivotTable

    If Not Intersect(Target, [C2]) Is Nothing Then
        If Target.Count > 1 Then Exit Sub
        If Not IsDate(Target) Then Exit Sub
        Application.ScreenUpdating = False
        dStart = Target.Value - 2: dEnd = Target.Value
        Set pt = Worksheets("Sheet4").PivotTables(1)
        With pt
            .ClearAllFilters
            .RefreshTable
            .PivotFields("date").EnableItemSelection = True
            .ManualUpdate = True
            .PivotFields("Date").PivotFilters.Add _
                    Type:=xlDateBetween, _
                    Value1:=CStr(dStart), _
                    Value2:=CStr(dEnd)
            .ManualUpdate = False
        End With
    End If

    MsgBox "le TCD a été actualisé.", vbInformation

    Set pt = Nothing

End Sub

Salut,

J'avais classé le sujet et renoncé et n'avais pas vu ta réponse ! Je viens de tester ton code et ça marche très bien !

Un très grand merci les utilisateurs ne vont plus devoir changer manuellement les dates

Super !!!

Bonjour,

Mieux mieux tard que jamais.

Merci.