Power query cumul par trimestre

Les données doivent s'ajouter et même si cela est sur 2 années différentes

Cordialement,

Quelque chose comme

let
    Source = Excel.CurrentWorkbook(){[Name="Conso_Carbu"]}[Content],
    Trimestre = Table.AddColumn(Source, "Trimestre", each Number.IntegerDivide(Number.From(Text.Start([Période],2))-1, 3)+1, type number),
    Année = Table.AddColumn(Trimestre, "Année", each Number.From(Text.End([Période], 4)), type number),
    #"Regroupement 1" = Table.Group(Année, {"Immat. - Immat.", "Trimestre", "Année"}, {{"Quantité", each List.Sum([Quantité]), type number}}),
    Fusion = Table.NestedJoin(#"Regroupement 1", {"Immat. - Immat."}, #"Regroupement 1", {"Immat. - Immat."}, "Lignes groupées", JoinKind.LeftOuter),
    Developpement = Table.ExpandTableColumn(Fusion, "Lignes groupées", {"Trimestre", "Année", "Quantité"}, {"Trimestre.1", "Année.1", "Quantité.1"}),
    #"Filtre Trimestre+ Année" = Table.SelectRows(Developpement, each ([Trimestre.1] <= [Trimestre] and [Année.1] = [Année]) or [Année.1] < [Année]),
    #"Regroupement 2" = Table.Group(#"Filtre Trimestre+ Année", {"Immat. - Immat.", "Trimestre", "Année"}, {{"Quantité", each List.Sum([Quantité.1]), type nullable number}}),
    Période = Table.AddColumn(#"Regroupement 2", "Période", each Number.ToText([Trimestre]*3,"00")&" "&Text.From([Année]))
in
    Période

EDIT
ou un peu plus simple avec des dates

let
    Source = Excel.CurrentWorkbook(){[Name="Conso_Carbu"]}[Content],
    Trimestre = Table.AddColumn(Source, "Trimestre", each #date(Number.From(Text.End([Période], 4)), 3*(Number.IntegerDivide(Number.From(Text.Start([Période],2))-1, 3)+1), 1), type date),
    #"Regroupement 1" = Table.Group(Trimestre, {"Immat. - Immat.", "Trimestre"}, {{"Quantité", each List.Sum([Quantité]), type number}}),
    Fusion = Table.NestedJoin(#"Regroupement 1", {"Immat. - Immat."}, #"Regroupement 1", {"Immat. - Immat."}, "Lignes groupées", JoinKind.LeftOuter),
    Developpement = Table.ExpandTableColumn(Fusion, "Lignes groupées", {"Trimestre", "Quantité"}, {"Trimestre.1", "Quantité.1"}),
    #"Filtre Trimestre+ Année" = Table.SelectRows(Developpement, each [Trimestre.1] <= [Trimestre] ),
    #"Regroupement 2" = Table.Group(#"Filtre Trimestre+ Année", {"Immat. - Immat.", "Trimestre"}, {{"Quantité", each List.Sum([Quantité.1]), type nullable number}}),
    Péiode = Table.AddColumn(#"Regroupement 2", "Période", each Date.ToText([Trimestre], [Format="MM yyyy"]))
in
    Péiode

Stéphane

Bonjour,

Merci c'est exactement cela 👏 merci beaucoup, je vais regarder comment vous avez fait

Cordialement,