Transformation de données en h:m

Bonsoir,

J'ai un fichier ou les heures /minutes apparaissent comme ci-dessous :

3 hrs 30 min

2 hrs 12 min

Est-il possible de les transformer en 03:30:00 et 02:12:00 ?

bonsoir,

une proposition, pour une donnée à convertir se trouvant en A1

=TEMPSVAL(SUBSTITUE(SUBSTITUE(A1;" hrs ";":");" min";":00"))

mettre la cellule contenant la formule au format [hh]:mm:ss

Merci mais cela ne fonctionne que pour les cellules comportant hrs min. Dans les cellules où il n'y a que des minutes, la formule me les transforme en heures. Ex : 19 min donne 19:00:00.

Bonjour à tous,

Formule un peu bulldozer mais qui devrait gérer le cas des heures parfois non indiquées (du coup heure = 0) : (avec l'heure texte en O55)

=TEMPS(
SIERREUR(GAUCHE(O55;CHERCHE(" hrs";O55));0);
STXT(O55;SIERREUR(CHERCHE(" hrs";O55)+4;1);CHERCHE(" min";O55)-SIERREUR(CHERCHE(" hrs";O55)+4;1));
0)

Bonjour à tous,

=--(SUBSTITUE(SUBSTITUE(SI(ESTERREUR(CHERCHE("hrs";A1));"0 hrs "&A1;A1);" hrs";":");" min";""))
mettre un format heure

eric

PS : saboh12617, tu as un pb s'il n'y a pas de min. Ex "2 hrs"

Bonjour tout le monde,

La solution de Saboh ne fonctionne malheureusement pas s'il n'y a pas de minutes dans la cellule.
C'est dingue hein, Mister Bluff, que les solutions proposées ne fassent pas des choses que tu n'avais pas demandées ? La prochaine fois, essaie de présenter un peu mieux les différentes possibilités pour éviter le temps perdu (cf signature de Saboh).

Je n'ai pas le temps d'optimiser ça, mais ça a l'air de fonctionner pour le moment. Pour les minutes, j'ai bêtement repris le boulot de Saboh :

=TEMPS(SI(F2=SUBSTITUE(F2;"hrs";":");0;GAUCHE(F2;CHERCHE(" ";F2)));SI(F2=SUBSTITUE(F2;"min";":");0;STXT(F2;SIERREUR(CHERCHE(" hrs";F2)+4;1);CHERCHE(" min";F2)-SIERREUR(CHERCHE(" hrs";F2)+4;1)));0)

D'ailleurs Saboh, tu es arrivé une fois que j'avais déjà décroché, mais je suis régulièrement tes interventions. Bravo pour leur qualité et ta patience !

Edit : Hello eriiic ! Bien joué :)

Re-salut à tous,

@21Formatic, je te remercie pour tes gentils mots, et pour dire la vérité j'apprécie tes propositions pour des problèmes souvent difficiles que tu prends le temps de résoudre, là où je n'ose pas me lancer. Bravo 🏓

Bon, pour revenir sur le sujet vous avez vu juste, j'ai supposé que les minutes étaient indiquées.

>> J'aime bien la solution de @Eric, super efficace, + simple et + court !

Bonne journée à tous

Juste pour vous saluer tous ,

La formule de eriiic (que je salue ) un tout petit peu raccourcie (c'est pour dire que j'ai bossé dur ) :

=1*(SUBSTITUE(SUBSTITUE(REPT("0 hrs ";NB.SI(A1;"*hrs*")=0) & A1;" hrs";":");" min";""))

Belle formule eriiic.

Je crois bien me souvenir qu'Excel 2007 n'avait pas la fonction SiErreur() ; d'ailleurs eriiic s'en est rappelé.

Bonsoir j'ai essayé la solution de Eriiic qui fonctionne bien. Mais je vais utiliser les autres pour voir. Pour ma part je suis incapable de créer de telles formules. Alors merci pour votre aide.