Fonction si ou autre solution

Le 13/02/2025 à 23:23

Bonjour à tous, nouveau sur ce forum je tiens à vous remercier par avance pour l'aide que vous pourrez, peut-être apporter à mon problème.

J'ai beau chercher des solutions dans les fonctions mises à disposition, je pense que mon souci tient du fait de mon approche qui n'est pas forcément dans la logique d'un utilisateur d'Excel confirmé.

Voilà, j'ai un tableau qui me sert à référencer mon stock entre deux lieux.

Afin de faciliter le référencement, je dois trouver une solution pour qu'en entrant deux valeur, l'une étant une date, l'autre un lieu nommé "SD" ou "RA". En fonction d'une autre colonne, si celle ci contient un numéro de série, alors cela doit automatiquement une réponse au besoin "OK" si il est à sa place ou Remplacer" si il ne l'est pas.

Voici mon tableau en partie pour la section concernée :

capture d ecran 2025 02 13 230046

Le Num D87822 n'a pas de numéro de série attribué. Tous les produits sont nommé dans la colonne D.

La colonne K indique si oui ou non il ont un numéro de série.

L indique la date de placement.

M le lieu "SD" ou "RA"

N l'action à effectuer.

Pour faire plus simple, Seule la colonne M doit être remplie à la main pas SD ou RA. et en fonction cela doit automatiquement inscrire OK ou REMPLACER dans la colonne N.

- Si numéro de série en K, et que RA est entré à la main dans M, alors cela doit indiquer automatiquement OK en colonne N.

- Si pas de numéro de série en K, et que RA est entré à la main dans M, alors cela doit indiquer automatiquement REMPLACER en colonne N.

de même à l'inverse pour le lieu...

Si numéro de série en K, et que SD est entré à la main dans M, alors cela doit indiquer automatiquement REMPLACER en colonne N.

Si pas de numéro de série en K, et que SD est entré à la main dans M, alors cela doit indiquer automatiquement OK en colonne N.

J'ai essayé les Fonctions SI dans tous les sens sans vraiment obtenir quelque chose qui marche.

Merci de votre lecture et de vos retours,

En pouvoir trouver une solution qui puisse me faire gagner un temps considérable.

Le 14/02/2025 à 05:38

Bonjour,

Essayez ceci:

=SI(OU(ET(K2="";M2="SD");ET(K2<>"";M2="RA"));"OK";SI(OU(ET(K2<>"";M2="SD");ET(K2="";M2="RA"));"REMPLACER"))

Cdlt

Le 14/02/2025 à 15:37

Comment dire... Cela parait tellement simple mais sans votre aide je n'y serai jamais arrivé. Ca marche parfaitement un fois remplacer les lettre des cases par [@[Num Serie]] et [@[SD / RA]] (car le tableau est déjà créé). C'est parfait, à l'exception d'un détail, cela marque toujours "FAUX" dans la colonne lorsque SD ou RA n'est pas encore indiqué.

Peut-on y faire quelque chose ?

J'ai réussi à le faire sur la moitié de la formule en essayant cela...

=SI(OU(ET([@[Num Serie]]="";[@[SD / RA]]="BL");ET([@[Num Serie]]<>"";[@[SD / RA]]="OFF"));"OK";"")

Mais pas sur l'intégralité de la formule...

Le 14/02/2025 à 16:07

Bonjour à tous,

......ET(K2="";M2="RA"));"REMPLACER"))

Apres remplacer, tu mets ;"")

ET(K2="";M2="RA"));"REMPLACER";""))

Crdlmt

Le 14/02/2025 à 16:25

Arturo83, DjiDji59430, Un grand Merci... c'est très gentil à vous.

Au risque maintenant d'abuser de votre gentillesse je découvre un nouveau problème.

J'ai du stock endommagé, perdu ou volé (hélas ça arrive) et bien évidement il ne peut être compris dans le stock à déplacer puisqu'il n'est plus présent. Dans la colonne O j'ai indiqué les infos de sortie de stock pour une raison lambda... Est-il possible avec cette formule de lui en rajouter une couche pour dire qu'il mette "OK" obligatoirement si les mots VOL, SORTI par exemple apparaissent dans cette colonne (même si par exemple il est indiqué VOL le xx/xx/xxxx). Ou bien peut être devrais-je faire une nouvelle colonne dans mon tableau, par exemple P qui indiquerait des mots précis et courts pour que le OK apparaisse automatiquement SI cette colonne l'affiche ou non

