Voir ou Cacher des feuilles

Bonjour le forum,

Voilà je cache et je montre des feuilles grâce à des macro excel avec un bouton "voir les feuilles" et "cacher les feuilles" voila tout les feuilles portant le mot "Fiche " je voudrais les cacher mais le problème c'est que j'ai d'autres feuilles avec un autre nom et je veux pas les prend en compte quand je fais ma bouble FOR parce "chaine1 = sheets.count me prend toutes les feuilles de mon classeur du coup mon code ne marche pas.

Quelqu'un à la solution à mon problème?

Voila mon code:

Option Explicit

Dim num As Variant
Dim chaine1 As Variant
Dim chaine2 As Long

Sub voirfeuil()

If InputBox("Mot de passe ?") = "123" Then
chaine1 = Sheets.Count
        For num = 1 To chaine1
            Sheets("Fiche " & num).Visible = True
        Next num
End If

End Sub

Sub cacherfeuil()

If InputBox("Mot de passe ?") = "123" Then

chaine2 = Sheets.Count
    For num = 1 To chaine2
        Sheets("Fiche " & num).Visible = False
        Sheets("Fiche " & num).Visible = xlSheetVeryHidden
    Next num
End If

End Sub

Merci d'avance!

Bonjour,

A essayer..

Sub voirfeuil()
Dim F As Worksheet
    If InputBox("Mot de passe ?") = "123" Then
        For Each F In Worksheets
            If Left(F.Name, 5) = "Fiche" Then
                F.Visible = True
            End If
        Next F
    End If
End Sub

Sub cacherfeuil()
Dim F As Worksheet
    If InputBox("Mot de passe ?") = "123" Then
        For Each F In Worksheets
            If Left(F.Name, 5) = "Fiche" Then
                F.Visible = xlSheetVeryHidden
            End If
        Next F
    End If
End Sub

A+

Merci lermite ça marche parfaitement bien! bonne journée à toi!