Remplir une cellule en fonction de la date

Bonjour,

Jai besoin d aide pour mon fichier ci-joint, en cas de besoin mot de passe "orodis"

En Feuil1

1) Livraison

2) choix de la ville par exemple "S"

3) choix type de bouteille par exemple B12

4) entre le nombre livré par 10

5) ok

6) dans "Feuil1" on voit apparaitre 10 en S colonne B12 7) Dans "Feuil2) en fonction da la date du jour, on verra aussi apparaitre 10 en B12

Maintenant dans ma macro, je change "Feuil2" par "S"

je voudrais lorsque je remplis ma livraison, comme on a fait pour "Feuil2", voir apparaitre le nombre que je rentre dans la ville "S" en fonction de la date du jour et dans la collonne souhaitée par emple en B12

j'ai testé et j'obtiens " une erreur d'incompabilité 13" sur cette ligne :

With Sheets("S")

Ligne = Application.Match(Date * 1, .[A:A], 0)

Merci par avance pour votre aide.

Bonjour

Avec Match il faut (dans la majorité des cas) tester le résultat, comme dans la fonction EQUIV()

Et la variable de retour peut soit retourner un nombre ou un message d'erreur il faut la typer en Variant (type par défaut)

Testes cette macro

Private Sub cbOK_Click()
Dim Ligne

  If Me.ComboBox1.Value = "" Then
    MsgBox "Choisissez un nom de client"
    Exit Sub
  End If

  With Sheets("Feuil1")
  Ligne = Application.Match(Me.ComboBox1.Value, .[A:A], 0)
  If Not IsError(Ligne) Then
    If Me.chkbxB6 = True And Me.tbB6.Text <> "" And IsNumeric(Me.tbB6.Text) Then
      .Cells(Ligne, 2) = .Cells(Ligne, 2) + CInt(Me.tbB6)
    ElseIf Me.ChkBxB12 = True And Me.tbB12.Text <> "" And IsNumeric(Me.tbB12.Text) Then
      .Cells(Ligne, 3) = .Cells(Ligne, 3) + CInt(Me.tbB12)
    End If
  Else
    MsgBox "Ville " & Me.ComboBox1 & " non trouvée"
  End If
  End With
  With Sheets("S")
    Ligne = Application.Match(Date * 1, .[A:A], 0)
    If Not IsError(Ligne) Then
      If Me.tbB6 <> "" Then .Cells(Ligne, 3) = .Cells(Ligne, 3) + CInt(Me.tbB6)
      If Me.tbB12 <> "" Then .Cells(Ligne, 2) = .Cells(Ligne, 2) + CInt(Me.tbB12)
    Else
      MsgBox "Date " & Date & " non trouvée"
    End If
  End With
  Me.Hide
End Sub

Je ne sais comment te remercier, Ca marche parfaitement.

Ca faisait 3 nuits Blanche depuis, Enfin le couchemare prend fin. Je vais continuer mon apprentissage.

Merci bcp.