Adapter une macro pour une autre feuille

Bonjour, je cherche a adapter cette petite macro pour qu'elle puisse afficher les occurences trouver sur une autre feuille.Je ne sais pas quoi changer pour "trouver sur la colonne H de la feuille ASS". Je fourni le fichier excel.

Sub MacroQte2() 'pouvoir afficher en C, le nombre d'occurrence de B , trouver dans la colonne H de la feuille ASS.
Dim Plage As Range
Dim Cel As Range

    If Range("C" & Rows.Count).End(xlUp).Row > 2 Then
      Range("C3:G" & Range("C" & Rows.Count).End(xlUp).Row).ClearContents 'effacement de colonne C
    End If
    On Error Resume Next                                         ' Au cas pas de cellules correspondantes
    Set Plage = Columns(2).SpecialCells(xlCellTypeConstants, 23) ' Récupère toutes les constantes
    On Error GoTo 0                                              ' On rétablit la gestion des erreurs
    If Not Plage Is Nothing Then                                 ' Des cellules ?
      For Each Cel In Plage                                      ' Oui alors pour chaque cellule
        If Cel.Row > 2 Then
          Cel.Offset(0, 1) = Application.CountIf(Columns("B"), "*" & Cel)
        End If
      Next Cel
    End If

End Sub

Merci.

Que dois-je modifier dans la macro pour que la recherche ce fasse sur une autre feuille, soit la feuille ASS, colonne H?

    Sub MacroQte2()  'afficher en C, le nombre d'occurrence de B , trouver dans la colonne H de la feuille ASS.
    Dim Plage As Range
    Dim Cel As Range

        If Range("C" & Rows.Count).End(xlUp).Row > 2 Then
          Range("C3:G" & Range("C" & Rows.Count).End(xlUp).Row).ClearContents 'effacement de colonne C
       End If
        On Error Resume Next                                         ' Au cas pas de cellules correspondantes
       Set Plage = Columns(2).SpecialCells(xlCellTypeConstants, 23) ' Récupère toutes les constantes
       On Error GoTo 0                                              ' On rétablit la gestion des erreurs
       If Not Plage Is Nothing Then                                 ' Des cellules ?
         For Each Cel In Plage                                      ' Oui alors pour chaque cellule
           If Cel.Row > 2 Then
              Cel.Offset(0, 1) = Application.CountIf(Columns("B"), "*" & Cel)
            End If
          Next Cel
        End If

    End Sub

Bonjour

Modifies la ligne suivante (non testé)

Set Plage = Sheets("ASS").Columns("G").SpecialCells(xlCellTypeConstants, 23)

Banzai, je me suis trompe, c'est plutot la colonne i qu'il faut. Par contre, ca ne marche pas, il dois y avoir autre chose que je n'ai pas saisi dans la macro. De plus, le resultat s'affiche sur la feuille "ASS" au lieu de "RAM" colonne C.

Je te renvoi mon fichier avec la correction que tu as suggerer.

Bonsoir à toi aussi

Je ne comprends pas

Tu recherches dans une colonne ( la I de la page ASS ) contenant du texte un nombre ( colonne B de la page RAM )

Oui, les nombres que je veux comptabilises sont a l'interieur du texte. J'ai voulu adapte la macroqte1 (Module UtilitaireAssembleur), qui fait pas mal le meme travail, pour faire la macroqte2 mais ca ne marche pas.

Bonsoir

Essayes cette macro

Sub MacroQte2() 'pouvoir afficher en C, le nombre d'occurrence de B , trouver dans la colonne i de la feuille ASS.
Dim Plage As Range
Dim J As Long

    If Range("C" & Rows.Count).End(xlUp).Row > 2 Then
      Range("C3:C" & Range("C" & Rows.Count).End(xlUp).Row).ClearContents 'effacement de colonne C
    End If
    With Sheets("ASS")
      Set Plage = .Range("I3:I" & .Range("I" & Rows.Count).End(xlUp).Row)
    End With
    With Range("C3:C" & Range("B" & Rows.Count).End(xlUp).Row)
      .NumberFormat = "General"
      .Formula = "=IF(B3="""","""",COUNTIF(ASS!" & Plage.Address & ",""*""&B3&""*""))"
      .Value = .Value
    End With
End Sub

comme d'habitude, ca marche!

Je ne comprend pas tres bien la macro, et surtout pourquoi je ne pouvais vraiment pas utiliser le format de l'autre macro. Je me suis encore plante

Merci pour ton aide, Banzai!