Générer une feuille avec un nom donné

Bonjour à tous,

Je suis nouveau sur ce forum, je me suis inscrits car j'avais besoin d'aide et je ne trouvais rien sur internet, j'ai donc choisis le forum le plus attirant.

Voici mon problème:

Je suis en stage et il faut que je crées un tableau qui sera remplis tous les mois par quelqu'un peu experimenté en informatique. Je me suis dis qu'il serait bien d'avoir tous les mois regroupés sous le même fichier excel, pour cela, sur la première feuille j'ai implimenté un bouton qui execute une macro: générer une nouvelle feuille avec le tableau en question. Jusqu'à là tout va bien. Mon problème se situe dans le fait que je n'arrive pas à implémenter dans la macro la modification du nom de la nouvelle feuille. A chaque fois j'ai :

Sub Macro

Sheets.Add After:=Sheets(Sheets.Count)

Sheets("Feuil10").Select

Sheets("Feuil10").Name = "lol"

End Sub

La macro échue au niveau de la modification du nom..

Par ailleurs je me suis dis qu'il serait bien que la feuille nommée se nomme automatiquement en fonction de la feuille précédente (par exemple: feuil1: avril donc automatiquement la prochaine feuille générée feuil2: mai) Pourriez vous m'aider s'il vous plaît, j'en serais très reconnaissant.

Cordialement

Bonjour

Roljo a écrit :

Par ailleurs je me suis dis qu'il serait bien que la feuille nommée se nomme automatiquement en fonction de la feuille précédente

Surement dans le monde des bisounours

Une macro à tester

Option Explicit

Sub Macro()
Dim I As Integer
Dim Ws As Worksheet

  Application.ScreenUpdating = False    ' Pour ne pas voir de flash
  Set Ws = ActiveSheet                  ' On repère la feuille de départ
  For I = 1 To 12                       ' Pour les 12 mois
    ' Création de la page puis modification de son nom
    Sheets.Add(After:=Sheets(Sheets.Count)).Name = MonthName(I)
  Next I
  Ws.Select                             ' On revient sur la feuille de départ
End Sub

Merci, cela me permet déjà de pouvoir créer des feuilles et de les nommer et surtout le coup de générer 12 mois est pas mal. Je pense que je vais intégrer un bouton au mois de décembre pour générer une nouvelle année à chaque fin d'année (je suis pas sûr que mon tableau servira aussi longtemps)

Tant que j'y pense, y aurait t il une macro qui permettrai d'ouvrir ces 12 nouveaux mois dans un nouveau fichier excel, qui par ailleurs serait nommée par le biais de cette dernière (par exemple: tableau 2014) ?

Bonjour

A voir

Option Explicit

Sub CreationFichier()
Dim I As Integer
Dim Nb As Integer
Dim Chemin As String
Dim Fichier As String

  Fichier = "Tableau 2014"
  Chemin = ThisWorkbook.Path & "\"

  Application.ScreenUpdating = False      ' Pour ne pas voir de flash
  Nb = Application.SheetsInNewWorkbook    ' Récupère
  Application.SheetsInNewWorkbook = 12    ' Nouvelle information
    With Workbooks.Add                    ' Création du classeur
      For I = 1 To 12                     ' Pour les 12 mois
        .Sheets(I).Name = MonthName(I)    ' Modification du nom
      Next I
      .SaveAs Chemin & Fichier            ' Enregistrement
      .Close                              ' Fermeture
    End With
  Application.SheetsInNewWorkbook = Nb    ' rétablit
End Sub

J'ai fais un mix de tout plus des petites chose que j'avais trouvé à côté et ça marche, merci