Formule index equiv grande valeur
Bonjour,
Cela fait plusieurs jours que je cherches désespérément la réponse a ma question.
Le contexte, je fais des stats pour mon groupe de jeu. Je renseigne donc manuellement des données, nombre d'attaque gagné / nombre d'attaque total, ce qui me donne mon pourcentage. Grâce a ca, je peux faire mon podium via la formule recherchex(grande.valeur) ou index(equivx/equiv(grande.valeur). Si tous le monde a des résultats différents pas de souci mes formules fonctionnes parfaitement.
Cependant, actuellement j'ai plusieurs personne ayant le même résultat en pourcentage. Les formules n'indiques qu'une seul personne dans la case. Je cherches a avoir l'intégralité des noms ayant la même valeur dans la même case.
Voici mes formules,
=INDEX($A$3:$A$22;EQUIVX(GRANDE.VALEUR($E$3:$E$22;1);$E$3:$E$22;2;1))
=RECHERCHEX(GRANDE.VALEUR(E3:E22;1);E:E;A:A)
La colonne A sont les noms des joueurs, la colonnes E sont les pourcentages.
Si quelqu'un a la solution, je suis preneur,
Merci beaucoup !
Bonjour à tous !
Et......
Une approche possible pour Q36 :
=LET(
m; TRIER(A3:E22; 5; -1);
JOINDRE.TEXTE(" / "; ; FILTRE(PRENDRE(m; ; 1); PRENDRE(m; ; -1) = GRANDE.VALEUR(UNIQUE(PRENDRE(m; ; -1)); 1)))
)Note : le dernier "1" de la formule correspond au rang recherché.
Bonjour,
Vous pouvez utiliser des fonctions dynamiques pour ce genre de choses.
Pour récupérer le(s) meilleurs scores, vous pouvez utiliser FILTRE :
=FILTRE($A$3:$A$22;$E$3:$E$22=GRANDE.VALEUR($E$3:$E$22;1))Pour récupérer directement les 3 meilleurs scores, vous pouvez utiliser TRIERPAR
=PRENDRE(TRIERPAR($A$3:$A$22;$E$3:$E$22;-1);3)Il suffit ensuite de piocher dans ces résultats pour votre podium (la 2e formule vous donne le podium).
Merci beaucoup, ca indique bien ce que je cherche.
Je ne connaissais pas du tous les formules indiqués.
Je laisse encore ouvert pour voir s'il y a d'autre proposition :)
Merci pour votre retour.
Une note importante : la formule de JFL tient compte des doublons dans le tableau des noms (et les exclus) pour éviter d'avoir plusieurs fois la meme personne sur le podium. Je n'ai pas fait cette vérification.
Pour le fun, une petite formule qui groupe vos joueurs par score
=LET(joueurs;$A$3:$A$22;scores;$E$3:$E$22;
scoreUnq;TRIER(UNIQUE(scores);;-1);
REDUCE({"Score"\"Joueur(s)"};scoreUnq;LAMBDA(acc;score; ASSEMB.V(acc;
ASSEMB.H(TEXTE(score;"0%"); JOINDRE.TEXTE(" / ";VRAI; FILTRE(joueurs;scores=score;"rien"))))))
)Merci beaucoup pour vos réponse.
J'aime beaucoup vos 2 formules (même si j'avoue ne pas les comprendre pour le moment, je ne les connaissaient pas du tous ).
Saboh, votre formule est un peu plus pratique a utiliser mais ne permet pas de l'utiliser dans une cellule fusionné. Celle de JFL est plus complexe mais me permet d'avoir l'info que je cherche en gardant ma cellule fusionné.
Pour la formule =LET(joueurs;$A$3:$A$22;scores;$E$3:$E$22;
scoreUnq;TRIER(UNIQUE(scores);;-1);
REDUCE({"Score"\"Joueur(s)"};scoreUnq;LAMBDA(acc;score; ASSEMB.V(acc;
ASSEMB.H(TEXTE(score;"0%"); JOINDRE.TEXTE(" / ";VRAI; FILTRE(joueurs;scores=score;"rien"))))))
)
J'ai fais un copier coller sur mon fichier, mais je n'ai pas encore bien compris comment la décripter.
En tous cas encore merci, vous avez résolut mon soucis en quelques minutes, la ou j'y suis depuis des jours :)
Bonjour à tous de nouveau !
Bien....
Je vous remercie de ce retour.
@sabo12617 : Hello !
=ASSEMB.V({"Score"."Joueurs"};GROUPER.PAR(E3:E22;A3:A22;TABLEAU.EN.TEXTE;;0;-1))Bonjour à tous de nouveau !
Bien....
Je vous remercie de ce retour.
@sabo12617 : Hello !
=ASSEMB.V({"Score"."Joueurs"};GROUPER.PAR(E3:E22;A3:A22;TABLEAU.EN.TEXTE;;0;-1))
J'étais sur que c'était possible... Mais je n'arrive pas à utiliser GROUPER.PAR...
@Alliouf, oui je sais bien, c'est pourquoi j'indiquais "Il suffit ensuite de piocher dans ces résultats" (mettre le résultat quelque part et utiliser des "=" par exemple). Tout dépend de l'usage. Mais à vrai dire la formule de @JFL vous évitera les problèmes de doublons donc je la privilégierai.
Bonjour à tous de nouveau !
J'étais sur que c'était possible... Mais je n'arrive pas à utiliser GROUPER.PAR...
Persistez ! Trompez-vous ! Encore et encore.... La (humble) maîtrise viendra.
Je viens de comprendre, je bloquais sur le 3e argument et c'est celui que tu as utilisé dont j'ai le plus besoin. Parfait un grand merci ! Ca m'évitera de trainer des REDUCE à ralonge. Bonne journée.