Calcul de congés

Bonjour

Je souhaite trouver une formule ou autre qui me permette de résumer des dates de début et de fin de congés comme indiqué dans le tableau

Ci joint un fichier test

Merci pour l'aide apportée

Salut

Enfin une demande en bonne et due forme avec un bonjour... c'est bien mieux que le post d'hier

Mais le fichier, c'est une autre paire de manche

Bonne chance

Bonjour,

tout ça n'est pas très clair, il faut remplacer les formules existantes ? Garder la même disposition ?

Calculer quoi précisément, juste le nombre de fois qu'il est mis CF entre les colonnes B et AF ?

Bonjour

Désolé mais je n'ai pas transmis le bon fichier. Celui que j'ai envoyé 'est celui sur lequel j'essaie de trouver une solution....pas évidente je reconnais

Je transmets celui de départ ....

Cdlt

Ma

Alors avec cette disposition, je n'ai pas trouvé le moyen de rapporter le bon total.

Mais en ajoutant une ligne pour chaque mois et en ayant une cellule par date, ça simplifie tout ;

Il y a une MFC pour le 29/02 (qui apparaît tous les 4 ans, les autres cellules hachurées le sont en permanence) et des formules pour ;

-les dates entre B5 et AF27 ;

=SI(A5="";"";SI(COLONNE()=2;DATE($A$2;NBVAL($A$5:$A5);1);SI(JOUR(DATE($A$2;NBVAL($A$5:$A5);COLONNE()-1))<JOUR(A5);"";DATE($A$2;NBVAL($A$5:$A5);COLONNE()-1))))

-les périodes en AH et AI (on tape manuellement le jour et le mois) ;

=DATE($A$2;1;26)

-les résultats entre AJ et AL ;

=SOMMEPROD((ESTNUM($B$5:$AF$27))*($B$5:$AF$27>=$AH7)*($B$5:$AF$27<=$AI7)*($B$6:$AF$28=AJ$2))

Les formules pour les dates et les résultats sont incrémentables sans modification.

On peut changer l'année en A2, les dates suivent.

Bonjour

Déjà un grand merci à Doux Rêveur pour cette solution ....je vais essayer d'ajouter une ligne par mois sur ma base comme dans le modele...

Petite question : est il possible d'automatiser la date de début en AH et de fin en AI au lieu qu'elle soit manuelle ?

Encore merci Doux rêveur

Cdlt

Ma

Bonjour,

oui, on peut remplacer le jour par la référence à une cellule contenant le jour, idem pour le mois.

Ou extraire le jour et le mois via les fonctions JOUR() et MOIS() et les insérer dans la fonction DATE().

Ou encore taper directement la date sans formule, tout dépend de la manière avec laquelle les dates arrivent dans votre fichier.

Du moment qu'au final on ait bien une date de début et une de fin de période.

Bonjour

Merci pour le retour.

Les cellules de mon tableau sont renseignées simplement par la fonction : =prévisions de congés ! B7 (par exemple) qui prend la position CA, ou CF ou RTT ou CAS dans un autre tableau.

Je souhaiterais sur ce nouveau fichier crée que les dates de début et de fin d'une période s'inscrivent automatiquement dans les colonnes AH et AI , le décompte détaillé suivrait

La raison c'est que j'ai un trentaine de tableaux/calendrier à renseigner . Si on compte une moyenne de 5 périodes par tableau cela ferait 150 dates à écrire ....

Cdlt

Ma

Bonjour,

sans voir vos fichiers c'est un peu difficile de savoir quel serait le moyen le plus approprié pour importer les dates mais en principe, une simple référence à la cellule où se trouve la date suffit.

Sauf que si les tableaux sont dans des fichiers différents, ça se complique.

Le plus simple est de les avoir tous dans le même fichier et de nommer les feuilles (une pour un tableau) avec le même nom suivi d'un n° : alors on peut faire une formule incrémentable qui ira chercher une date par feuille pour les dates de début, et idem pour les dates de fin.

À condition que la date soit toujours dans la même cellule sur chaque feuille.

Exemple avec des feuilles nommées Tab 1, Tab 2 ... et la date toujours en B2 ;

=INDIRECT("'Tabl "&LIGNE(1:1)&"'!$B$2")

C'est comme si on mettait ;

='Tabl 1'!$B$2

Sauf qu'avec INDIRECT et LIGNE(1:1), ça va s'incrémenter en passant à ='Tabl 2'!$B$2, ='Tabl 3'!$B$2 ...

Donc ne pas mettre 01, 02 ... dans les noms des 9 premières feuilles, pas de zéro devant.

