Automatisation cadencement échelon des agents contractuels FPT

Bonjour,

Je suis chargée rh, à partir de 2026 nous allons faire avancer en échelon nos agents contractuels au même titre que nos agents titulaires. J'ai créé un tableau de suivi ci-joint, mais je n'arrive pas à automatiser les colonnes en jaune. pouvez-vous m'aider et me conseiller pour améliorer mon tableau svp.

Bonjour

Pour la date on peut plutôt utiliser

=MOIS.DECALER(J4;12*K4)

Pour les autres colonnes il faudrait savoir si la grille indiciciaire est bien classée dans l'ordre des grades car cela ne semble pas correspondre à ce qui est dans certaines cellules

A priori il y a un problème concordance entre la colonne A et les colonnes F et G sur 5 lignes

Bonjour et bienvenue sur ce forum,

Pour la colonne IB actuelle, vous pourriez utiliser cette formule en H4

=INDEX(Variables!$A$5:$F$136;EQUIV($F4&"-"&G4;Variables!$A$5:$A$136;);4)

NB : je ne vois pas trop l'intérêt de vos deux colonnes en F et G puisque l'info se trouve déjà en colonne A. A voir de votre coté...

ou alors la formule comme ceci

=INDEX(Variables!$A$5:$F$136;EQUIV($A4;Variables!$A$5:$A$136;);4)

Formule, à recopier vers le bas

Pour la colonne IM, même formule mais en changeant le chiffre 4 par 5

Rem : dans votre feuille Variables, vous pourriez aussi mettre votre colonne A dans le tableau de droite. Par exemple en colonne D avec cette formule =B5&"-"&C5 ou alors mieux vous laissez l'info en colonne A avec la même formule =B5&"-"&C5

Crdlt

Re

edit :

Fil cloturé sans commentaires ??

MErci pour vos réponses, je vais prendre le temps d'y regarder attentivement, pourquoi fil cloturé?

re

pourquoi fil cloturé ?

Parce que vous avez cliqué sur le petit V à droite dans mon post à 10:25
En gros cela revient à informer que le fil est terminé pour vous et que les posts sur lesquels vous avez cliqué sur le petit V sont ceux qui ont résolu votre demande.

Mais bien entendu vous pouvez continuer sur le fil

Cordialement

Edit :
1. si vous voulez quelques info complémentaires sur la cloture de fils voyez ce lien --> https://forum.excel-pratique.com/s/goto/856807

2. Tant qu'à faire : En M4 je suppose que ce sera une formule du genre=G4 + 1 ?

ah non mince, je voulais juste vous montrer que j'avais vu !

merci pour les infos

ah non mince, je voulais juste vous montrer que j'avais vu !

Bon c'est pas grave, cela partait d'une bonne intention. J'ai édité mon post à ce sujet

Dites moi pour le reste

Merci encore pour vos retours, je viens de modifier avec vos conseils et je vous remercie.

En colonne M j'aimerais que ça me mette tout seul le prochain échelon d'avancement et que le must du must ça me fasse une alerte pour me dire que l'agent est arrivé au sommet des échelons possibles de son grade.

Pouvez-vous m'aider svp

Ci-joint mon fichier avec les modifications prises en compte.

En colonne M j'aimerais que ça me mette tout seul le prochain échelon d'avancement et que le must du must ça me fasse une alerte pour me dire que l'agent est arrivé au sommet des échelons possibles de son grade.

Donc si on prend le code C1-1, l'échelon max est bien le 11 ?

Déjà dans M4 vous pouvez utiliser cette formule pour vérifier si ce que cela renvoie est correct pour vous

=INDEX(Variables!$A$5:$F$136;EQUIV(F4&"-"&(G4+1);Variables!$A$5:$A$136;);3)

Bonjour,

Oui voici les sommets des grades :

J'ai mis la formule nickel, y aurait-il moyen que dans une colonne à côté, le positionnement suivant se mette à savoir pour C1-1 que ça note C1-2.

Après pour le sommet du grade pourquoi pas que ça note sommet ?

Bonjour

Après pour le sommet du grade pourquoi pas que ça note sommet ?

En M4, remplacez la formule que je vous ai donnée par celle ci-dessous

=SI($G4=NB.SI(Variables!B:B;"="&F4);"Sommet";INDEX(Variables!$A$5:$F$136;EQUIV(F4&"-"&(G4+1);Variables!$A$5:$A$136;);3))

