Problème de boucle dans une macro

Bonjour,

Voici mon probléme.

Je dois récupérer des dates sur dans différents fichiers excel dont les liens se trouve dans la colonne AH.

La macro ouvre le premier fichier dont le lien se trouve en AH2, récupére des dates qui sont dans les cellules C8 à C12 du fichier qui vient de s'ouvrir, le referme et me les recopie dans les cellules copiées sur ma feuille dans les cellules AT à AX, puis recommence avec le lien en AH3 et ceci 20 fois jusque AH21. sous condition que la cellule B & i soit > 0

Tout fonctionne si le lien qui se trouve en AH est valide, mais dés que le lien est érroné, la macro s'arrête et je me retrouve avec la fenêtre deboggage macro qui s'ouvre, comment ignorer les liens éronnés automatiquement?

Merci de votre aide précieuse.

Voici ma macro:

Application.ScreenUpdating = False

Application.DisplayAlerts = False

Sheets("CE").Activate

i = 2

For i = 2 To 21

Range("AH" & i).Select

Zlien = ActiveCell.Value

If Range("B" & i) > 0 Then

Workbooks.Open Filename:= _

Zlien

Sheets("EVALUATION").Select

Range("C" & 8).Select

zdate1 = ActiveCell.Value

Range("C" & 9).Select

zdate2 = ActiveCell.Value

Range("C" & 10).Select

zdate3 = ActiveCell.Value

Range("C" & 11).Select

zdate4 = ActiveCell.Value

Range("C" & 12).Select

zdate5 = ActiveCell.Value

ActiveWorkbook.Close

' retour au fichier "MEI équipe"

Range("AT" & i).Select

ActiveCell.Formula = zdate1

Range("AU" & i).Select

ActiveCell.Formula = zdate2

Range("AV" & i).Select

ActiveCell.Formula = zdate3

Range("AW" & i).Select

ActiveCell.Formula = zdate4

Range("AX" & i).Select

ActiveCell.Formula = zdate5

End If

Next i

ActiveWorkbook.Save

Bonjour

Sans fichier

Option Explicit

Sub test()
Dim I As Integer
Dim WsDestin As Worksheet
Dim Zlien

  With Application
    .ScreenUpdating = False
    .DisplayAlerts = False
  End With

  Set WsDestin = Sheets("CE")

  For I = 2 To 21
    Zlien = WsDestin.Range("AH" & I)
    If WsDestin.Range("B" & I) > 0 Then
      If Dir(Zlien) <> "" Then
        With Workbooks.Open(Filename:=Zlien)
          .Sheets("EVALUATION").Range("C8:C12").Copy Destination:=WsDestin.Range("AT" & I)
          .Close
        End With
      End If
    End If
  Next I

  ActiveWorkbook.Save
End Sub

Si pas ça joins ton fichier maitre et au moins 1 fichier Zlien

Merci pour le réponse je teste ça dans la soirée pour savoir si ça fonctionne et vous tiens au courant. Au cas ou je joindrai un fichier.

Après plusieurs essais pour vérifier, la macro fonctionne parfaitement, et je vous en remercie.