[Powerquery] - Petit défi sympa

Hello les exceliens,

J'espère que vous allez bien, voici un petit défi tiré de "excel bi" sur linkedin. C'est toujours sympa à faire.

Objectif simple, une liste de phrases. Ce sont les chiffres qui composent chaque mot qui déterminent l'ordre de la phrase.

A vos requêtes

@+

Bonjour à tous !

Une approche ?

let
    Source = Excel.CurrentWorkbook(){[Name = "tSource"]}[Content], 
    Traitt = Table.AddColumn(
        Source, 
        "Résultat attendu", 
        each 
            let
                ts = Splitter.SplitTextByWhitespace()([Sentence])
            in
                Text.Combine(
                    List.Transform(
                        List.Sort(
                            List.Transform(
                                ts, 
                                each {
                                    Text.Remove(_, {"0" .. "9"}), 
                                    Number.From(Text.Select(_, {"0" .. "9"}))
                                }
                            ), 
                            each _{1}
                        ), 
                        each _{0}
                    ), 
                    " "
                )
    )
in
    Traitt

Hey,

Une autre approche mais très similaire

let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1"]}[Content],
    Result = Table.TransformColumns(Source, {"Sentence", each [
                                                    Sequence = Text.Split(_," "),
                                                    Sort = List.Sort(Sequence, each Number.From(Text.Select(_,{"0".."9"}))),
                                                    Combine = Text.Combine(List.Transform(Sort, each Text.Select(_,{"A".."z"})), " ")
                                                    ][Combine]})
in
   Result

Les autres ?

@+