Problème de saisie fonction VLOOKUP

Bonjour,

Je pense que j'écris mal la fonction VLOOKUP ci-dessous. J'ai un message "d'erreur d'éxecution 1004".

Je crois que cela vient des parenthèses et guillemets

Sub INSERTION()

Dim PR_DATE As Range 
Set PR_DATE = Sheets("FA").Range("B2:O11")

Dim NoLIGNE As Integer
For NoLIGNE = 2 To 100
Sheets("PR").Range("AC" & (NoLIGNE)).FormulaR1C1 = "=VLOOKUP(Sheets(""PR"").Range(""G"" & (NoLIGNE),PR_DATE,14,0)"
Sheets("PR").Range("AC" & (NoLIGNE)).FormulaR1C1 = Sheets("PR").Range("AC" & (NoLIGNE)).Value

Next
End Sub

En générant la macro, j'ai le code ci-dessous:

= "=VLOOKUP(PR!R[43]C[6],PR_DATE,14,0)"

Merci de la réponse que vous pourrez m'apporter.

Bonjour et bienvenu(e)

A tester

Sheets("PR").Range("AC" & NoLIGNE).Formula = "=VLOOKUP(PR!G" & NoLIGNE & ",FA!" & PR_DATE.Address & ",14,0)"

En simplifiant tu peux avoir

Sheets("PR").Range("AC" & NoLIGNE).Formula = "=VLOOKUP(G" & NoLIGNE & ",FA!" & PR_DATE.Address & ",14,0)"

Et en simplifiant beaucoup (si j'ai compris ce que tu veux faire)

Sub INSERTION()
  With Range("AC2:AC" & Range("G" & Rows.Count).End(xlUp).Row)
    .Formula = "=VLOOKUP(G2,FA!$B$2:$O$11,14,0)"
    .Value = .Value
  End With
End Sub

Bonjour,

Le test fonctionne.

Le code simplifié fonctionne

Merci beaucoup.