Comment obtenir le nom de la feuille contenant une cellule nommée

Dans un classeur multi feuilles dans lequel existent plusieurs cellules nommées, comment récupérer le nom de la feuille à laquelle appartient une cellule. Après avoir explorer toutes les noms :

' positionnement à "Cellule défaut" si existe
Dim NomCellule As String
Dim Nom As Name

'Liste des noms
For Each Nom In Names
NomCellule = Nom.Name
If NomCellule = "Cellule_Defaut" Then

Range("Cellule_defaut").Select

End If
Next Nom
...

la fonction Range("Cellule_defaut").Select provoque une erreur si la cellule (ex Cellule_defaut") n'appartient pas à la feuille active.
j'aurais donc besoin de récupérer le nom de la feuille contenant la cellule afin de changer la feuille active .

Merci d'avance pour vos conseils

bonjour GPtits, un essai

Sub PlageNommees()
     'positionnement à "Cellule défaut" si existe
     Dim Nom As Name, c As Range

     For Each Nom In ThisWorkbook.Names
          On Error Resume Next
          Set c = Nothing: Set c = Range(Nom.Name)
          On Error GoTo 0
          If Not c Is Nothing Then
               MsgBox "feuille : " & c.Parent.Name & vbLf & "Plage : " & c.Address, , Nom.Name
               Application.Goto Range(Nom.Name)
          End If
     Next

End Sub

Bonjour GPtits, BsAlv,

J'aurais plutôt fait sans boucle...

Sub Test()
Dim VersNom As String, rgVersNom As Range
   VersNom = "Toto"
   Set rgVersNom = Nothing: On Error Resume Next: Set rgVersNom = Range(VersNom): On Error GoTo 0
   If rgVersNom Is Nothing Then     ' suite du code si la plage rgVersNom N'EST PAS sélectionnable
      MsgBox "'" & VersNom & "' n'est pas une plage sélectionnable de cellules", vbCritical
   Else                             ' suite du code si la plage EST sélectionnable
      Application.Goto rgVersNom
   End If
End Sub

...

Merci Bart , l'essai est très satisfaisant et j'intègre donc ta solutions dans ma macro initiale

Cordialement

Merci aussi à "mafraise" ta solution fonctionne parfaitement et sa version sans boucle, est effectivement plus rapide si le nombre de cellules nommées est important.

Cordialement