Signature outlook utilisateur en cours

Bonjour

J'essaye d'adapter ce code qui vient de "Ron de Bruin" et qui permet d'insérer ma signature dans les courriels.

Comment le modifier de sorte que la signature de n'importe quel utilisateur soit insérée dans les courriels. Je travaille sur projet multi utilisateurs.

Je suis en train de convertir mes codes de sorte à pouvoir utiliser le nouveau Outlook.

Merci pour toute aide!

Note : You only have to change the mail address and name of your signature file before you run the code

Sub Mail_Outlook_With_Signature_Html_2()
' Don't forget to copy the function GetBoiler in the module.
' Working in Office 2000-2016
    Dim OutApp As Object
    Dim OutMail As Object
    Dim strbody As String
    Dim SigString As String
    Dim Signature As String

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    strbody = "<H3><B>Dear Customer Ron de Bruin</B></H3>" & _
              "Please visit this website to download the new version.<br>" & _
              "Let me know if you have problems.<br>" & _
              "<A HREF=""/rdb/tips.htm"">Ron's Excel Page</A>" & _
              "<br><br><B>Thank you</B>"

    'Change only Mysig.htm to the name of your signature
    SigString = Environ("appdata") & _
                "\Microsoft\Signatures\Mysig.htm"

    If Dir(SigString) <> "" Then
        Signature = GetBoiler(SigString)
    Else
        Signature = ""
    End If

    On Error Resume Next

    With OutMail
        .To = "ron@debruin.nl"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .HTMLBody = strbody & "<br>" & Signature
        .Send    'or use .Display
    End With

    On Error GoTo 0
    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function GetBoiler(ByVal sFile As String) As String
'Dick Kusleika
    Dim fso As Object
    Dim ts As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(sFile).OpenAsTextStream(1, -2)
    GetBoiler = ts.readall
    ts.Close
End Function

Bonjour,

Vous vous compliquez bien la vie.

D'abord ce code ne fonctionnera pas dans les dernières versions d'Outlook car le compte de messagerie est désormais inclus dans le chemin d'accès aux signatures et de plus l'image de la signature n'y est pas gérée.

Le plus simple est d'utiliser l'action "display" pour ajouter la signature.

Sub Mail_Outlook_With_Signature_Html_2()
' Don't forget to copy the function GetBoiler in the module.
' Working in Office 2000-2016
    Dim OutApp As Object
    Dim OutMail As Object
    Dim strbody As String

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    strbody = "<H3><B>Dear Customer Ron de Bruin</B></H3>" & _
              "Please visit this website to download the new version.<br>" & _
              "Let me know if you have problems.<br>" & _
              "<A HREF=""/rdb/tips.htm"">Ron's Excel Page</A>" & _
              "<br><br><B>Thank you</B>"

    With OutMail
        .To = "ron@debruin.nl"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Display 'ajout signature
        .HTMLBody = strbody & "<br>" & .HTMLBody
        .Send    'or use .Display
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Bonjour

Avec le nouveau Outlook, aussitôt que tu utilises ".Display", l'envoi ne se fait pas. Je dois toujours faire ".Send". Par conséquent, je dois rajouter la signature sans utiliser ".Display".

Merci

Bonjour,

Désolé, je ne comprends pas votre réponse. Bien sûr qu'il faut faire ".Send" pour envoyer le mail et ce, que le ".Display" soit utilisé ou non.

En tout cas, le code que je vous ai communiqué fonctionne parfaitement dans mon Outlook 2021.

Est-ce que tu utilises Outlook16 qui fait partie d'Office 365?

Je n'ai pas Office365 mais la dernière version d'Office, c'est à dire Office 2021. J'utilise bien Outlook 16 qui fait partie d'Office 2021.

Bonsoir

Si tu as l'option d'essayer la nouvelle version d'outlook, active-la et fais les tests.

J'utilise un ordinateur de compagnie.

Merci!