Saisie des dates sans les slashs

@xlutilisateur, voici votre code adapté mais si on utilise que les dates entre 1950 et 2050,on peut encore supprimer la moitié du code

Private Sub Worksheet_Change(ByVal Target As Range)
       Dim X, S, L
       With Target
              If IsEmpty(.Value2) Then Exit Sub       'vide
              If .CountLarge <> 1 Then Exit Sub       'plusieurs cellules
              If Intersect(Target, Me.Range("C8,C22,D15:E17")) Is Nothing Then Exit Sub
              X = .Value2
              If X Like "#######" Or X Like "########" Then       'numéro avec 7 ou 8 chiffres
                     S = Format(X, "00/00/0000")       'ajouter des séparateurs "/"
                     On Error Resume Next
                     L = 0: L = CLng(CDate(S))       'transformer la date sous forme "Text" en valeur "long"
                     On Error GoTo 0
                     Select Case L
                            Case Is < 0
                                   MsgBox "date avant le 01/01/1900, impossible pour excel", vbCritical, X
                                   .ClearContents
                            Case 0           'ce n'est pas une date réelle
                                   MsgBox "date erronée", vbCritical, X
                                   .ClearContents
                            Case Is < DateSerial(1950, 1, 1), Is >= DateSerial(2050, 1, 1)
                                   MsgBox "année n'est pas dans l'intervalle 1950-2050", vbCritical, X
                                   .ClearContents
                            Case Else
                                   If Format(L, "dd/mm/yyyy") = S Then       'la date en format "long" correspond avec l'original
                                          Application.EnableEvents = False
                                          Target.Value2 = L       'coller cette valeur "long" au lieu
                                          Application.EnableEvents = True
                                   Else
                                          MsgBox "erreur ...."
                                          .ClearContents
                                   End If
                     End Select
              Else
                     MsgBox "on n'a pas le format ""jjmmaaaa"" or ""jmmaaaa""""", vbCritical, X
                     .ClearContents
              End If
       End With
End Sub
Rechercher des sujets similaires à "saisie dates slashs"