Extraction des données des feuilles diff vers une seul feuil

Bonjour,

Je voulais savoir d'après vos connaissance s'il y'a un programme pour extraire des données des feuilles différentes vers une seul feuil et les mettres l'un au dessous de l'autre.

Les données sont dans Classeur1, Classeur2, Classeur3 je voulais importer les données dans l'onglet 'Symboles' et la coller dans l'onglet 'Symboles' du classeur 'EE' comme j'ai fais dans l'exemple. Par contre je vais qu'il me colle les colonnes A, B, D et G

et les lignes sa peux varier de 10 à 100 lignes dans chaque classeur, pour l'instant j'en ai 25 classeurs.

Je voulais si possible une resultat comme dans le classeur 'EE'

Merci d'avance

Bonne journée

Bonjour,

un proposition de macro à tester

Sub importer()
Set wsee = Workbooks("EE.xls").Worksheets("Symboles")
chemin = wsee.Parent.Path ' par défaut, même répertoire que celui dans lequel se trouve le fichier EE.xls
f = Dir(chemin & "\" & "class*.xls")  ' on prend tous les fichiers qui correspondent au filtre class*.xls
While f <> "" ' tant qu'il y a des fichiers
Set wbi = Workbooks.Open(chemin & "\" & f) ' on ouvre le classeur
bonformat = True
On Error GoTo terreur
Set wsi = wbi.Worksheets("Symbole")
On Error GoTo 0
If bonformat Then 'si le fichier contient un onglet qui s'appelle symbole, on estime que le fichier a le format qui convient
dlee = wsee.Range("A" & Rows.Count).End(xlUp).Row + 1:  ' première ligne libre dans le fichier EE
dli = wsi.Range("A" & Rows.Count).End(xlUp).Row ' nombre de lignes dans le classeur en cours
wsi.Range("A2:B" & dli).Copy wsee.Range("A" & dlee) ' copie des colonnes A,B, D et G
wsi.Range("D2:D" & dli).Copy wsee.Range("C" & dlee)
wsi.Range("G2:G" & dli).Copy wsee.Range("D" & dlee)
End If
wbi.Close ' on ferme le classeur
f = Dir()
Wend

Exit Sub
terreur:
bonformat = False
Resume Next
End Sub

Bonjour,

Merci h2so4 ton programme marche très bien nickel

Bonne Journée

Bonjour,

Je viens d'essayer le programme avec un autre tableau ou il y'a des formules dans les cellules, ton programme me prend la formule et pas ce que marqué dans la cellule.

Il faut que je change quoi pour importer la valeur de la cellule et pas la formule??

merci d'avance

bonsoir,

Sub importer()
Set wsee = Workbooks("EE.xls").Worksheets("Symboles")
wsee.Activate
chemin = wsee.Parent.Path ' par défaut, même répertoire que celui dans lequel se trouve le fichier EE.xls
f = Dir(chemin & "\" & "class*.xls")  ' on prend tous les fichiers qui correspondent au filtre class*.xls
While f <> "" ' tant qu'il y a des fichiers
Set wbi = Workbooks.Open(chemin & "\" & f) ' on ouvre le classeur
bonformat = True
On Error GoTo terreur
Set wsi = wbi.Worksheets("Symbole")
On Error GoTo 0
If bonformat Then 'si le fichier contient un onglet qui s'appelle symbole, on estime que le fichier a le format qui convient
dlee = wsee.Range("A" & Rows.Count).End(xlUp).Row + 1:  ' première ligne libre dans le fichier EE
dli = wsi.Range("A" & Rows.Count).End(xlUp).Row ' nombre de lignes dans le classeur en cours
wsi.Range("A2:B" & dli).Copy
wsee.Range("A" & dlee).PasteSpecial Paste:=xlValues ' copie des colonnes A,B, D et G
wsi.Range("D2:D" & dli).Copy
wsee.Range("C" & dlee).PasteSpecial Paste:=xlValues
wsi.Range("G2:G" & dli).Copy
wsee.Range("D" & dlee).PasteSpecial Paste:=xlValues
End If
wbi.Close ' on ferme le classeur
f = Dir()
Wend

Exit Sub
terreur:
bonformat = False
Resume Next
End Sub