On peut appliquer le même principe aux noms de fichiers (si vous avez un tableau par fichier). Mais alors je crois que tous les fichiers doivent être ouverts pour que la formule fonctionne donc mieux vaut les assembler en un seul fichier.

Ou encore utiliser le module Power Query (aller dans Données, Requêtes) pour assembler des données provenant de fichiers différents mais je ne le maîtrise pas.

Si vous avez plusieurs dates de début et de fin par feuille, ça va compliquer la formule, surtout si le nombre de dates par feuille est variable.

Bonjour

Et merci à nouveau pour le retour.

C'est vrai que sans fichier c'est un peu compliqué . J'en ai fait un avec un tableau de données qui renseigne mon nouveau tableau dont je souhaite extraire les périodes ....

Cdlt

N.F

Ok je vois, c'est différent de ce à quoi je m'attendais puisque c'est en analysant le tableau qu'on doit trouver les périodes.

Comme vous le dites dans le fichier, il vaudrait mieux que tous les mois soient sur la même ligne parce que sinon ça va être compliqué de déterminer les débuts et fin de périodes.

Surtout dans le cas où une période chevaucherait 2 mois.

Mais je vais essayer, il y a peut-être moyen de le faire en laissant comme ça (j'ai une vague idée).

Pour la 2ème année, n'oubliez pas de changer la référence dans les formules, ce n'est plus B3 mais B38 (ce n'est utile que pour les années bissextiles).

Bonjour,

j'ai créé une feuille qui sert d'intermédiaire parce que sans ça je n'ai pas trouvé, et je me suis grillé quelques neurones.

Elle fait référence à la feuille "RECAPITULATIF CONGES" et sert à remplacer les types de congés par d'autres lettres qui servent à déterminer les dates de début et de fin (voir la légende en haut). Les M sont ignorés.

Formule matricielle en AH7 ;

=SIERREUR(SOMMEPROD(PETITE.VALEUR(SI(SI(ESTNUM($B$7:$AF$29);$B$7:$AF$29;0)*(($B$8:$AF$30="D")+($B$8:$AF$30="DeF"))=0;"x";SI(ESTNUM($B$7:$AF$29);$B$7:$AF$29;0)*(($B$8:$AF$30="D")+($B$8:$AF$30="DeF")));LIGNE(1:1)));"x")

En AH21 et AI21 il y a des légères variantes.

Dans la colonne N° Fin il n'y a qu'un 5, c'est le but, ça permet de savoir que les deux 5 font partie de la même période et on n'en garde qu'un (le dernier).

Pour le test j'ai ajouté CA le 08/01 dans la feuille "DONNEES" pour avoir un exemple de jour seul qui est à la fois le début et la fin de la période.

Formule en B8 ;

=SI(ET(ESTNONTEXTE('RECAPITULATIF CONGES'!A8);ESTTEXTE('RECAPITULATIF CONGES'!B8);ESTNONTEXTE('RECAPITULATIF CONGES'!C8));"DeF";SI(ET(ESTTEXTE('RECAPITULATIF CONGES'!B8);ESTNONTEXTE('RECAPITULATIF CONGES'!C8));"F";SI(ET(ESTTEXTE('RECAPITULATIF CONGES'!B8);ESTTEXTE('RECAPITULATIF CONGES'!A8));"M";SI(ESTTEXTE('RECAPITULATIF CONGES'!B8);"D";""))))

Résultat en feuille "RECAPITULATIF CONGES" ;

Pour AH8 ;

=SIERREUR(INDEX(Dates!$AH$7:$AH$16;EQUIV(LIGNE(1:1);Dates!$AJ$7:$AJ$16;0));"x")

Le tout est fait pour une année donc il reste à reproduire mon tableau et modifier les plages des formules pour les autres années.

Bonjour Doux Rêveur

Wouha, c'est génial :-) Merci beaucoup

Quel beau travail et vraiment bien l'intégration d'un tableau intermédiaire. Franchement c'est vraiment cette finalité que je voulais.

Un grand merci...et en plus avec toutes les explications

Je vais mettre tout cela en place dans mon tableau pour la trentaine de personnes ...ca devrait aller.

Je vous tiens au courant avant de clôturer le fil....

Encore un grand grand merci

Bonne journée

Je me mets à la tache :-)

Cdlt

Ma

Avec plaisir

Il faudra bien vérifier les références aux plages quand vous dupliquerez les tableaux, et aussi bien mettre l'année pour les dates (en B3 pour 2025).

Normalement un simple copier/coller du tableau devrait suffire, en tout cas pour les lignes de dates.