Copier une liste de MP3 dans une feuille Excel

Bonjour à toutes et tous,

J'ai, dans un dossier, des MP3 et dans un autre des MP4, je voudrais importer dans une feuille Excel la liste des MP3 et dans une autre la liste des MP4.

J'ai sélection tous les MP3, fait copier et dans une feuille Excel j'ai voulu faire coller mais cette possibilité est grisé.

Avez vous une solution ?

Etant donné que la liste est très grande, je ne voudrais pas la faire à la main dans Excel.

Merci de vos prochaines réponses

Bien cordialement à vous

bonjour

ci joint un module qui me satisfait

Option Explicit

Sub Lister_Fichiers()
    Dim Fichier As String, Chemin As String
    '
   'Nécessite d'activer la référence "Microsoft Scripting RunTime"
   '
   Dim Fso As Scripting.FileSystemObject
    Dim FileItem As Scripting.File
    Dim Tableau()
    Dim Plage As Range
    Dim m As Integer, i As Integer
    Dim z As Byte, Valeur As Byte
    Dim Cible As Variant

    '---liste les fichiers du répertoire ---
   Chemin = "E:\Driver Windows 8" 'à changer
   Fichier = Dir(Chemin & "\*.exe") ' à changer selon le besoin

    'Boucle sur les fichiers
   Do

        m = m + 1
        ReDim Preserve Tableau(1 To 2, 1 To m)
        Tableau(1, m) = Fichier

        Set Fso = CreateObject("Scripting.FileSystemObject")
        Set FileItem = Fso.GetFile(Chemin & "\" & Fichier)

        'Récupère la date de création
       Tableau(2, m) = Left(FileItem.DateCreated, 10)
        'Pour récupérer la date de dernière modification
       'Tableau(2, m) = Left(FileItem.DateLastModified, 10)
       'Pour récupérer la taille du fichier
       'Tableau(2, m) = Left(FileItem.Size, 10)

        Fichier = Dir
    Loop Until Fichier = ""

    '---Trie les fichiers par ordre décroissant de création ---
   Do
        Valeur = 0
        For i = 1 To m - 1
            If CDate(Tableau(2, i)) < CDate(Tableau(2, i + 1)) Then
                For z = 1 To 2
                    Cible = Tableau(z, i)
                    Tableau(z, i) = Tableau(z, i + 1)
                    Tableau(z, i + 1) = Cible
                Next z

                Valeur = 1
            End If
        Next i
    Loop While Valeur = 1

    '--- Transfère les données dans la feuille de calcul ---
   Set Plage = Worksheets("Feuil1").Range("A1")
    Set Plage = Plage.Resize(UBound(Tableau(), 2), UBound(Tableau()))
    Plage = Application.Transpose(Tableau())

End Sub

a changer dans la partie

 '---liste les fichiers du répertoire ---
   Chemin = "E:\Driver Windows 8" 'à changer
   Fichier = Dir(Chemin & "\*.exe") ' à changer selon le besoin

le chemin et l'extention voulu

a te relire

Bonsoir iliyes

Merci pour ce code, il fonctionne très bien et c'est tout ce dont j'avais besoin.

Maintenant, je vais l'étudier pour voir comment tout cela fonctionne, savoir le pourquoi du comment.

J'aime bien savoir pourquoi cela fonctionne plutôt que de m'en servir bêtement et comme ton code est très bien expliqué, cela va me faciliter la tache.

Cela fait un bon moment que j'étudie le VBA, et c'est pas facile en autodidacte mais je progresse et c'est le principal

Encore merci à toi