Supprimer lignes doublons

Bonjour,

J'aimerais pouvoir supprimer les lignes doublons des colonnes A à G sur ma feuille.

Avec 2007 on peut supprimer les doublons mais il reste quand même un occurence

Ce que je souhaite c'est supprimer la totalité des lignes doublons! et garder que les lignes qui n'ont pas de doublons.

Merci de votre aide

Je ne trouve pas ! help please

Bonjour,

Envoie une feuille exemple avec lignes en doublon colorées

Amicalement

Claude

Bonjour, ci -joint l exemple. Le vrai fichier contient 3000 4000 lignes.

J'ai mis en rouge les lignes qui devraient être supprimés.

Merci de votre aide

re,

Tu ne conserve pas au moins 1 des doublons ?

précise

Claude

Merci de votre réponse,

Je ne conserve aucun doublons

je dois conserver les lignes qui ne sont pas en doublons. les doublons doivent supprimés. Sur l'exemple il doit me rester que les 3 lignes blanches

Bonjour

Dans ton exemple il reste deux fois ALLIOT Francois c'est voulu ?

Mon idée

Merci pour la réponse.

Dans la feuille résultat il devrait il y' avoir également ALLIOT Francois ce n'est pas deux fois les mêmes infos, les doublons sont de la colonne A à H.

Bonjour à tous,

ici, on supprime les lignes dans la feuille active,

mais on pourrait extraire dans une autre feuille

Sub Doublons()
Dim Lg&
    Application.ScreenUpdating = False
    On Error Resume Next
    ActiveSheet.ShowAllData                             'libère le filtre
    On Error GoTo 0
    Application.CutCopyMode = False
    Rows(1).Insert
    Lg = Range("a" & Rows.Count).End(xlUp).Row

    Range("n3:n" & Lg) = "=a3&b3&c3&d3&e3&f3&g3&h3"     'concatène A:H
    Range("o2") = "=COUNTIF(n:n,n3)>1"                  'critère filtre
    '--- filtre ---
    Range("a2:n" & Lg).AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
    Range("o1:o2"), Unique:=False
    '--- supprime lignes ---
    If Range("a" & Rows.Count).End(xlUp).Row > 2 Then
        Range("a3:n" & Lg).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    End If
    On Error Resume Next
    ActiveSheet.ShowAllData
    Columns("n:o").Clear
    Rows(1).Delete
End Sub

Amicalement

Claude

Bonjour

Bonjour Claude

Faut que j'essaie ces filtres, cela donne un code plus concis

A voir cette version

re,

Bonjour Banzai,

et moi; il faut que j'apprenne à utiliser les tablos !

version un peu simplifiée (sans insérer la ligne 1)

Sub Doublons()
Dim Lg&
    Application.ScreenUpdating = False
    On Error Resume Next
    ActiveSheet.ShowAllData                             'libère le filtre
    On Error GoTo 0
    Lg = Range("a" & Rows.Count).End(xlUp).Row

    Range("n2:n" & Lg) = "=a2&b2&c2&d2&e2&f2&g2&h2"     'concatène A:H
    Range("o2") = "=COUNTIF(n:n,n2)>1"                  'critère filtre
    '--- filtre ---
    Range("a1:n" & Lg).AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
    Range("o1:o2"), Unique:=False
    '--- supprime lignes ---
    If Range("a" & Rows.Count).End(xlUp).Row > 1 Then
        Range("a2:n" & Lg).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    End If
    On Error Resume Next
    ActiveSheet.ShowAllData
    Columns("n:o").Clear
End Sub

Claude