Le 14/02/2025 à 16:52

Bonjour,

Oui c'est possible, mais pouvez-vous partager un fichier d'exemple type et préciser sur votre profil votre version d'excel ? 2016/2021/365… ?

Je vous le demande car il y a surement moyen de "simplifier" la formule avec ces informations en plus.

Pour trouver un mot dans une phrase on peut utiliser CHERCHE, fonction - Support Microsoft.

Le 14/02/2025 à 18:31

Merci Saboh12617, Oui, c'est effectivement la meilleure Idée.

Je partagerai bien mon fichier mais je n'en ai pas encore la permission, pas assez de messages échangés pour le moment.

Et ma version d'Excel est la 2021 Pro. De mon côté, je cherche, je cherche, en faisant des exercices les uns après les autres pour tenter de comprendre... mais il me manque la logique... Ca viendra ;)

Encore merci par avance à tous

Le 14/02/2025 à 19:10

Bonjour à tous,

Ta version d'excel, il faut la mettre dans ton profil ! (remplacer "française" par "Excel 2021 Pro)

Crdlmt

Le 14/02/2025 à 19:38

Done

Le 14/02/2025 à 20:40

Je pense avoir trouver, enfin ça semble marcher... Vos avis sont les bien venus.

Encore merci à tous pour votre aide précieuse

=SI(ET(OU([@[SD / RA]]="RA";[@[SD / RA]]="SD");
OU(ET([@[Num Sorti]]<>"";[@Out]="";[@[SD / RA]]="SD");
ET([@[Num Sorti]]<>"";[@Out]="OUT";[@[SD / RA]]="SD");
ET([@[Num Sorti]]<>"";[@Out]="";[@[SD / RA]]="RA");
ET([@[Num Sorti]]<>"";[@Out]="OUT";[@[SD / RA]]="RA");
ET([@[Num Sorti]]="";[@Out]="";[@[SD / RA]]="SD");
ET([@[Num Sorti]]="";[@Out]="OUT";[@[SD / RA]]="SD");
ET([@[Num Sorti]]="";[@Out]="";[@[SD / RA]]="RA");
ET([@[Num Sorti]]="";[@Out]="OUT";[@[SD / RA]]="RA")));
SI(ET([@[Num Sorti]]<>"";[@Out]="";[@[SD / RA]]="SD");"REMPLACER";
SI(ET([@[Num Sorti]]<>"";[@Out]="OUT";[@[SD / RA]]="SD");"OK";
SI(ET([@[Num Sorti]]<>"";[@Out]="";[@[SD / RA]]="RA");"OK";
SI(ET([@[Num Sorti]]<>"";[@Out]="OUT";[@[SD / RA]]="RA");"REMPLACER";
SI(ET([@[Num Sorti]]="";[@Out]="";[@[SD / RA]]="SD");"OK";
SI(ET([@[Num Sorti]]="";[@Out]="OUT";[@[SD / RA]]="SD");"OK";
SI(ET([@[Num Sorti]]="";[@Out]="";[@[SD / RA]]="RA");"REMPLACER";
SI(ET([@[Num Sorti]]="";[@Out]="OUT";[@[SD / RA]]="RA");"REMPLACER";""))))))));"")

Le 21/02/2025 à 09:01

Bonjour à tous,

Juste pour info, si la formule de @Arturo complétée par @Djidji vous convenait, et qu'il suffisait juste de rajouter les vols/sortie (que je ne vois pas dans votre dernier post), je pense que l'adaptation ci-dessous vous conviendrait :

Je vous laisse traduire ça sur votre tableau structuré mais a priori, ça me semble plus simple. Votre solution à l'air correcte mais il y a énormément de redondance dans les conditions, et surtout empiler les "SI" comme ça rend vite la formule difficile à déboguer.

=SI.CONDITIONS(
SOMME(SIERREUR(CHERCHE({"VOL";"SORTI"}; O2); 0))>0; "OK";
OU(ET(K2=""; M2="SD"); ET(K2<>""; M2="RA")); "OK";
OU(ET(K2<>""; M2="SD"); ET(K2=""; M2="RA")); "REMPLACER";
VRAI;"")
Rechercher des sujets similaires à "fonction solution"