Power Query : List. Sum?

Bonjour à tous,

J'ai vraiment besoin de votre aide sur un sujet que je n'arrive pas à maîtriser : la fameuse fonction List. Sum

Voici mon problème :

J'ai une liste de vendeur reprenant leur vente, par nature de produit et le moment de la vente.

Je souhaite ajouter une colonne pour avoir la valeur cumulée des ventes pour chaque vendeur.

Dans mon exemple, pour Marie, la dernière colonne est un cumul de toutes ses ventes.

J'ai trouvé sur le forum des exemples similaires mais impossible de les adapter à mon cas.... faut croire que je ne suis pas très douée.

Quelqu'un peut-il m'aider?

Ci-joint mon fichier :

Un grand merci par avance.

Petitejij

Bonjour,

Votre demande ne correspond pas trop au fichier. Vous ne souhaitez pas faire un total partiel mais un total par vendeur. Auquel cas j'utiliserai GroupBy. Par exemple :

let
    Source = Excel.CurrentWorkbook(){[Name="Tableau"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"vendeur", type text}, {"moment", type text}, {"nature evnte", type text}, {"prix", Int64.Type}, {"unité", Int64.Type}}),
    #"Personnalisée ajoutée" = Table.AddColumn(#"Type modifié", "TOTAL", each [prix]*[unité]),
    #"Lignes triées" = Table.Sort(#"Personnalisée ajoutée",{{"vendeur", Order.Ascending}}),
    #"Grouped Rows" = Table.Group(#"Lignes triées", {"vendeur"}, {{"Total par vendeur", each List.Sum([TOTAL]), type number}, {"1", each _, type table [vendeur=nullable text, moment=nullable text, nature evnte=nullable text, prix=nullable number, unité=nullable number, TOTAL=number]}}),
    #"Reordered Columns" = Table.ReorderColumns(#"Grouped Rows",{"vendeur", "1", "Total par vendeur"}),
    #"Expanded 1" = Table.ExpandTableColumn(#"Reordered Columns", "1", {"moment", "nature evnte", "prix", "unité", "TOTAL"}, {"moment", "nature evnte", "prix", "unité", "TOTAL"})
in
    #"Expanded 1"

Bonjour à tous !

Une autre approche ?

let
  Source = Excel.CurrentWorkbook(){[Name = "Tableau"]}[Content], 
  AjtTotal = Table.AddColumn(Source, "TOTAL", each [prix] * [unité]), 
  Jointure = Table.NestedJoin(
    AjtTotal, 
    {"vendeur"}, 
    AjtTotal, 
    {"vendeur"}, 
    "Caff Vendeur", 
    JoinKind.LeftOuter
  ), 
  CaffVendeur = Table.ReplaceValue(
    Jointure, 
    each [Caff Vendeur], 
    each List.Sum([Caff Vendeur][TOTAL]), 
    Replacer.ReplaceValue, 
    {"Caff Vendeur"}
  ), 
  TriVendeur = Table.Sort(CaffVendeur, {{"vendeur", 0}})
in
  TriVendeur

Bonjour Saboh12617 et JFL,

Un GRAND merci pour vos propositions !

Les 2 méthodes fonctionnent Nikel !

Encore merci pour vos réponse si rapide

Bon après-midi à tous les 2

Petitejiji

Bonjour à tous de nouveau !

Bien...

Je vous remercie de ce retour.