Dénombrement de valeurs hors norme dans un tableau

Bonsoir,

J'aimerais trouver une fonction pour dénombrer les valeurs non conformes dans un chiffrier pour un suivi de conformité environnemental. Une colonne contient les paramètres et l'autre les critères admissibles. La comparaison se fait entre les valeurs d'une même ligne dans l'ensemble du tableau.

Exemple joint.

Merci!

Bonjour,

Une proposition formule unique pour Excel 365 :

NB : si vous pouviez éviter les "<XXX" qui sont interprétés comme du texte... Je ne sais pas comment les traiter. Idem "ND". A prendre ou à laisser ?

=LET(
    _param; A6:A10;
    _crit; B6:B10;
    _vals; D6:M10;
    THUNK; LAMBDA(x; LAMBDA(x));
    filtreThk; MAP(
        SEQUENCE(LIGNES(_param));
        LAMBDA(i;
            LET(
                _r; CHOISIRLIGNES(_vals; i);
                _m; INDEX(_crit; i);
                THUNK(FILTRE(_r; _r > _m; ""))
            )
        )
    );
    _nbCols; MAX(SCAN(0; filtreThk; LAMBDA(a; f; COLONNES(f()))));
    _matRes; MAKEARRAY(LIGNES(_param); _nbCols; LAMBDA(r; c; INDEX(INDEX(filtreThk; r; 1)(); 1; c)));
    ASSEMB.H(_param; SIERREUR(_matRes; ""))
)

Pour ne prendre que les valeurs numériques en compte, remplacez le filtre (au milieu de la formule) par :

THUNK(FILTRE(_r; ESTNUM(_r) * (_r > _m); ""))

Bonjour à tous !

Le concept de non-conformité n'est pas défini.
Est-ce une valeur supérieure au critère (D6) ?
Est-ce une valeur inférieure au critère (D8) ?
Est-ce une valeur différente du critère ?

D'autres abréviations que "ND" signifiant obligatoirement une non-conformité ?
D'autres symboles que le "<" pourraient être envisagés ?

Bonjour à tous,

Un essai avec la formule suivante en D12 à recopier vers la droite:

=SOMMEPROD(SIERREUR(1*(CNUM(SUBSTITUE(D6:D10;"<";0))>$B$6:$B$10);0))

..

• On considère que la valeur "ND" n'est pas une non-conformité tout comme une cellule vide.
• Une non conformité est une valeur strictement supérieure à la valeur de la colonne B après avoir éliminé l'éventuel signe "<".
  

Notez que les interrogations de saboh12617 et de JFL sont pertinentes pour élaborer une réponse juste.

.

Merci JFL, Saboh et Mafraise!

Désolé pour les manque de précision dans ma demande JFL. Je ferai plus attention à la clarté de ma demande la prochaine fois.

La formule soumise par Mafraise fonctionne bien dans tous les cas.

Bonjour à tous !

C'est dommageable ne pas apporter réponse aux questions. Vous vous privez, éventuellement, d'alternatives.

Exemple avec deux propositions (formules uniques dynamiques) :