Rechercheh renvoyant plusieurs valeurs (calcul matriciel?)
Bonjour,
C'est mon premier message sur ce forum, je fais appel à votre aide car je n'arrive pas faire un rechercheh renvoyant plusieurs résultats. J'ai vu que c'était possible sur divers forums mais chaque fois que j'essaye d'adapter à mon cas, ça ne fonctionne pas! j'y ai passé maintenant plusieurs heures et je ne comprends pas! (ma difficulté vient que souvent les exemples sont donnés en colonnes alors que mon fichier est en lignes, ou vice-versa selon comme on interprète!)
Ci-joint vous trouverez le fichier Excel, j'en profite pour poser trois questions (1 question par onglet) relatives au calcul matriciel
Onglet 1: je voudrais faire un simple rechercheh renvoyant potentiellement plusieurs résultats
Onglet 2: je voudrais faire un rechercheh qui renvoie les résultats compris dans une fourchette
Onglet 3: je voudrais virer les blancs d'une table avec calcul matriciel
J'aimerais faire tout cela sans macro si possible, j'ai lu qu'on pouvait le faire mais je n'arrive pas à passer à la pratique.
Je remercie vivement ceux qui voudront bien m'aider en complétant mon fichier.
Merci beaucoup,
Thomas
bjr,
je crois avoir répondu à la question 1 et à la question 2, dans le fichier attaché.
AL
Bonsoir,
Formules matricielles à valider simultanément par CTRL + MAJ + ENTRE
Fichier :
Question 1 :
=SIERREUR(INDEX($7:$7;PETITE.VALEUR(SI($C$8:$AGS$8=$D$12;COLONNE($C$8:$AGS$8));LIGNE(A1)));"")Question 2 :
=SIERREUR(INDEX($7:$7;PETITE.VALEUR(SI(($C$8:$AGS$8>=$D$12)*($C$8:$AGS$8<=$D$13);COLONNE($C$8:$AGS$8));LIGNE(A1)));"")Question 3 :
=SIERREUR(INDEX($5:$5;PETITE.VALEUR(SI($D$5:$L$5<>"";COLONNE($D$5:$L$5));COLONNE(A1)));"")cdt.
Merci beaucoup à vous deux, c'est génial.
Je suis un peu frustré de pas tout à fait comprendre les formules, est-ce que vous pouvez m'expliquer vite faite comment celles-ci fonctionnent?
Si on prend la question 1 par exemple
=SIERREUR(INDEX($7:$7;PETITE.VALEUR(SI($C$8:$AGS$8=$D$12;COLONNE($C$8:$AGS$8));LIGNE(A1)));"")
Par exemple, que vient faire A1 dans la formule alors qu'il ne se passe rien en A1? à quoi sert le SIERREUR ici?
Comment s'interprète cette écriture: $7:$7 ?
Merci
Afin d'essayer de comprendre comment cela marche, dans l'onglet 3 du fichier ci-joint, j'ai essayé d'adapter pour afficher les résultats dans une colonne; mais ça ne marche pas, j'ai des zéros à la place des prénoms.
Qu'ai-je mal fait ?
Merci beaucoup,
Thomas
Bonjour,
Il faut mettre $5$5 dans la formule.
=SIERREUR(INDEX($5:$5;PETITE.VALEUR(SI($D$5:$L$5<>"";COLONNE($D$5:$L$5));LIGNE(A1)));"")
La fonction :
Sierreur(formule;valeur_si_erreur) : donc Sierreur(formule;"") : renverra une cellule vide si la formule contient une erreur
Index : on travaille sur la ligne 5 :
index($5:$5;;numéro_renvoyé) : par exemple index(5:5;;3) : renverra la troisieme valeur de la ligne 5
Ligne(A1) renvoie 1
Ligne(A2) renvoie 2
On l'utilise pour renvoyer la premiere valeur correspondante D5:L5<>""
Petite.valeur(ma_formule,ligne(A1)) : renvoie la premiere valeur qui répond à ma formule
cdt
Merci beaucoup Ketamacanna, j'ai tout compris grâce à toi!