Prix moyen d'un article dans un tableau
Bonjour à tous,
Je cherche à résoudre un problème dans le fichier annexe. Dans le premier onglet, j'ai des achats, dans le deuxième du stock.
J'aimerais trouver pour l'article de stock (colonne B) avec la référence (colonne C) le prix moyen de l'article (colonne E) et le dernier prix (colonne F) en cherchant dans la base de donnée de l'onglet "achat".
Est-ce que l'un d'entre vous aurait une solution ? Merci beaucoup d'avance.
Salutations Fred
Bonsoir le forum,
C8 : =RECHERCHEV(B8;Achats!B5:C12;2;0)
E8 :
=SIERREUR(MOYENNE(SI(Achats!B5:B12=B8;Achats!E5:E12));"")Formule matricielle.
F8 :
=MAX(Achats!E5:E12*(Achats!B5:B12=B8))Formule matricielle.
mbbp
Pour la moyenne :
=MOYENNE.SI.ENS(Achats!E5:E12;Achats!B5:B12;Stock!B8;Achats!C5:C12;Stock!C8)Pour le max :
=(SOMMEPROD(MAX((Achats!B5:B12=Stock!B8)*(Achats!C5:C12=Stock!C8)*(Achats!E5:E12))))Re,
Les deux formules de moyennes présentées jusqu'à présent ne fonctionnent pas, bien que donnant la réponse attendue.
En effet il faudrait calculer une moyenne pondérée.
mbbp
Tu as raison ... alors ceci :
=SOMMEPROD((Achats!B5:B12=Stock!B8)*(Achats!C5:C12=Stock!C8)*Achats!D5:D12*Achats!E5:E12)/SOMMEPROD((Achats!B5:B12=Stock!B8)*(Achats!C5:C12=Stock!C8)*Achats!D5:D12)Re,
=SOMME(SI(Achats!B5:B12=B8;(Achats!D5:D12)*(Achats!E5:E12)))/SOMME(SI(Achats!B5:B12=B8;Achats!D5:D12;0))Formule matricielle.
mbbp
Bonsoir
Pour la moyenne pondérée
=SOMMEPROD((Achats!$B$5:$B$12=B8)*(Achats!$D$5:$D$12)*(Achats!$E$5:$E$12))/D8Amicalement
Nad
Fred74 a écrit :J'aimerais trouver pour l'article de stock (colonne B) avec la référence (colonne C) le prix moyen de l'article (colonne E) et le dernier prix (colonne F)
Et pour renseigner la cellule D8 : "Quantité" :
=SOMME.SI.ENS(Achats!D5:D12;Achats!B5:B12;B8;Achats!D5:D12;">0")mbbp
Re
Attention mbpp ! Le dernier prix n'est pas forcément le Max
Amicalement
Nad
Re,
Nad a écrit :Attention mbpp ! Le dernier prix n'est pas forcément le Max
Merci Nad pour cette bonne remarque.
F8 :
=INDEX(Achats!B5:E100;LIGNE(INDEX(Achats!A1:A100;SOMMEPROD(MAX((Achats!B1:B100=B8)*(LIGNE(Achats!A1:A100))))))-4;4)mbbp