Disossier une addition d'une cellule en chiffres
Bonjour,
Dans une cellule, j'ai :
=28300+28020+27820+29820+28760+29740+29060+30240+29680+30140+29480
Je devrais mettre ces chiffres dans une colonne, un chiffre par cellule:
28300
28020
Comment puis-je faire ?
D'avance merci.
Bonjour,
Voulez-vous dire que, dans cette cellule, vous avez cette valeur en forme de texte ?
Ou plutôt que la valeur dans cette cellule est réellement 321060 et que la formule qui donne cette valeur est =28300+28020+27820+29820+28760+29740+29060+30240+29680+30140+29480? Si oui, est-ce qu’il faut que vous la mainteniez ainsi, ou peut-on la convertir en une valeur de texte afin de la manipuler ?
Cordialement
Bonjour,
La valeur dans cette cellule est réellement 321060 et que la formule qui donne cette valeur est =28300+28020+27820+29820+28760+29740+29060+30240+29680+30140+29480.
L'on peut effectivement traiter ces nombres sous forme de texte.
Déjà merci .
Bonjour et Bienvenue sur XLP,
Disons que la cellule qui contient ce calcul est A1,
Alors dans le gestionnaire de noms tu vas nommer cette Macro XL4,
MaCellule :
=SUBSTITUE(LIRE.CELLULE(41;Feuil1!$A$1);"=";"+")&"+"
Puis en B1,
=SIERREUR(STXT(MaCellule;TROUVE("-";SUBSTITUE(MaCellule;"+";"-";LIGNES($1:1)))+1;TROUVE("-";SUBSTITUE(MaCellule;"+";"-";LIGNES($1:2)))-TROUVE("-";SUBSTITUE(MaCellule;"+";"-";LIGNES($1:1)))-1)*1;"")@ tirer vers le bas
@ + +
Bonjour,
Une autre plus simple pour le fun,
Nommer MaFormule dans le gestionnaire de noms :
=EVALUER("{"&SUBSTITUE(SUBSTITUE(LIRE.CELLULE(41;Feuil1!$A$1);"=";);"+";";")&"}")en B1,
=SIERREUR(INDEX(MaFormule;LIGNES($1:1));"")@ tirer vers le bas
@ + +
C’est vraiment jolie, R@chid. Les fonctions ÉVALUER et LIRE.CELLULE sont rarement utilisées.
Cordialement
Encore mieux. Mille mercis.
Bonjour,
Comment dois-je faire pour utiliser le gestionnaire de noms et y inscrire la ligne de code maformule ? C'est la première fois que je l'utilise.
Merci
Bonjour,
Et comment tu as essayé les formules proposées pour dire Merci...???
@ + +
C'est un collègue qui m'a aidé.