Formule pour obtenir la N ème plus grosse valeur

Bonjour,

Je suis à la recherche d'une solution pour simplifier ou raccourcir une formule. Je souhaite obtenir la valeur associée à N, N étant déterminé par la cellule J3.

Les colonnes E:W représentent des diamètres de 15 à 105 avec une incrémentation de 5. Sur la ligne 7 (E7:W7), j’ai mes effectifs.

J’ai créé une formule qui vérifie si l’effectif est supérieur ou égal à J3. Si ce n’est pas le cas, elle calcule l’effectif cumulé avec la colonne suivante. La colonne de départ est W (du plus gros diamètre au plus petit).

Ma formule est répétitive et longue :

=SI(W7>=J3;W6;SI(SOMME(V7:W7)>=J3;V6;SI(SOMME(U7:W7)>=J3;U6;SI(SOMME(T7:W7)>=J3;T6;SI(SOMME(S7:W7)>=J3;S6;SI(SOMME(R7:W7)>=J3;R6;SI(SOMME(Q7:W7)>=J3;Q6;SI(SOMME(P7:W7)>=J3;P6;SI(SOMME(O7:W7)>=J3;O6;SI(SOMME(N7:W7)>=J3;N6;SI(SOMME(M7:W7)>=J3;M6;SI(SOMME(L7:W7)>=J3;L6;SI(SOMME(K7:W7)>=J3;K6;SI(SOMME(J7:W7)>=J3;J6;SI(SOMME(I7:W7)>=J3;I6;SI(SOMME(H7:W7)>=J3;H6;SI(SOMME(G7:W7)>=J3;G6;SI(SOMME(F7:W7)>=J3;F6;SI(SOMME(E7:W7)>=J3;E6;"ERR")))))))))))))))))))

Cordialement,

Bonjour,
Une proposition de ce que je comprends !
Cdlt.

=LET(
   n; J3;
   a; E6:W6;
   b; E7:W7;
   c; SCAN(PRENDRE(b; ; 1); b; SOMME);
   SIERREUR(INDEX(a; EQUIVX(n; c; 1));"pas de correpondance")
)

Bonjour à tous !

@Jean-Eric : Hello !

Et....

Une autre.....compréhension (sur la base du classeur fourni par Jean-Eric (merci !) :

=LET(
    e; E7:W7;
    t; SEQUENCE(; COLONNES(e); 0; -1);
    s; TRIERPAR(SCAN(0; TRIERPAR(e; t); SOMME); t);
    SI.NON.DISP(INDEX(E6:W6; ; EQUIVX(J3; s; 1; -1)); "ERR")
)

Les tests effectués retournent la même valeur que la formule originelle.

Bonsoir,

on peut aussi utiliser des formules basiques à condition de rajouter une ligne (ce que vous voulez peut-être éviter). Je me suis basé sur le fichier de Jean-Eric ;

On met ceci en E8 et on étire vers la droite ;

=SOMME(E7:$W7)

Et en F20 ;

=INDEX($E$6:$W$6;SOMMEPROD(MAX(($E$8:$W$8>=$J$3)*COLONNE($E$8:$W$8))-COLONNE($D$6)))

edit :

il y a plus simple pour remplacer ma 2ème formule ;

=INDEX($E$6:$W$6;EQUIV($J$3;$E$8:$W$8;-1))

Bonsoir,

pour le fun j'ai cherché un moyen avec les anciennes formules de se passer de ligne intermédiaire et j'ai trouvé ceci mais ça reste un peu long ;

=INDEX($E$6:$W$6;EQUIV(J3;CHOISIR(LIGNE(1:19);SOMME(E7:W7);SOMME(F7:W7);SOMME(G7:W7);SOMME(H7:W7);SOMME(I7:W7);SOMME(J7:W7);SOMME(K7:W7);SOMME(L7:W7);SOMME(M7:W7);SOMME(N7:W7);SOMME(O7:W7);SOMME(P7:W7);SOMME(Q7:W7);SOMME(R7:W7);SOMME(S7:W7);SOMME(T7:W7);SOMME(U7:W7);SOMME(V7:W7);W7);-1))

Bien la sauver en mode matriciel !