Calcul automatique avec différents onglets
Bonjour,
Je souhaite mettre en place un calcul automatique en fonction des informations disponible sur d'autres feuilles du classeur :
En clair sur l'onglet " Août " je souhaite que :
1 ère case orange : Récupérer toutes les cases N3 Sur tous les onglets
2 ème case orange : Récupérer toutes les cases N4 Sur tous les onglets
Case bleue Récupérer toutes les cases Q3 Sur tous les onglets
Case Verte : Récupérer toutes les cases T3 Sur tous les onglets
Merci
Romeo59181
Bonjour
Pour N3
=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(2013;8;{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15});"jj-mm")&"'!N3");"<>"&"";INDIRECT("'"&TEXTE(DATE(2013;8;{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15});"jj-mm")&"'!N3")))Pour les autres, tu remplaces N3 par ta nouvelle cellule
Cordialement
Bonjour,
En effet cela fonctionne merci,
Et il possible de me détailler cette formule afin de la comprendre pour l'adapter à d'autres situation similaire ?
Merci
Romeo59181
Bonjour
Une autre formule
=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(2013;8;LIGNE(INDIRECT("1:15")));"jj-mm")&"'!N3");"<>"&"";INDIRECT("'"&TEXTE(DATE(2013;8;LIGNE(INDIRECT("1:15")));"jj-mm")&"'!N3")))Quant à expliquer en détail, c'est une autre affaire
Aide Excel
SOMME.SI
Additionne des cellules spécifiées si elles répondent à un critère donné.
Syntaxe
SOMME.SI(plage;critère;somme_plage)
plage représente la plage de cellules sur lesquelles baser la fonction.
critère représente le critère, sous forme de nombre, d'expression ou de texte, définissant les cellules à additionner. Par exemple, l'argument critère peut être exprimé sous une des formes suivantes : « 32 », « >32 », « pommes ».
somme_plage représente les cellules à additionner.
Notes
Les cellules comprises dans l'argument somme_plage sont additionnées si et seulement si les cellules correspondantes situées dans l'argument plage répondent au critère.
Si l'argument somme_plage est omis, ce sont les cellules de l'argument plage qui sont additionnées.
Microsoft Excel offre des fonctions supplémentaires que vous pouvez utiliser pour analyser des données sur la base d'une condition. Par exemple, pour compter le nombre d'occurrences d'une chaîne de texte ou d'un nombre à l'intérieur d'une plage de cellules, utilisez la fonction NB.SI. Pour faire en sorte qu'une formule renvoie une ou deux valeur(s) basée(s) sur une condition telle qu'une prime à la vente basée sur un certain chiffre de vente, utilisez la fonction SI.
Sommeprod transforme la formule
INDIRECT("'"&TEXTE(DATE(2013;8;LIGNE(INDIRECT("1:15")));"jj-mm")&"'!N3")en une matrice
Sommeprod('01-08'!N3;'02-08'!N3;'03-08'!N3; etc
Les noms des Feuilles sont reconstruits à partir de la formule précédente parce que
TEXTE(DATE(2013;8;1);"jj-mm") ="01-08"
et que ici aussi, une seconde matrice est créée (tojours Sommeprod) par la formule
LIGNE(INDIRECT("1:15")) qui donne les jours 1;2;3;4;etc...
Cordialement
Bonjour,
Merci de ces détails,
Donc si je comprends bien pour le mois de septembre on aura :
=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(2013;9;LIGNE(INDIRECT("1:30")));"jj-mm")&"'!N3");"<>"&"";INDIRECT("'"&TEXTE(DATE(2013;9;LIGNE(INDIRECT("1:30")));"jj-mm")&"'!N3")))C'est ça ?
@+
Romeo59181