Formule afficher une valeur selon le jour et mois de l'année plus récente
Bonjour mes gens biens. J'ai besoin de votre aide svp.
Je souhaite établir une formule pour pouvoir afficher le résultat d'une colonne en fonction du 31/08 de l'année la plus récente.
Les dates sont dans la colonne A et les résultats dans la colonne E.
Je souhaite donc afficher la valeur de E selon le 31/08 de l'année la plus récente de A.
J'essaie d'apprendre les choses par moi-même et ça fait 3 jours que je galère d'essai en essai sans succès. Merci de m'aider.
Ci-joint le fichier. Merci
Bonsoir,
comme ceci ;
=INDEX($E$4:$E$537;MAX(SI(ESTNUM($A$4:$A$537);JOUR($A$4:$A$537)=31)*SI(ESTNUM($A$4:$A$537);MOIS($A$4:$A$537)=8)*(SI(ESTNUM($A$4:$A$537);ANNEE($A$4:$A$537)=MAX(SI(ESTNUM($A$4:$A$537);ANNEE($A$4:$A$537)))))*LIGNE($E$4:$E$537)-3))Et la sauver en mode matriciel (Ctrl+Maj+Enter).
bonjour egk,salut Doux-Rêveur
un autre essai avec "LET"
=LET(
Recent3108;DATE(ANNEE(AUJOURDHUI())-(MOIS(AUJOURDHUI())<9);8;31);
SIERREUR(INDEX($E:$E;
AGREGAT(14;6;LIGNE(MesDates)/(ESTNUM(MesDates)*(MesDates<=Recent3108));1)
);"?"))Bonjour à vous
Doux Rêveur et BsAlv
Je vous exprime toute ma reconnaissance. Copier coller la formule de Doux Rêveur a fonctionné correctement malgré que je suis actuellement sur smartphone et affiche la valeur souhaitée. (Ctrl+Maj+Enter) je le ferai dès que j'aurai accès à l'ordi dans la journée.
Cependant je voudrais demander s'il est possible de ne pas verrouiller les lignes et laisser la formule opérer juste dans les colonnes A:A (pour les dates existantes et à venir) et E:E (pour les valeurs).
Par contre copier coller, la formule de BsAlv affiche un point d'interrogation. Je ne sais pas si ça a rapport avec (Ctrl+Maj+Enter).
Désolé, j'ai cherché à citer la réponse de chacun de vous pour plus de visibilité mais j'ai pas pu identifier l'icône.
Une fois encore recevez toute ma gratitude.
J'ai pu modifier la formule de Doux Rêveur et ça a fonctionné comme j'espérais. Une fois encore merci à tous.
=INDEX(E:E;MAX(SI(ESTNUM(A:A);JOUR(A:A)=31)*SI(ESTNUM(A:A);MOIS(A:A)=8)*(SI(ESTNUM(A:A);ANNEE(A:A)=MAX(SI(ESTNUM(A:A);ANNEE(A:A)))))*LIGNE(E:E)))
Bonjour,
La proposition de BsAlv fonctionne parfaitemant, suivant la version Excel utilisée !...
Sinon, au plus simple, car les données sont triées :
=INDEX($A$4:$E$537; EQUIV(DATE(ANNEE(AUJOURDHUI()) - (MOIS(AUJOURDHUI()) < 9); 8; 31); $A$4:$A$537; 1); 5)Et le résultat attendu au 31 août 2025 n'est pas 802.429 mais 101.679, si je ne me trompe pas (comme BsAlv) !...
Cdlt.
Salut,
son fichier contient un 31/08/2026, donc je suppose que c'est le plus avancé dans le fichier qu'il faut prendre en compte.
Bonjour Monsieur Jean-Eric
Ok merci. Je suis pour l'instant sur smartphone. Je vais vois si la formule de BsAlv marche dès que je serai sur pc avec Excel 2021.
Oui en effet le résultat attendu est 101 679.
Merci à tous.
Désolé Monsieur Jean-Eric
Le résultat attendu sur le fichier envoyé est bien 802 429 et non 101679 comme j'ai pu le dire précédemment.
Merci
Re,
On est après le 31/08 !...
Cdlt.
Bonjour à tous !
Une... tentative ....
Cette approche gère les dates identiques nommées "d°" et retourne la valeur du 31 août de l'année maxi :
=LET(
pl_T; A1:E540;
pl_D; A1:A540;
derLig; LIGNE(RECHERCHEX("?*"; pl_D & ""; pl_D; ; 2; -1));
dat0; DATE(ANNEE(MAX(pl_D)); 8; 31);
ligD1; EQUIVX(VRAI; pl_D = dat0);
ligD2; SIERREUR(EQUIVX(1; (pl_D > dat0) * (ESTNUM(pl_D))); derLig + 1);
f; FILTRE(pl_T; (LIGNE(pl_T) >= ligD1) * (LIGNE(pl_T) < ligD2));
INDEX(f; LIGNES(f); 5)
)A tester..... (!)
EDIT : Suite à de nouveaux tests, la formule a été modifiée.
Re: Monsieur Jean-Eric
En effet on est après le 31/08..
Au fait c'est un livre de banque. Les opérations sont enregistrées continuellement mais à chaque 31/08 de l'année, le solde est arrêté pour servir de report à l'exercice budgétaire suivant. Dans mes efforts pour y arriver j'avais ajouté le 31/08/2026 pour voir si mes tentatives fonctionnaient, c'est à dire si l'une de mes formules feraient la différence entre le 31/08/2025 et 31/08/2026 pour m'afficher le bon solde. Ce que j'ai pu finalement obtenir grâce aux interventions ici.
Merci
Re: BsAlv
Re: JFL
Les deux formules fonctionnent aussi, seul problème, la formule de BsAlv ne prend pas en compte les autres 31/08 qui viennent après, ça affiche uniquement le solde de 101679 au 31/08/2025 même si on ajoute le 31/08/2026.
La formule de JFL mais #REF ! lorsqu'on ajoute le 31/08/2026.
En tout cas je remercie très sincèrement tout le monde, j'ai eu beaucoup de plats que je vais essayer de manger à tête reposée. J'ai déjà pu modifier la formule de Jean-Eric afin qu'elle puisse prendre en compte toute la colonne, j'espère pouvoir faire autant avec les deux autres.
Merci à tous
Bonsoir à tous !
La formule de JFL mais #REF ! lorsqu'on ajoute le 31/08/2026.
Il s'agit bien de considérer l'année située en bas de tableau comme étant l'année de référence pour déterminer la date du 31/08/aaaa ?
Bonjour tout le monde
Re: JFL "Il s'agit bien de considérer l'année située en bas de tableau comme étant l'année de référence pour déterminer la date du 31/08/aaaa ?"
En effet oui, considérer la dernière année pour retrouver le 31/08/aaaa plus récent et la valeur correspondante dans E:E.
Cette formule marche maintenant même si je la comprends beaucoup moins que celle de Monsieur Jean-Eric.
Dites-moi svp s'il est possible de sauter la référence des numéros de ligne par exemple mettre A:E et non A1:E540 afin que la formule puisse opérer librement.
Chacune des 3 proposition est d'un niveau qui me dépasse j'avoue. Je n'y serais jamais arrivé par moi-même. 😂
Vous êtes tous formidables.
Merci
Bonjour à tous !
Dites-moi svp s'il est possible de sauter la référence des numéros de ligne par exemple mettre A:E et non A1:E540 afin que la formule puisse opérer librement.
Œuvrer sur des colonnes entières n'est pas une bonne pratique car vous intégrez dans les calculs des milliers de cellules vides !
Je vous propose d'utiliser un tableau structuré (la formule a été adaptée) :
A tester !
Re: JFL
"Œuvrer sur des colonnes entières n'est pas une bonne pratique car vous intégrez dans les calculs des milliers de cellules vides !
Je vous propose d'utiliser un tableau structuré (la formule a été adaptée)"
Super joli travail. Je comprends bien le risque. L'enregistrement des opérations étant continue, je crains juste d'oublier un jour que la formule est limitée à une ligne. Mais bon, je suis totalement satisfait de vos apports.
Merci beaucoup
Re: JFL "J'ai bien peur de ne pas comprendre votre crainte. Pouvez-vous expliciter ?"
Oh mince ! Je suis vraiment désolé. C'est maintenant je comprends peu à peu comment fonctionne votre tableau et la formule. Je ne suis pas doué du tout dans cette affaire. C'est super formidable. Je pense qu'il n'y a plus à dire.
Merci beaucoup pour le travail.
Bonsoir à tous !
C'est une excellente nouvelle !
Bon apprentissage....