Afficher même valeur dans un autre onglet

Bonjour à tous,

J'ai des valeurs identiques dans 2 feuilles.

Ce que je voudrais:

Lorsque je suis sur une cellule dans la feuille 1 => je souhaite être renvoyer sur la cellule qui contient le même contenu en feuille 2.

Exemple: cellule C8 de feuille 1 me renvoi en B4 feuille 2 car les contenus sont identiques

Merci pour votre aide

P@t76

Bonjour,

Voici une macro qui te renvoie en feuille 2 sur la cellule qui contient le même contenu que la cellule active .

Sub Renvoyer()
Dim C As Range
    Set C = Sheets("Feuil2").Cells.Find(What:=ActiveCell.Value, LookIn:=xlValues, LookAt:=xlWhole)
    If Not C Is Nothing Then
        Sheets("Feuil2").Activate
        C.Activate
    Else
        MsgBox "Aucun contenu identique en feuille 2"
    End If
    Set C = Nothing
End Sub

A+

ça marche !!

Merci beaucoup pour ton aide.

P@t

Bonjour à tous,

J'aurai besoin d'un info complémentaire:

J'utilise un raccourçi CTL SHIFT P pour lancer la macro quand je suis positionné sur la cellule.

Comment faire pour remplaçer ce raccourçi par un double clic dans la cellule.

Merci

P@t

Bonjour,

Tu inclus le code dans la procédure évènementielle BeforeDoubleClick de la feuille concernée

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim C As Range
    Set C = Sheets("Feuil2").Cells.Find(What:=Target.Value, LookIn:=xlValues, LookAt:=xlWhole)
    If Not C Is Nothing Then
        Sheets("Feuil2").Activate
        C.Activate
    Else
        MsgBox "Aucun contenu identique en feuille 2"
    End If
    Set C = Nothing
End Sub

A+

Merci beaucoup Frangy, c'est superbe !

Bonjour,

Serait-il possible d'activer le double clic uniquement dans la colonne C au lieu de toute la feuilles ?

Merci

P@t

Bonjour,

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim C As Range
    If Target.Column = 3 Then
        Set C = Sheets("Feuil2").Cells.Find(What:=Target.Value, LookIn:=xlValues, LookAt:=xlWhole)
        If Not C Is Nothing Then
            Sheets("Feuil2").Activate
            C.Activate
        Else
            MsgBox "Aucun contenu identique en feuille 2"
        End If
        Set C = Nothing
    End If
End Sub

A+

ça maaaaarche .... !!!!

Merci pour ta rapidité frangy !!