Insertion de crochets
Bonsoir
Je souhaite avoir une formule qui me permet d'insérer (sur Mac) des crochets. Voir fichier Excel ci joint
Merci pour votre aide
Bonsoir à tous !
Une proposition en K5 ? :
=J$3-J5 & " ["&L5&"]"A étirer vers le bas.
Bonjour,
D'accord avec JFL sur ce début de formule mais, car il y a toujours un "mais" 😜, si on regarde ton exemple et la formule proposée on s'aperçoit qu'il manque le signe "+" en début de résultat de la formule si la soustraction est positive.
Pas difficile à ajouter en complétant la formule donnée mais là je suis sur mon smartphone. Si pas de retour avant que je sois sur mon PC je te fais ça.
Re
Comme promis tu trouveras en PJ ma proposition de formules pour obtenir le résultat demandé sans utiliser les colonnes K et L.
En bonus je te mets également ma proposition de formules pour obtenir le résultat demandé sans utiliser les colonnes J, K et L.
Selon ce que tu retiens il ne te reste plus qu'à supprimer les colonnes superflues.
Remarque : si la soustraction est égale à 0 alors aucun signe ne s'affichera devant. Ni + ni -.
Teste et dis-nous.
Bonjour à tous,
Une autre formule : =TEXTE(J$3-J5;"+0;-0;0")&" ["&J5&"]"
Ou en plus lisible : =CONCAT(TEXTE(J$3-J5;"+0;-0;0");" [";J5;"]")
...
Bonjour,
@Alex020181 : Vous êtes nouvellement inscrit sur ce fourm. Ce serait intéressant que vous mettiez à jour votre profil de compte en y mentionnant votre version excel.
Merci de votre participation
Je souhaite avoir une formule qui me permet d'insérer (sur Mac) des crochets.
Une autre -->
=SI($J$3-J5<0; $J$3-J5 & " [" & J5 &"]";"+" & $J$3-J5 & " [" & J5 &"]")Je n'ai pas pu encore vérifier sous MAC, mais bon la formule Texte proposée par Mafraise me semble la plus simple et si je ne me trompe elle fonctionnera
Si ok merci de cloturer votre fil
Cordialement
Bonjour,
Une autre proposition.
Cdlt.
=LET(a; SOMME(F5:I5); b; $J$3 - a; TEXTE(b; "+0;-0") & TEXTE(a; """ [""0""]"""))Bonjour à tous !
Pour le "fun", une approche type formule unique dynamique en K5 :
=LET(
_j3;J3;
_pg;F5:I7;
EXCLURE(REDUCE("";SEQUENCE(LIGNES(_pg));LAMBDA(a;c;ASSEMB.V(a;TEXTE(_j3-SOMME(CHOISIRLIGNES(_pg;c));"+0;-0;0")&" ["&SOMME(CHOISIRLIGNES(_pg;c))&"]")));1)
)Elle retourne ceci :
Remarque : En souhaitant que l'environnement MAC ne pénalise pas la démarche.....
Re,
Une petite mise à jour !...
Cdlt.
=LAMBDA(valeurs;seuil; LET(a; BYROW(valeurs; SOMME);b; seuil - BYROW(a; SOMME);TEXTE(b; "+0;-0") & TEXTE(a; """ [""0""]""")))(F5:I7;J3)Bonjour à tous de nouveau !
Une petite mise à jour !
=LET(s;BYROW(F5:I7;SOMME);TEXTE(J3-s;"+0;-0")&" ["&s&"]")Re,
Voilà, c'est plus court, plus compréhensible pour le quidam !... 😊
Cdlt.
Bonjour
Merci à tous et merci aussi au team EXCEL-PRATIQUE pour votre feedback
Ca me convient parfaitement
Bonjour à tous !
Je vous remercie de ce retour.