Formule avec SOUS.TOTAL (filtre)

Bonjour à tous,

Résultat d'un filtre, je ne connais pas à l'avance combien il y aura de lignes

Peut-on et comment formuler la "ligne 2" ?

Bonne journée

Amicalement

Claude

Bonjour Claude

A essayer en E2 -->

=SOMMEPROD(DECALER($C$4;;;NBVAL($C4:$C500))*DECALER($E$4;;;NBVAL($E4:$E500)))/SOMME(DECALER($C$4;;;NBVAL($C4:$C500)))

Amicalement

Bonjour Claude, Dan

Partant du principe de "qui peut le plus, peut le moins" :

=SOMMEPROD(($C$4:$C$65536)*(E$4:E$65536))/SOMME($C$4:$C$65536)

Amicalement

Nad

re Nad, Dan,

Merci pour vos réponse, je voyais çà + compliqué, sais pas pourquoi !

en fait il s'agit de ce poste

https://forum.excel-pratique.com/excel/pb-de-moyenne-ponderer-t22519.html

Nad,

Tu m'avais donner récemment une formule pour "patouma" qui faisait un SommeProd

associé à un Sous.total (filtre)

on devrait donc pouvoir appliquer ce genre de formule à ce fichier joint

de manière à avoir les résultats directement en fonction du filtre (ici en ligne 5)

les formules en place ne donne pas satisfaction

encore merci

Claude

Re

Claude, je dois m'absenter mais je regarde à mon retour.

P.S. : on dirait un débutant ! Si tu avais dis au départ que les lignes étaient filtrées ! Je pensais que tu avais fait une extraction.

Nad

re Nad,

Hé oui ! comme dit + haut, je voyais çà + compliqué

et pensais être obligé d'extraire, mais en voyant ta formule, j'ai tilté !

Amicalement

Claude

Bonjour Claude

En c5, tu as directement le résultat avec

=SOUS.TOTAL(1;C7:C1000)

Cordialement

Bonjour Amadéus,

C'est ce que j'avais mis au départ sur ce poste

https://forum.excel-pratique.com/excel/pb-de-moyenne-ponderer-t22519.html

mais apparemment ce n'est pas le résultat attendu

Pour sirat muriel dans pertinance de la reponse elle a etait ecouter 12 fois elle a obtenue 10 fois 100% et 2fois 0% Donc ca moyenne et de 83.33% or le resultat que me donne le tableau et de 75%

j'essaye d'appliquer la formule de Nad, mais pour le moment je cale !

quelque chose du genre (pour un autre fichier)

=SOMMEPROD((SOUS.TOTAL(9;DECALER($E$7;LIGNE(Dates)-7;)))*(Attribution=L2)*(Dates>=$J$3)*(Dates<=$J$4))

Amicalement

Claude

Bonjour Claude

J'ai repris le sujet au début

Le 83,33% en F5 peut être obtenu avec la formule

=SOMMEPROD(($B$7:$B$338=B3)*($C$7:$C$338)*(ESTNUM($F$7:$F$338));$F$7:$F$338)/SOMMEPROD(($B$7:$B$338=B3)*($C$7:$C$338))

Cordialement

re Amadéus,

ok, le résultat est bon,

mais, car il y a un mais !

Si en B3 je tape seulement "s" ou si" par exemple

SIRAT MURIELLE

SIMONET FABIEN

la formule ne suit pas, d'où l'intérêt de la méthode de Nad qui prend en compte

les cellules filtrées avec le "Sous.total" (uniquement la colonne "C" et la colonne formule)

enfin, si j'ai bien compris.

attendons sa réponse

Sujet intéressant à suivre

Amicalement

Claude

Re

Je ne comprends pas ta remarque sur la formule d'Amadeus ; elle était bonne si ce n'est que la moyenne ne tenait pas compte des cellules vides.

J'ai fait un mix en ajoutant ta dernière remarque :

dubois a écrit :

Si en B3 je tape seulement "s" ou si" par exemple

En D5 :

=SI(SOUS.TOTAL(3;D$7:D$1000)=0;"";(SI($B$3="";SOMMEPROD(($C$7:$C$1000)*D$7:D$1000);SOMMEPROD((GAUCHE($B$7:$B$1000;NBCAR($B$3))=$B$3)*($C$7:$C$1000)*D$7:D$1000)))/SOMMEPROD((SOUS.TOTAL(3;DECALER(D$6;LIGNE($7:$1000)-6;)))*(ESTNUM(D$7:D$1000));$C$7:$C$1000))

Dis-moi si c'est bien ça que tu attendais.

Amicalement

Nad

Bonjour Nad, Amadéus, forum,

Les résultats semblent bons, mais ce n'est pas vraiment ce que je voyais,

Il faut distinguer 2 choses

1) le filtre, déterminé par les cellules A3 et B3

2) la formule,

qui devrait traiter les cellules filtrées, mais sans s'occuper de A3 et B3

uniquement la colonne "C" (Nb_écoutes) avec la colonne de la formule.

Un peu comme quand on somme une colonne filtrée

=SOUS.TOTAL(9;C$7:C$1000)

ici, on ne s'occupe pas des critères de filtre

suis-je + clair ? , pas sûr !

Amicalement

Claude

Bonjour

A l'arrivée c'est le même résultat, mais je pense que tu attends donc cette formule (en D5) :

=SI(SOUS.TOTAL(3;D$7:D$1000)=0;"";SOMMEPROD((SOUS.TOTAL(9;DECALER(D$6;LIGNE($7:$1000)-6;)))*($C$7:$C$1000)*(ESTNUM($D$7:$D$1000)))/SOMMEPROD((SOUS.TOTAL(3;DECALER(D$6;LIGNE($7:$1000)-6;)))*($C$7:$C$1000)*(ESTNUM(D$7:D$1000))))

Dis-moi

Nad

re Nad,

Voilà, c'est exactement çà,

quel que soit le filtre, j'ai toujours les bons %

Il faut que j'ingurgite la formule avec les "SOUS.TOTAL, DECALER et LIGNE"

merci à vous

Bonne journée

Amicalement

Claude

édit: Changé titre du poste

edit 2 : je joins le fichier en accord