Faire coïncider 2 colonnes ?
Bonsoir à tous,
En faite je vais faire simple, j'ai 2 colonnes A & B et lorsque je rentre la valeur qui correspond à A dans C, je veux que ça m'affiche la valeur de B dans D.
Exemple (je rentre la valeur dans C1 et je veux que le résultat s'affiche dans D1), donc, si C1 égal A1, alors D1 égal B1.
=SI(C1=A1;B1;0)
Le soucis, c'est que je voudrais également que ça m'affiche les autres lignes des colonnes A & B.
Par exemple, (je rentre toujours la valeur dans C1 et je veux toujours que le résultat s'affiche dans D1), mais cette fois ci, si C1 égal A2, alors D1 égal B2.
=SI(C1=A2;B2;0) et ainsi de suite =SI(C1=A3;B3;0) jusqu'à =SI(C1=A55;B55;0)
Donc ma question est de savoir comment regrouper tout ça en une seule formule ?
Merci d'avance...
@+...
bonsoir
essaie la fonction recherchev, à mettre en D1 et à recopier vers le bas éventuellement
=recherchev(C1,$A$1:$B$55,2,0)Merci de vouloir m'aider, c'est cool
Par contre, j'ai essayé ta formule mais Excel me dit qu'elle contient des erreurs et comme je comprends pas grand chose, j'ai du mal à rectifier le tir
bonsoir,
sorryn j'ai été piégé par ma version UK, qui veut des "," là où la version FR veut des ";"
=RECHERCHEV(C1;$A$1:$B55;2;0)Franchement un grand merci à toi, ça doit bien faire 3 heures que je galère pour trouver une solution, et toi en 2 secondes tu solutionne mon problème.
Juste un dernier petit détail, je souhaiterais que lorsque qu'il n'y a rien d'inscrit dans C1, que se soit de même pour D1 ?
Parce que quand y a rien dans C1, ça m'écrit #N/A dans D1 ?
Encore merci pour ton aide précieuse...
utilise sierreur
=SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")Merci ça fonctionne nickel
Bonjour,
J'ai encore un service à vous demander.
Je voudrais garder cette même formule en ajoutant une condition :
=SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")
Exemple :
Si la valeur de C1 est inférieure ou égale à 10, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")
Mais si la valeur de C1 est supérieure à 10 mais inférieure ou égale à 20, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$E55;2;0);"")
Mais si la valeur de C1 est supérieure à 20 mais inférieure ou égale à 30, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$F55;2;0);"")
Mais si la valeur de C1 est supérieure à 30 mais inférieure ou égale à 40, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$G55;2;0);"")
Et ainsi de suite...
Donc comment faire pour retranscrire le tout dans une seule formule ?
Merci d'avance...
mickael.91 a écrit :Bonjour,
J'ai encore un service à vous demander.
Je voudrais garder cette même formule en ajoutant une condition :
=SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")
Exemple :
Si la valeur de C1 est inférieure ou égale à 10, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")
Mais si la valeur de C1 est supérieure à 10 mais inférieure ou égale à 20, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$E55;2;0);"")
Mais si la valeur de C1 est supérieure à 20 mais inférieure ou égale à 30, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$F55;2;0);"")
Mais si la valeur de C1 est supérieure à 30 mais inférieure ou égale à 40, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$G55;2;0);"")
Et ainsi de suite...
Donc comment faire pour retranscrire le tout dans une seule formule ?
Merci d'avance...
bonjour,
je ne suis pas sûr que ce que tu as formulé soit ce que tu attendes.
par exemple, pas de différence de résultat entre
Si la valeur de C1 est inférieure ou égale à 10, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$B55;2;0);"")
Mais si la valeur de C1 est supérieure à 10 mais inférieure ou égale à 20, alors D1 égale =SIERREUR(RECHERCHEV(C1;$A$1:$E55;2;0);"")
ni entre
Mais si la valeur de C1 est supérieure à 20 mais inférieure ou égale à 30, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$F55;2;0);"")
Mais si la valeur de C1 est supérieure à 30 mais inférieure ou égale à 40, alors D1 égale =SIERREUR(RECHERCHEV(C1;$E$1:$G55;2;0);"")
pourrais-tu nous reformuler en indiquant dans quelle colonne il faut chercher le critère et dans quelle colonne trouver la réponse ?
si c1<10, rechercher C1 en colonne A et afficher le contenu de la colonne B
si 10=<c1<20,recherche C1 en colonne A et .....
etc ...
Bonjour,
Je vais repartir de zéro, se sera plus simple.
J'ai fait des exemples pour que se soit un peu plus clair :
J'espère que je me ferais mieux comprendre
Encore merci pour ton aide h2so4
formule appliquée à l'exemple donné,
valeur à rechercher F2 en colonne A, selectionner la colonne à afficher en fonction de i2
à mettre en L2
=SIERREUR(RECHERCHEV(F2;$A$1:$D$55;2+ENT(I2/10);0);"")Merci merci, j'ai testé et la formule à l'air de très bien fonctionner
Par contre, au lieu de faire comme dans l'exemple 0 à 10, 10 à 20, 20 à 30 (colonne B,C & D)
Si je veux faire 0 à 60, 60 à 80, 80 à 100 que dois-je modifier dans la formule ?
bonsoir,
dans l'instruction suivante, le numéro de la colonne à sélectionner est donné par
2+ENT(I2/10) soit 2 + la partie entière de la I2/10 si i2 vaut 5, ENT(I2/10)=0 la colonne à sélectionner=2+0 donc 2ème colonne du tableau A1:D55 soit colonne B
=SIERREUR(RECHERCHEV(F2;$A$1:$D$55;2+ENT(I2/10);0);"")pour selectionner la colonne en fonction d'intervalles non réguliers, on peux utiliser la fonction EQUIV, qui retourne la position de la valeur (d'un ensemble de valeurs triées en ordre croissant) inférieure ou égale à la valeur recherchée
1+EQUIV(I2;{0,60,80,100};1)
si I2=79, le resultat de la fonction EQUIV donnera 2 (60 est en 2ème position) , si on ajoute 1, la colonne à selectionner sera la 3eme colonne du tableau A1:D55 soit la colonne C.
=SIERREUR(RECHERCHEV(F2;$A$1:$D$55;1+EQUIV(I2;{0;60;80;100};1);0);"")C'est parfait, explications et formules au TOP
On sent le professionnalisme, et merci de m'avoir accorder de ton temps pour partager ton savoir
Je vais encore chipoter une dernière fois
Si dans la formule =SIERREUR(RECHERCHEV(F2;$A$1:$D$55;1+EQUIV(I2;{0;60;80;100};1);0);"") je souhaite que rien ne s'inscrive dans la cellule L2 tant que les cellules F2 & I2 ne sont pas complétées, comment dois-je procéder ?
essaie ceci,
rajoute un test avec l'instruction SI et ET pour combiner 2 conditions.
=SI(ET(F2<>"";I2<>"");SIERREUR(RECHERCHEV(F2;$A$1:$D$55;1+EQUIV(I2;{0;60;80;100};1);0);"");"")Merci, comme d'habitude c'est parfait