UserForm Pré-saisir le nom de l'auteur par défaut

Bonjour,

je voudrais mettre le nom de l'auteur dans un textBox d'un userform

je connais le code pour le mettre dans une cellule

'Range("A1") = BuiltinDocumentProperties("author").Value

mais pas pour l'inclure dans un Userform ; j'ai essayé ça dans la procédure Private Sub UserForm_Initialize()

'TxBAuthor = BuiltinDocumentProperties("author").Value

mais j'ai une erreur de compil : "sub ou Function non définie"

Attention, je veux vraiment le nom qui a été saisie dans les options excel / standard / nom de l'utilisateur.

Merci d'avance

PS : Très débutante

Bonsoir

Code à essayer

TxBAuthor = ActiveWorkbook.BuiltinDocumentProperties("author")

Cordialement

Bonjour Dan,

C'est exactement ce que je voulais...

Autre question sur le même "auteur" ; est-il possible de mettre ce même auteur dans un bas de page excel sans et avec macro ?

re,

Avec macro :

With ActiveSheet.PageSetup
    'en-tête
    .LeftHeader = ""
    .CenterHeader = ""
    .RightHeader = ""
    'pied
    .LeftFooter = ""
    .CenterFooter = Application.UserName 
    .RightFooter =""
End With

J'ai mis le code générale pour toutes les parties de la feuille car on peut mettre d'autres paramètres (Date, nom fichier, ect...)

Ici le nom d'utilisateur se mettra dans le pied de page au centre de la feuille active.

Amicalement

Bonjour Dan

super ;

ça m'a permis de faire une macro 'Entête', quand mon fichier doit servir à d'autres, j'y mets toutes mes références, dont mon logo ;

je mets le code des fois que ça serve à d'autres

Sub entete()
ActiveSheet.PageSetup.LeftFooterPicture.Filename = _
        "D:\Données\Picture\PPT\DEO_Ico.jpg"
    With ActiveSheet.PageSetup.LeftFooterPicture    'dimension de l'image
        .Height = 13.8
        .Width = 19.2
    End With
With ActiveSheet.PageSetup
    'en-tête
   .LeftHeader = "&F"   'Nom de fichier (avec le chemin "&Z&F / &F")
    .CenterHeader = ""
    .RightHeader = "MàJ &D" 'Date (time = "&T")
    'pied
   .LeftFooter = "&G / " & Application.UserName 'Image et Nom
    .CenterFooter = "&A"  'Onglet
    .RightFooter = "Page : &P / &N" 'Page
End With
End Sub

Merci encore, à la prochaine

Re,

Ok. J'ai vu ton code que tu peux simplifier comme ceci aussi :

Sub entete()
With ActiveSheet.PageSetup
    With .LeftFooterPicture
        .Filename = "D:\Données\Picture\PPT\DEO_Ico.jpg"
        'dimension de l'image"
        .Height = 13.8
        .Width = 19.2
    End With
    'en-tête
    .LeftHeader = "&F"   'Nom de fichier (avec le chemin "&Z&F / &F")
    .CenterHeader = ""
    .RightHeader = "MàJ &D" 'Date (time = "&T")
   'pied
    .LeftFooter = "&G / " & Application.UserName 'Image et Nom
    .CenterFooter = "&A"  'Onglet
    .RightFooter = "Page : &P / &N" 'Page
End With
End Sub

Amicalement

Bonjour Dan,

Merci pour ta bien vaillance en m'apprenant à alléger mon code.