Comment convertir une adresse postale en coordonnées GPS sur Excel

Bonjour à tous je viens de passer des heures à suivre des tutoriels pour allez recuperer sur API des latitudes longitudes versus des adresses. Je n'y arrive pas. une ame charitable pour m'aider svp ?

Lionel

Bonjour,

ci-dessous une fonction le permettant avec éléments de l'adresse à séparer par des espaces ou des "+'".

NB: ajouter dans l'éditeur VBA la référence Microsoft XML

Function Adresse_GPS(adresse As String) As String
    '// ajouter la référence  Microsoft XML v6.0

    Dim url As String
    Dim temps_début As Long
    Dim doc_xml As DOMDocument60
    Const doc_loading As Integer = 1, doc_loaded As Integer = 2, doc_interactive As Integer = 3, doc_completed As Integer = 4
    Dim coordonnées As IXMLDOMNode

    '//URL API
    adresse = Replace(Trim(adresse), " ", "+")
    adresse = Replace(Trim(adresse), ",", "+")
    url = "https://nominatim.openstreetmap.org/search?format=xml" & "&q=" & adresse & "&polygon_kml=1&addressdetails=1"

    '// chargement du document xml à partir de l'url
    Set doc_xml = New DOMDocument60: doc_xml.Load url
    temps_début = Timer
    While doc_xml.readyState <> doc_completed
        DoEvents
        If Timer > temps_début + 30 Then MsgBox "temps de chargement de la page > 30 secondes -- Abandon": Exit Function
    Wend

    '// Récupération coordonnées GPS
    Set coordonnées = doc_xml.SelectSingleNode("/searchresults/place/geokml/Point/coordinates")
    If coordonnées Is Nothing Then MsgBox "coordonnées " & adresse & " non trouvées": Exit Function
    Adresse_GPS = Split(coordonnées.Text, ",")(1) & "," & Split(coordonnées.Text, ",")(0)

End Function

Merci Thev j'ai suivi tous ces tutos mais malehuresment pas de reusltat. Ca me saoule.

Bonjour

Le travail de thev, (salut) appliqué

mais peut de code postal connu...

voir aussi: https://forum.excel-pratique.com/excel/obtenir-latitude-longtiude-a-partir-d-une-adresse-125577

A+ François

re,

modification du fichier de Fanfan du fichier de Thev avec des adresses effectives au lieu des numéros postaux