Erreur 1004 méthode "range"

Bonjour à tous.

J'ai un problèmes avec une macro sur excel 2003 : elle est censée sélectionner les lignes dignes d'intéret et les copier dans une feuille différente et l'imprimer mais en la lancantj'ai toujours l'erreur 1004 : la méthode "range" de l'objet "_global" a échoué. Dans tous les autres sujet que j'ai lu je n'ai pas trouvé de réponse. Voici la macro avec la ligne en cause en rouge :

Dim y As Integer

Dim x As Integer

Dim z As Integer

Range("$A$1:$D$4,$J$1:$L$4").Select

Range("L1").Activate

Selection.Copy

Sheets(2).Select

Range("A1").Select

ActiveSheet.Paste

Sheets(1).Activate

x = 4

If Cells(1, 6) <> "" Then

For y = 5 To 999

For z = 1 To 12

If Cells(y, z) = Cells(1, 6) Then

x = x + 1

Range("$A$y:$D$y,$J$y:$L$y").Select

Sheets("Feuil2").Activate

Range("$A$x").Select

ActiveSheet.Paste

Sheets("Feuil1").Activate

End If

Next z

Next y

Sheets(2).PrintOut Copies:=1

MsgBox ("Impression en cours")

Else: MsgBox ("Veuillez Sélectionner un objet à imprimer")

End If

End Sub

Il parait que j'ai une méthode de codage vraiment foireuse et je m'en excuse

Merci d'avance

Bonjour

Les $ ne servent à rien

Pour inclure une variable il faut reconstruire la chaine

Range("A" & y & ":D" & y & ",J" & y & ":L" & y).Select

A tester

Merci beaucoup pour cette réponse très rapide.

En effet ça marche beaucoup mieux

Encore merci

Salut elwinner08 et le forum

Pas sûr de moi, car ton code...

Sub test()
Dim X As Integer, Y As Integer, Z As Integer

With Sheets(1)
    .Range("A1:D4,J1:L4").Copy Sheets(2).Range("A1")
    X = 4
    If .Cells(1, "F") <> "" Then
        For Y = 5 To 999
            For Z = 1 To 12
                If .Cells(Y, Z) = .Cells(1, "F") Then
                    X = X + 1
                    .Range("A" & Y & ":D" & Y & ",J" & Y & ":L" & Y).Copy Sheets("Feuil2").Cells(X, "A")
                End If
            Next Z
        Next Y
        Sheets(2).PrintOut Copies:=1
        MsgBox ("Impression en cours")
    Else
        MsgBox ("Veuillez Sélectionner un objet à imprimer")
    End If
End With
End Sub

A+

Merci beaucoup à vous deux. Vous m'avez beaucoup servi. et maintenant je me retrouve avec un belle macro que je commence à avoir moi-même du mal à lire...

Comme tu le dis Gorfael : je suis encore désolé pour ma qualité de code ...

Encore merci