Evaluer une échéance à venir par rapport à aujourd'hui

Bonjour, je suis très heureux de franchir le pas en rejoignant votre communauté :)

Je me heurte à un problème,

considérons une date jj/mm/aaaa en cellule A1,

en B2 j'attends une date jj/mm/aaaa résultat d'une évaluation d 'aujourdhui()' et d 'A1' donnant la prochaine échéance à venir,

dans mon cas sur un cycle de 6 mois et (important) en conservant le numéro du jour...

par exemple A1 12/03/2024 comparé à aujourd'hui (31/07/2024) donnera comme prochaine échéance le 12/09/2024

alors que le 30/07/2024 comparé à aujourd'hui (31/07/2024) donnera comme prochaine échéance le 30/01/2025.

le résultat devant générer une alerte 1 mois avant l'échéance via une MFC (ça je devrais pouvoir le gérer :))

je devine que la formule doit aller au delà du blougiboulga informe de toutes les imbrications de formules dates que j'ai tenté :s

Je vous remercie de l'aide que vous pourrez me donner.

Bonjour

=MOIS.DECALER(A1;6)

Il peut y avoir un décalage si la date est le 31 et que 6 mois après c'est un mois de moins de 30 jours : le 31/08 donne le 28 ou 29/02

Bonjour, j'ai utilisé mois.decaler dans une fonction si par rapport à aujourdhui() et je pense que c'est la clé

mais la difficulté c'est la restitution de la prochaine échéance si par exemple on considère une date comme 02/03/2022 en A1,

il faut arriver à poser le cycle sur plusieurs années pour correctement évaluer.

pour préciser le contexte, c'est faire une alerte pour des rapports de renouvellements, ceux ci se faisant tous les 6 mois à partir de la date en A1.

Bonjour à tous !

Et...

Compte tenu de ma compréhension du besoin, et pour une date initiale en A1, je propose en B2 :

=MOIS.DECALER(A1;(ENT(DATEDIF(A1;AUJOURDHUI();"M")/6)+1)*6)

JFL bonjour,

J'était aussi parti sur cette piste mais ça ne marche pas, je pense qu'il faut une condition et servir de la fonction DATE

ci dessous sur l'hypothèse que aujourdhui() soit la 31/07/24,

A est la date de départ,

B le résultat de la formule et

C le résultat qui devrait apparaitre.

RE

A quoi correspond B ? ce n'est pas 6 mois de A ou de C ...

Chris, c'est le résultat de la formule proposée par JFL donc erroné

je viens d'avancer en reposant le problème ici :

avec cette formule c'est presque bon :

=SI((MOIS(AUJOURDHUI())-MOIS(A1))<=6;DATE(ANNEE(AUJOURDHUI());MOIS(A1)+6;JOUR(A1));DATE(ANNEE(AUJOURDHUI());MOIS(A1)+12;JOUR(A1)))

Bonjour à tous de nouveau !

L'application de ma proposition sur vos exemples donne ceci :

RE

Ceci à l'air OK

=LET(x;6;y;{1.2.3.4.5.6.7.8.9.10};d;MOIS.DECALER(A2;x*y);MIN(SI(d<AUJOURDHUI();9^9;d)))

Marche sur 5 ans

bonjour à tous,

un petit complément à la formule de JFL , pour gérer une date de contrat dans le futur.

=SI(A1>=AUJOURDHUI();MOIS.DECALER(A1;6);MOIS.DECALER(A1;(ENT(DATEDIF(A1;AUJOURDHUI();"M")/6)+1)*6))

correction erreur de traduction de la formule d'anglais en français: DATEDIF reste DATEDIF et non DATEDSI

Bonjour

Pour couvrir tous les cas il faut modifier la formule de JFL

=MOIS.DECALER(A5;(ENT(DATEDIF(MIN(A5;AUJOURDHUI());MAX(A5;AUJOURDHUI());"M")/6)+1)*6)

Cela fait 2 formules qui fonctionnent

EDIT : faute de frappe dans la formule de H2So4

Mais même en corrigeant la date du 15/09 ne donne pas le bon résultat

JFL je suis désolé, je vais mettre ça sur les 40° dans le bureau :D ta formule était bonne !

Idem pour Chris !

Merci beaucoup pour votre aide, je vais bien étudier vos approches, merci encore.

Bonjour à tous de nouveau !

Pour le fun, une autre approche qui devrait retourner la date évènementielle pour tous les contrats (anciens et futurs) :

=LET(l;MOIS.DECALER(A1;SEQUENCE(99;;6;6));PRENDRE(FILTRE(l;l>=AUJOURDHUI());1))

Remarque : Ancienneté des contrats : 99 ans. Est-ce suffisant....?

JFL tu m'ouvres un nouveau champs d'expérimentations :D

Bonjour à tous !

Fredopoulos a écrit :

JFL tu m'ouvres un nouveau champs d'expérimentations :D

Alors..... bonnes explorations !