Texte vs Nombre
J'ai un chiffrier qui contient des cellules dont le nombre se termine par un C pour Crédit (ex: 382.89C). Donc ces cellules ne sont plus une valeur mais bien du texte.
1. Comment remplacer le C final ( 382.89C) par un Moins (-) en avant (-382.89) du texte dans la cellule.
2. Comment changer toutes ces cellules de Texte à Nombre.
J'ai tenté de le faire par une simple formule sans faire de VBA mais en vain!
Bonsoir à tous !
Et.....
Une proposition pour retraiter une valeur A1 :
=VALEURNOMBRE(SUBSTITUE(A1;"C";"");".")*-1Bonsoir à tous,
2 autres propositions.
=-SUBSTITUE(SUBSTITUE(A1;"C";"");".";",")ou
=-SUBSTITUE(GAUCHE(A1;NBCAR(A1)-1);".";",")Cordialement.
Merci pour les réponses.
J'y étais presque mais là je crois que votre aide sera très utile.
Je fais les tests et je vous reviens.
Merci encore.
MDO100 et JFL,
vos formules fonctionnent pour les cellules là où j'ai des montant avec un C mais par contre dans cette colonne j'ai aussi des montants en positif qui n'ont pas de C au bout et qui sont déjà des nombres et qui se changent en négatif lorsque j'applique les formules.
Je dois être capable d'appliquer cette formule dans tout la colonne et non seulement au montant en C comme Si le montant a un C a la fin, met un moins en avant et change le en nombre sinon laisse le nombre tel quel.
Dans ma formule j'utilisais "Si'' ''Droite'' " Substitue" Sinon A1 mais j'oublie surement qque chose car ça fonctionne que partiellement.
Voici ma formule qui ne fonctionne pas mais je sais aussi que je devrais la commencer avec VALEURNOMBRE.:
=SI(DROITE(A1)="C";"-"&(A1);(SUBSTITUE(A1:"C";"");A1))
Bonjour,
Essaie ainsi :
Re @Richard Gauthier,
A tester:
=SI(DROITE(A1;1)="C";-SUBSTITUE(SUBSTITUE(A1;"C";"");".";",");A1)ou
=SI(DROITE(A1;1)="C";-SUBSTITUE(GAUCHE(A1;NBCAR(A1)-1);".";",");A1)Cdlt.
Bonjour à tous !
vos formules fonctionnent pour les cellules là où j'ai des montant avec un C mais par contre dans cette colonne j'ai aussi des montants en positif qui n'ont pas de C au bout et qui sont déjà des nombres et qui se changent en négatif lorsque j'applique les formules.
C'est pourquoi nous ne cessons de réclamer un classeur exemple représentatif !
Proposition amendée, dans un esprit similaire à celle de Jean-Eric (Hello !) :
=LET(t;A1;v;VALEURNOMBRE(SUBSTITUE(t;"C";"");".");SI(DROITE(t)="C";-v;v))Merci à vous tous, les formules fonctionnent toutes. mais je devrai y ajouter une autre condition, si la cellule est vide, je ne veux pas de "0" =SI(M71=0;" ";M71).
Lorsque je l'ajoute dans les formules que vous m'avez envoyées, un Pop-Up me dit que j'ai trop de conditions.
Re @Richard Gauthier,
A tester:
=SI(DROITE(A1;1)="C";-SUBSTITUE(SUBSTITUE(A1;"C";"");".";",");SI(A1="";"";A1))ou
=SI(DROITE(A1;1)="C";-SUBSTITUE(GAUCHE(A1;NBCAR(A1)-1);".";",");SI(A1="";"";A1))Cdlt.
Bonjour à tous de nouveau !
Troisième contrainte.......
La valeur 0 peut être utilement masquée via un format personnalisé : 0,00;-0,00;
Quelle est la source de vos données ?
Gros merci à tous.
Problème résolu à 100%
Bonjour à tous de nouveau !
Je vous remercie de ce retour.
Et sinon...pour la source de vos données ? Je subodore une source externe qui pourrait être retraitée automatiquement via Power Query (fonctionnalité nativement intégrée dans Excel depuis 2016)