Doublons

Bonsoir amis Forumer

je veux comparer dans un même dossier

des données présentes en feuille 1 et en feuille 2 et de connaître la présence de doublons en feuille 3 , les colonnes de références sont par exemple A1 et A2 dans les deux feuilles

en espérant avoir été assez clair

Merci à vous

Bonsoir,

Tu t'es pas trop foulé pour l'exemple !

Sub Doublons() 'extrait les communs aux feuilles 1 et 2
Dim lg%, f1 As Worksheet, f2 As Worksheet
    Set f1 = Sheets("Feuille1")
    Set f2 = Sheets("Feuille2")
        Sheets("resultat Doublons").Activate
    lg = Application.Max( _
        f1.Cells.Find("*", , , , xlByRows, xlPrevious).Row, _
        f2.Cells.Find("*", , , , xlByRows, xlPrevious).Row)
    '--- doublons colonne A ---
    Range("k2") = "=COUNTIF(Feuille2!a2:a" & lg & ",Feuille1!a2)>0" 'critère
    f1.Range("a1:a" & lg).AdvancedFilter Action:=xlFilterCopy, CriteriaRange:= _
    Range("k1:k2"), CopyToRange:=Range("a1"), Unique:=True
    '--- doublons colonne B ---
    Range("k2") = "=COUNTIF(Feuille2!b2:b" & lg & ",Feuille1!b2)>0" 'critère
    f1.Range("b1:b" & lg).AdvancedFilter Action:=xlFilterCopy, CriteriaRange:= _
    Range("k1:k2"), CopyToRange:=Range("b1"), Unique:=True
    Range("k2").ClearContents
End Sub

Amicalement

Claude

Bonsoir ,

merci pour ton aide je vais voir çà de plus prêt et découvrir si çà marche

grand merci

bonsoir ,

je viens d'essayer ta macro et cela fonctionne hyper bien ( grand merci )

une question subsidiaire , peux tu me dire le nombre de lignes que ta macro vérifie dans les feuilles 1 et 2 colonnes A et B

bonne soirée

Bonsoir,

Normalement, sur toutes les lignes renseignées

avec Lg:

    lg = Application.Max( _
        f1.Cells.Find("*", , , , xlByRows, xlPrevious).Row, _
        f2.Cells.Find("*", , , , xlByRows, xlPrevious).Row)

Claude