Code pour modifier la couleur de fond d'un commentaire

Bonjour à tous,

Avec un double click sur ma feuille (je travail de la cellule N13 à N22) j'ouvre un InputBox, que je remplis et

qui me permet à la fin l'insertion d'un commentaire

Tout fonctionne correctement.

Ce que je voudrais et j'ai chercher mais je n'ai pas trouver

c'est d'ajouter un code pour pouvoir modifier la couleur de fond du commentaire

Voici mon code

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

If Target.Count = 1 Then

With Target

If .NoteText = "" Then

reponse = InputBox("Indiquez les kilomètres parcourus")

If reponse <> "" Then

.AddComment reponse & " kilomètres parcourus"

With .Comment.Shape.OLEFormat.Object.Font

.Name = "Comic Sans MS"

.Size = 8

.FontStyle = "gras"

.ColorIndex = 10

End With

.Comment.Visible = True

.Comment.Shape.Select

Selection.AutoSize = True

.Comment.Visible = False

End If

Else

.Comment.Delete

End If

End With

End If

Cancel = True

End Sub

Je vous en remercie d'avance.

Bonjour

A essayer

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
 If Target.Count = 1 Then
   With Target
     If .NoteText = "" Then
        reponse = InputBox("Indiquez les kilomètres parcourus")
        If reponse <> "" Then
            .AddComment reponse & " kilomètres parcourus"
            With .Comment.Shape.OLEFormat.Object.Font
              .Name = "Comic Sans MS"
              .Size = 8
              .FontStyle = "gras"
              .ColorIndex = 10
            End With
            .Comment.Shape.Fill.ForeColor.RGB = RGB(255, 120, 180)
            .Comment.Visible = True
            .Comment.Shape.Select
            Selection.AutoSize = True
            .Comment.Visible = False
         End If
      Else
        .Comment.Delete
      End If
   End With
 End If
 Cancel = True
End Sub

Bonjour Banzai64,

Merci c'est vraiment super , excellent.

et quel rapidité.

Bon week-end à toi et au forum

Encore merci

Hello Banzaï64, Joyeuses fêtes !

Penses tu qu'il serait possible avec du code VBA, de modifier, la couleur de fond du commentaire en lui affectant une image,

En effet lorsque l'on clique droit sur le petit carré qui sert de poignée pour agrandissement du commentaire, cela ouvre un menu contextuel "Format de commentaire" puis dans l'onglet couleur et trait , menu remplissage, dans la liste déroulante des couleurs il est possible de choisir "motif et texture", ce qui ouvre un deuxième menu contextuel ou il y a un onglet image, il est ensuite possible de sélectionner une image comme couleur de remplissage du commentaire.

J'aimerais pouvoir créer une macro qui boucle sur une colonne avec des codes, et qu'elle soit capable d'aller associer une image - ayant pour nom de fichier le code de la cellule - en couleur de fond du commentaire associer à la cellule,