Valeurs selon une période définie
Bonjour,
Serait-il possible de modifier les valeurs en fonction d'un nombre de jours précis ?
J'ai, par exemple, une période de données s'étalant sur 25 jours, mais j'aimerais obtenir certaines valeurs figurant en haut des lignes 8, 9 et 10 pour les 7 derniers jours uniquement, plutôt que pour l'ensemble des 25 jours.
J'ai tenté d'expliquer cela dans le tableau.
Je vous remercie par avance pour votre aide.
Cependant, il me semble (mes connaissances étant limitées) que cela pourrait ne pas être réalisable.
Bonjour,
C'est possible en utilisant la fonction DECALER avec hauteur de ligne en remplacement de la plage E12:AB378, par exemple pour le nombre de mesures ou la moyenne :
=NB(DECALER(E12:AB12;;;C9))
OU
=MOYENNE(DECALER(E12:AB12;;;C9))Précisez exactement les cellules ou vous voulez agir avec les formules actuelles.
Bonjour,
Tout d'abord, merci pour votre aide
Je ne parviens pas à comprendre, j'ai assimiler que dans la cellule C9 il devrait y avoir le nombre de jours mais dans mon tableau possède des formules complexes.
comment placer =NB(DECALER(E12:AB12;;;C9)) OU =MOYENNE(DECALER(E12:AB12;;;C9))
les formules qui doivent changées sont en ligne 8 - 9 et 10 en fonction de C9 soit :
Ecart-type ; formule → =ECARTYPE(E12:AB378)
Coefficient de variation ; → =AM3/S8*100 / dans AM3 → =ECARTYPE(E12:AB378)
et dans la cellule S8 → =SI(ESTERREUR(MOYENNE(E12:AB378));"";MOYENNE(E12:AB378))
Nb de mesure ; =AM8 / dans AM8 → =SOMMEPROD((E12:AB378<>"")*1)
Moyenne ; → =SI(ESTERREUR(MOYENNE(E12:AB378));"";MOYENNE(E12:AB378))
HBA1c ; → =((MOYENNE(AC12:AC228) + 46,7) / 28,7)
Petite valeur ; = AM7 / dans AM7 → =MIN(E12:AB378)
grande valeur ; AN7 / dans AN7 → =MAX(E12:AB378)
les moyennes -> à jeun → =SI(ESTERREUR(MOYENNE(K12:O378));"";MOYENNE(K12:O378))
avant repas → =SI(ESTERREUR(MOYENNE(P12:Y378));"";MOYENNE(P12:Y378))
au coucher → =SI(ESTERREUR(MOYENNE(Z12:AB378));"";MOYENNE(Z12:AB378))
comment intégrer =NB(DECALER(E12:AB12;;;C9)) OU =MOYENNE(DECALER(E12:AB12;;;C9))
Merci pour votre aide
Bonjour de nouveau,
Et bien un début pour le moment, est-ce ok ?
en AM3 et G8 Ecart-type :
=ECARTYPE(DECALER(E12:AB12;;;C9))en M8 nombre de mesures :
=NB(DECALER(E12:AB12;;;C9))en S8 moyenne :
=SI(ESTERREUR(MOYENNE(DECALER(E12:AB12;;;C9)));"";MOYENNE(DECALER(E12:AB12;;;C9)))en AA8 HbA1c pourquoi AC12:AC228 et pas AC12:AC378 ?
Je n'ai pas fait le reste pour l'instant
Merci pour le travail fourni.
En ce qui concerne AA8 HbA1c, pourquoi AC12:AC228 et pas AC12:AC378 ? Initialement, le tableau commençait le 1er janvier, par conséquent, j'ai commencé à travailler sur les formules sur une année. Mais comme celui-ci a commencé le 5 septembre, AC228 correspond au 31 décembre.
Pardonnez moi, mais lorsque vous saisissez en C9 le nombre de jours, le tableau calcule-t-il à partir du début ou en partant de la dernière ligne ?
Bonsoir BeGood,
Je suis également en train d'examiner votre proposition et je constate que la formule DECALER s'applique à partir de la ligne 12 (soit du début), et non en commençant par la fin.
Étant donné qu'il s'agit d'une évolution de la maladie, le travail consiste à prendre les dernières saisies et à remonter sur une période de 7 jours, ou plus.
Pensez-vous que cela soit réalisable ?
Re,
Arf ! je n'avais pas fait attention au fait qu'il s'agissait des dernières lignes.
On doit pouvoir remplacer le DECALER par celui-ci, (il y a peut-être mieux) :
DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9)Vérifiez sur les formules précédentes si ok
Bonsoir,
une ÉNORME MERCIIIIIIIIIII
j'ai saisie toutes les formules, ça fonctionne très bien.
Il me reste juste 3 cellules où je ne parviens pas à saisir la fonction DECALER.
2 cellules NB.SI
→ =NB.SI(AC12:AC378;">120") → si au-dessus de 120
→ =NB.SI.ENS(AC12:AC378;">=80";AC12:AC378;"<=120") → si entre 80 et 120
et la 3e cellule correspond au nombre de contrôles effectués → =SOMMEPROD((E12:AB378<>"")*1)
et le tableau, grâce à votre aide, sera alors fonctionnel.
merci encore
Bonsoir,
En M8 :
=NB(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9))En AC8 :
=NB.SI(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);">120")En AC10 :
=NB.SI.ENS(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);">=80";DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);"<=120")On ne doit plus être loin maintenant ?
Bonjour,
désolé de répondre seulement maintenant, je viens de prendre connaissance de vos formules
Je vous remercie une nouvelle fois pour le travail réalisé.
Concernant les formules fournies, la formule en M8 =NB(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9)) fonctionne très bien.
Je rencontre un problème avec le calcul des colonnes AC8 et AC10.
Il devrait y avoir pour 25 jours 13 valeurs si → au dessus de 120 dans AC8 et 12 valeurs si → valeurs comprises entre 80 et 120 dans AC10
C'est uniquement sur cette colonne AC (moyenne du jour) que le calcul s'effectue, si le nombre de jours est placé en C9.
En AC8 : =NB.SI(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);">120") → j'ai 67 au lieu de 13
En AC10 : =NB.SI.ENS(DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);">=80";DECALER(E12:AB12;EQUIV("";AC12:AC378;0)-2;;-C9);"<=120") → j'ai 42. au lieu de 12 sur 25 jours
J'essaie de comprendre la raison pour laquelle E12:AB12 est utilisé et d'apporter les modifications nécessaires afin de trouver la formule appropriée, mais je n'y parviens pas.
En effet, vous avez raison ; si ce problème est résolu, alors vous aurez réussi à finaliser le tableau.
Quoi qu'il en soit je vous remercie.
Je pense que la formule devrait presque ressembler à AA8,
=((MOYENNE(DECALER(AC12:AC378;EQUIV("";AC12:AC378;0)-2;;-C9))+46,7)/28,7)car vous utiliser que la colonne AC comme référence, sauf que dans mon cas il doit juste comptabiliser en AC8 les valeurs au dessus de 120 en fonction de C9 et en AC10 comprise entre 80 et 120.
je bidouille, mais je ne trouve pas
=NB.SI.EN(DECALER(AC12:AC378;EQUIV("";AC12:AC378;0)-2;;-C9;">120")))
=NB.SI.EN(DECALER(AC12:AC378;EQUIV("";AC12:AC378;">120")-2;;-C9)))
Rien à faire, c'est un Level bien au dessus
Bonjour,
1) Effectivement, pour AC8 et AC10 il ne faut pas prendre la plage E12:AB12 mais uniquement AC12:AC378
2) On peut simplifier légèrement les formules DECALER en remplaçant partout EQUIV("";AC12:AC378;0)-2;;-C9 par NB(AC12:AC378)-1
ce qui donne :
pour AC8
=NB.SI(DECALER(AC12:AC378;NB(AC12:AC378)-1;;-C9);">120")
et pour AC10
=NB.SI.ENS(DECALER(AC12:AC378;NB(AC12:AC378)-1;;-C9);">=80";DECALER(AC12:AC378;NB(AC12:AC378)-1;;-C9);"<=120")Vous pouvez faire cette modif (NB remplace EQUIV) partout dans vos autres formules
J'avais noté également que dans le dernier fichier transmis la formule en S8 était erronée (formule DECALER à modifier)
On approche !
Bonsoir,
merci cela fonctionne très bien.
et merci pour l'astuce NB
je ne rencontre pas un problème en S8 mais en S9 je viens de m'en rendre compte. toutes les formules sont OK sauf celle-ci
=NB.SI.ENS((DECALER(E12:AB12;;;C9));">=80";(DECALER(E12:AB12;;;C9));"<=120")
Merci mille fois pour votre disponibilité
J'ai essayer ceci grâce à vos formules
=NB.SI.ENS(DECALER(E12:AB12;NB(AC12:AC378)-1;;-C9);">=80";DECALER(E12:AB12;NB(AC12:AC378)-1;;-C9);"<=120")
et ça fonctionne
Un grand merci pour votre travail
Re,
Très bien, alors bonne continuation si tout est ok