Code macro non fonctionnel lorsque feuille protégée

Le 19/12/2011 à 01:02

Salut le forum

Merci de me donner un coup de main avec le code macro ci-dessous.

En effet, lorsque je protège la feuille, la macro ne fonctionne pas totalement bien.

Tout fonctionne bien sauf le code macro qui permet de transformer les valeurs de certaines cellule en format date.

Y'a t-il possibilité de rendre le code moin lourd afin qu'il puisse bien fonctionner?

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim outdNumberFormat As String
Dim ValSaisie
Dim P As Integer

On Error GoTo fin

  If Target.Count > 1 Then Exit Sub
  If Not Intersect(Range("B18,B22,B23,B38,B47"), Target) Is Nothing Then
    outdNumberFormat = Target.NumberFormat ' Récupère l'ancien format de cellule
    Target.NumberFormat = "@" ' Force en standart
    If IsNumeric(Target) = True Then ' Si c'est un nombre
      If (Len(Target) = 7 Or Len(Target) = 8) Then ' Longueur 7 ou 8 caractères
        If IsDate(Left(Target, Len(Target) - 6) & "/" & Mid(Target, Len(Target) - 5, 2) & "/" & Right(Target, 4)) Then
          ' Vérifie si une fois transformé on obtient une date
          Application.EnableEvents = False
          With Target
            .Value = Left(Target, Len(Target) - 6) & "/" & Mid(Target, Len(Target) - 5, 2) & "/" & Right(Target, 4)
            .NumberFormat = "m/d/yyyy"
          End With
          Application.EnableEvents = True
        Else
          ' On n'obtient pas de date donc on remet le format de cellule d'origine
          Target.NumberFormat = outdNumberFormat
        End If
      Else
        ' La longueur n'est ni 7 ni 8 donc on remet le format de cellule d'origine
        Target.NumberFormat = outdNumberFormat
      End If
    Else
      ' Ce n'est pas un nombre donc on remet le format de cellule d'origine
      Target.NumberFormat = outdNumberFormat
    End If
  ElseIf Not Intersect(Range("B11,B30"), Target) Is Nothing Then
    Application.EnableEvents = False
    ValSaisie = Target
    Application.Undo
    P = InStr(Target, ValSaisie)
    If P > 0 Then
      Target = Left(Target, P - 1) & Mid(Target, P + Len(ValSaisie) + 1)
      If Right(Target, 1) = ":" Then
        Target = Left(Target, Len(Target) - 1)
      End If
    Else
      If Target = "" Then
        Target = ValSaisie
      Else
        Target = Target & ":" & ValSaisie
      End If
    End If
    Application.EnableEvents = True
ElseIf Range("B4").Value = "CH PARTICULIER" Then
    If Target.Address = "$B$5" And Target.Value <> "" Then
    Range("B7").Select
    ElseIf Target.Address = "$B$31" And Target.Value <> "" Then
    Range("B33").Select
    ElseIf Target.Address = "$B$37" And Target.Value <> "" Then
    Range("B39").Select
    ElseIf Target.Address = "$B$39" And Target.Value <> "" Then
    Range("B42").Select
        ElseIf Target.Address = "$B$42" And Target.Value <> "" Then
    Range("B44").Select
    ElseIf Target.Address = "$B$44" And Target.Value <> "" Then
    Range("B48").Select
    ElseIf Target.Address = "$B$48" And Target.Value <> "" Then
    Range("B49").Select
    Call Macro10
    'Range("E3").Select
    Range("E3").Select
    Else: GoTo fin
    End If
Else: GoTo fin
  End If

fin:
  Application.EnableEvents = True   ' Dans tous les cas on remet les évènements en service
  Exit Sub
End Sub
Le 19/12/2011 à 12:46

Salut le forum

Deux solutions :

  • Tu déprotèges en début de macro et tu remets la protection à la fin
Me.Unprotect "Mot de Passe"
...
Me.Protect "Mot de Passe"
  • Tu protèges les feuilles avec UserInterfaceOnly (A l'ouverture du fichier)
Private Sub Workbook_Open()
Dim ws As Worksheet 

For Each ws In ActiveWorkbook.Worksheets 
ws.Protect Password:="xxxxxxxx", UserInterfaceOnly:=True 
Next ws 

End Sub

Mytå

Le 19/12/2011 à 22:57

Merci myta

le 1er code m'a déjà été protégé mais ca fait pas trop mon affaire.

Si le fichier est deprotégé, un utilisateur pourrait éventuellement modifier mes données.

Je l'ai déjà testé mais je vois que le risque est considérable.

Je comprend pas trop ce que le 2è code me réserve.

Est-ce qu'il pourra éviter toute modification de mes données?

Aussi, comment dois-je utiliser ce code?

Peut-tu l'intégrer dans mon code pour me faciliter la tache car suis pas trop fort en vba?

Merci pour tout

Le 19/12/2011 à 23:01

Re le forum

Tu l'insêres dans ThisWorkbook

Private Sub Workbook_Open()
Dim ws As Worksheet 

For Each ws In ActiveWorkbook.Worksheets 
ws.Protect Password:="xxxxxxxx", UserInterfaceOnly:=True 
Next ws 

End Sub

Tes macros vont alors fonctionner sans enlever les protections de feuille, et la feuille demeure protégée.

Pour le premier code la feuille est à nouveau protégée en fin de macro, je ne vois aucun risque.

Me.Unprotect "Mot de Passe"
...
Me.Protect "Mot de Passe"

Mytå

Le 20/12/2011 à 00:52

J'ai collé le 2è code dans thisworkbook mais ca ne marche pas.

Pour le 1er code, je repète qu'il y'a bel et bien un risque car j'ai moi même fait cette expérience.

En effet, lorsque nous sommes en mode unprotected, cela signifie que la feuille est déprotégée.

Pour quelle soit à nouveau protégée, il faut exécuter la macro.

Si je n'exécute pas la macro pour activer à nouveau la protection, je peux disposer du contenu de la feuille comme je veux.

Voila pourquoi je parle d'un risque latent : il est conseillé (le 1er code) lorsqu'un fichier est à usage personnel.

Le 20/12/2011 à 01:08

Bonjour

Le 1er code

Tu places

A toi de remplacer "Mot de Passe" par celui que tu veux

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim outdNumberFormat As String
Dim ValSaisie
Dim P As Integer

On Error GoTo fin

  If Target.Count > 1 Then Exit Sub
Me.Unprotect "Mot de Passe"

et la deuxième partie juste avant de sortir de la macro

fin:
  Application.EnableEvents = True   ' Dans tous les cas on remet les évènements en service
Me.Protect "Mot de Passe"
' Exit Sub    ' Inutile
End Sub
Le 21/12/2011 à 09:37

Merci pour ce code.

La declaration ci-dessous est-elle correcte :

[quote="Banzai64"]Dim ValSaisie

Aussi, ce code doit être intégré ou (feuille ou thisworbook)?

Le 21/12/2011 à 11:44

Bonjour

zombe a écrit :

Dim ValSaisie

Code valable, tu déclares la variable ValSaisie ayant comme type Variant (tu peux mettre ce que tu veux dans cette variable Integer,Long, Boolean,String, Worksheet etc.....)

zombe a écrit :

Aussi, ce code doit être intégré ou (feuille ou thisworbook)?

Quel code ?

Si c'est la macro Private Sub Worksheet_Change(ByVal Target As Range) c'est dans le code de la feuille (mais si mes souvenirs sont exacts, elle y est déjà)

Donc ta question je ne la comprends pas trop

Rechercher des sujets similaires à "code macro fonctionnel lorsque feuille protegee"