y aurait-il moyen que dans une colonne à côté, le positionnement suivant se mette à savoir pour C1-1 que ça note C1-2.

Heu, je n'ai pas compris, la colonne M vous donne cela.. (si vous mettez en A4 --> C1-10 en colonne M vous aurez 11. Mais peut être voulez-vous avoir C1-11 ?

oui tout à fait svp

Voilà ce que j'ai fait

, mais j'aimerais que ça soit encore plus automatisé, car pour AM1-13 je dois le faire à la main et si vous avez des idées pour ne puis rien à inscrire à la main avec les années à venir?!

Re

Voilà ce que j'ai fait

Ok j'ai vu mais on aurait pu aussi faire sur la seule colonne M plutôt que de rajouter la colonne en N
Si intérêt, le formule en colonne M que je vous ai donnée dans mon post précédent devient celle-ci

=SI($G4=NB.SI(Variables!B:B;"="&F4);"Sommet";F4&"-"&INDEX(Variables!$A$5:$F$136;EQUIV(F4&"-"&(G4+1);Variables!$A$5:$A$136;);3))

mais j'aimerais que ça soit encore plus automatisé, car pour AM1-13 je dois le faire à la main et si vous avez des idées pour ne puis rien à inscrire à la main avec les années à venir?!

Non du tout ou alors je n'ai pas compris. Si vous recopiez la formule vers le bas, vous verrez que pour AM1-13, elle vous renvoie "Sommet"
Tout sur une seule colonne
Maintenant si vous voulez absolument garder deux colonnes il faut revoir mais à priori je ne vois aucun intérêt car les infos sont un peu redondantes
Exemple : M4 vous avez C1-2 et N4 -> 2. Le deux est déjà mentionné en M4 et le titre de la colonne mentionne "Grade suivant".

Dites-moi...

rem : ne me remettez pas un nouveau fichier avec votre réponse. Si besoin je vous le demanderai

Oui ça parait redondant, mais j'en ai besoin pour faire des extractions dans d'autres fichiers.

Juste en colonne O et P peut-on rajouter une formule de condition que si dans la colonne M, il y a noté sommet alors reprendre les infos de la colonne H pour o et I pour P

en colonne Q, il faudrait que l'année du prochain changement apparaissent et que si l'agent est au sommet du grade qu'un commentaire ressort " passage au grade supérieur".

Oui ça parait redondant, mais j'en ai besoin pour faire des extractions dans d'autres fichiers.

Ok. Mais est-ce normal que vous ayez AM1-Sommet au lieu de AM1-13 et la mention Sommet en colonne N ?

Juste en colonne O et P peut-on rajouter une formule de condition que si dans la colonne M, il y a noté sommet alors reprendre les infos de la colonne H pour o et I pour P

heu "Sommet" en colonne N non car colonne M vous avez les infos du grade tandis qu'en N pas ?
C'est plus simple pour les formules à venir que vous voudriez

en colonne Q, il faudrait que l'année du prochain changement apparaissent et que si l'agent est au sommet du grade qu'un commentaire ressort " passage au grade supérieur".

Là cela suppose que vous n'écrivez plus rien manuellement dans le cellule

ah oui bonne idée

en colonne M il faudrait que ça reprenne AM1-13

en colonne N que ça note sommet

et en colonne Q oui, je n'écrirais plus rien

Re

Voici les formules :
en M4 -->

=SIERREUR($F4&"-"&INDEX(Variables!$A$5:$F$136;EQUIV(F4&"-"&(G4+1);Variables!$A$5:$A$136;);3);$F4&"-"&$G4)

en N4 -->

=SI($G4=NB.SI(Variables!B:B;"="&F4);"Sommet";INDEX(Variables!$A$5:$F$136;EQUIV(F4&"-"&(G4+1);Variables!$A$5:$A$136;);3))

en O4 -->

=SI($N4="Sommet";$H4;INDEX(Variables!$A$5:$F$136;EQUIV($F4&"-"&$N4;Variables!$A$5:$A$136;);4))

en P4 -->

=SI($N4="Sommet";$I4;INDEX(Variables!$A$5:$F$136;EQUIV($F4&"-"&$N4;Variables!$A$5:$A$136;);5))

en Q4 -->

=SI($N4="Sommet"; "Passage au grade supérieur";"")

Crdlt