Formule prorata mois

bonjour

Je cherche a faire un tableau pour avoir le prorata du montant HT, par mois en fonction de la durée du chantier (début et fin).

Merci

Bonjour tfoot2002 et bienvenue sur XLP,

Une proposition de formule pour O365. La formule est en D2 (à recopier vers la droite et vers le bas) :

=SOMME(1*ESTNUM(EQUIV(SEQUENCE($C2-$B2+1;;$B2);SEQUENCE(JOUR(D$1);;FIN.MOIS(D$1;-1)+1);0)))*$A2/($C2-$B2+1)

nota : cette formule doit aussi fonctionner pour d'autres versions d'Excel si elles disposent de la fonction SEQUENCE().

Merci beaucoup pour 2 choses :

rapidité et efficacité !!!

Re,

Pour ceux qui ne disposent pas de la fonction SEQUENCE(), voici une autre formule qui doit fonctionner pour toutes les versions d'Excel.

Ne disposant plus que de O365, je ne peux pas tester cette formule. Je pense que cette formule nécessite une validation matricielle sur les anciennes versions d'Excel. On a remplacé la fonction SEQUENCE() par la fonction LIGNE(INDIRECT(...))

La formule en D2 est à valider matriciellement avec la combinaison des trois touches Ctrl+MAj+Entrée au lieu de la seule touche Entrée, puis à recopier vers la droite et vers le bas :

=SOMME(1*ESTNUM(EQUIV(LIGNE(INDIRECT($B2 & ":" & $C2));LIGNE(INDIRECT((FIN.MOIS(D$1;-1)+1) & ":" & D$1));0)))*$A2/($C2-$B2+1)

Bonjour à tous !

Pour le "fun", une proposition type "formule unique dynamique" :

Deux variables sont à adapter : mP (matrice des Mois) et MD (matrice des Données).

=LET(
    mM; $E$3:$K$3;
    mD; B4:D7;
    MAKEARRAY(
        LIGNES(mD);
        COLONNES(mM);
        LAMBDA(l;c;
            LET(
                dd; INDEX(mD; l; 2);
                nJ; INDEX(mD; l; 3) - dd + 1;
                sj; SEQUENCE(nJ; ; dd);
                ARRONDI(NB(FILTRE(sj; (sj > FIN.MOIS(INDEX(mM; ; c); -1)) * (sj <= INDEX(mM; ; c)); "")) * INDEX(mD; l; 1) / nJ; 2)
            )
        )
    )
)

Bonjour ,

Belle formule JFL !

On a quand même affaire à des tueurs en Excel ou power query.

Merci à tous pour votre aide, qui permet de faire avancer les novices.