Liste DANS graphique
Bonjour à tous cher membre respectable de ce forum
Je viens à vous car j'ai un petit problème au niveau d'un graphique. J'ai joints mon fichier excel. Le hic se trouve au niveau du 1er tableau à réaliser (feuille maquette) concernant l'évolution du prix en fct du poste.
Je n'arrive pas à réaliser ce tableau... !! C'est pour cela que je viens à vous aujourd'hui ! Je continue à chercher de mon coté !
Les personnes qui auront réussi ce challenge peuvent-elles expliquer leurs démarches dans leurs réponses ?
Merci d'avance pour votre aide
Ps : si une âme charitable pouvait aussi régler mon problème de marge afin que tout puisse rentrer sur une feuille A4 en impression...
Bonjour
concernant l'évolution du prix en fct du poste.
Quels sont les différents postes à retenir?
Cordialement
Les postes à retenir se situent sur la feuille "données".
Il y donc le Béton Pret à l'Emploi, le gros œuvre, la menuiserie, plomberie, cloisons, carrelage, électricité et l'isolation...
Les différentes catégories sont mise en couleurs et ont comme "titre" ceux cité précédemment et qui sont positionné sur la 1er ligne.
La 1er des choses à faire est je pense créer des nouvelles colonnes comportant le prix/surface plancher. Par exemple pour le BPE l'opération serait =somme(E:F)/C:C
Bonjour
Le principe est dans le fichier. A toi de choisir ta présentation
Cordialement
Merci pour la présentation et la formule mais je n'ai pas compris celle-ci ... Pourrais tu me donner plus d'explication sur celle ci via MP ou répondre à la suite du post !
Merci d'avance
Bonjour
C'est vrai que j'ai omis les explication .
Avant la formule, commençons par le début
J'ai nommé Année la formule
=DECALER(Données!$AK$3;0;0;SOMMEPROD((Données!$AK$3:$AK$500<>"")*1))car j'ai vu que ton fichier comprenait la liste des années en colonne AK
J'ai nommé DateChantier la formule
=DECALER(Données!$A$3;;;NBVAL(Données!$A$3:$A$100))qui représente le champ dynamique (adaptable au nombre de données) de la colonne A
J'ai nommé Postes le champ contenant la liste des Postes
=Données!$AP$2:$AP$9 J'ai nommé SurfaceChantier la formule
=DECALER(Données!$C$3;;;NBVAL(DateChantier))(Champ dynamique de la colonne Surface Chantier aligné sur le nombre de dates de la colonne A)
J'ai inséré la Zone de liste déroulante sur le graphique et dans le "format de contrôle" de la liste déroulante, "cellule liée", j'ai choisi $A$22
En B22, la formule
=INDEX(Postes;$A$22)renvoie le Poste sélectionné dans la liste.
La Formule en B24 (Matricielle à valider avec les 3 touches Ctrl+Maj+Entrée)
=SI($B$22="Béton Prêt Emploi";SOMMEPROD((DateChantier=$A24)*(DECALER(SurfaceChantier;0;3)))/SOMMEPROD((DateChantier=$A24)*(SurfaceChantier));SI($B$22="Gros Œuvre";SOMMEPROD((DateChantier=$A24)*DECALER(SurfaceChantier;0;5;;6))/SOMMEPROD((DateChantier=$A24)*(SurfaceChantier));SOMMEPROD((DateChantier=$A24)*DECALER(SurfaceChantier;0;MIN(SI(Données!$D$1:$AE$1=$B$22;COLONNE(Données!$D$1:$AE$1)))-2;;2))/SOMMEPROD((DateChantier=$A24)*(SurfaceChantier))))en la relisant, je constate qu'on peut la simplifier par
=SI($B$22="Béton Prêt Emploi";SOMMEPROD((DateChantier=$A24)*(DECALER(SurfaceChantier;0;3)));SI($B$22="Gros Œuvre";SOMMEPROD((DateChantier=$A24)*(DECALER(SurfaceChantier;0;5;;6)));SOMMEPROD((DateChantier=$A24)*(DECALER(SurfaceChantier;0;MIN(SI(Données!$D$1:$AE$1=$B$22;COLONNE(Données!$D$1:$AE$1)))-2;;2)))))/SOMMEPROD((DateChantier=$A24)*(SurfaceChantier))puisque les 3 arguments de la fonction SI sont tous divisés par
SOMMEPROD((DateChantier=$A24)*(SurfaceChantier)) qui renvoie la surface totale des chantiers pour l'année.
Voici l'explication:
Le principe est d'établir la surface en fonction du Poste choisi dans la liste déroulante par année, le prix total pour le Poste choisi et l'année choisie, et de diviser ce résultat par la surface totale concernée par les chantiers de cette année là (Tu suis?)
Si nous prenons la première partie de la formule pour Béton Prêt Emploi
SOMMEPROD((DateChantier=$A24)*(DECALER(SurfaceChantier;0;3)))/SOMMEPROD((DateChantier=$A24)*(SurfaceChantier)SOMMEPROD((DateChantier=2006)*(DECALER(SurfaceChantier;0;3))SurfaceChantier est la colonne C et les prix pour Béton Prêt Emploi sont en colonne F, soit 3 colonnes plus loin et DECALER(SurfaceChantier;0;3)) est décaler colonne C de 3 colonne vers la droite, donc colonne F
Nous avons sur ta feuille Données 3 cas de figures
1) Pour Béton Prêt Emploi, il faut sommer les données de la colonne F
DECALER(SurfaceChantier;0;3))2) Pour Gros Oeuvre, nous avons 6 colonnes de Prix , la première (H) étant 5 colonnes à droite de la colonne C
DECALER(SurfaceChantier;0;5;;6) soit décaler la colonne C de 5 colonnes vers la droite et de 6 colonnes de largeur
3) Pour tous les autres postes nous avons 2 colonnes de prix
Dans
DECALER(SurfaceChantier;0;MIN(SI(Données!$D$1:$AE$1=$B$22;COLONNE(Données!$D$1:$AE$1)))-2;;2))la partie
MIN(SI(Données!$D$1:$AE$1=$B$22;COLONNE(Données!$D$1:$AE$1)))-2identifie la colonne corespondante à partir de laquelle on doit sommer les 2 colonnes.
Comme toutes les formules, souvent plus facile à réaliser intuitivement qu'à expliquer
Cordialement
Bonjour à tous
Beau boulot Amadeus
Edit Amadéus: Merci Bruno
Merci beaucoup pour l'explication je pense avoir compris, j'ai réussi à réaliser ta procédure en suivant tes indications