Recuperer 15 premières lettres

Bonsoir à tous !

un peu novice sur excel, je fais appel à la communauté du forum pour la première fois !

J'ai un fichier excel, avec mes contacts de la manière suivante :

Nom Prénom (des espaces) adresse@mail.com

Tout ça dans les cases de la première colonne, et ce, sur 1600 lignes... autrement dit, j'ai moyennement envie de me taper un copier coller autant de fois pour séparer les nom prénom du mail.

Existe-il une formule permettant de récuperer les 10 ( ou 15 ou autres) premières lettres d'une case, ainsi que les 10 (15 ...) dernières lettres de la case ?

Merci d'avance,

Arthur.

Bonsoir,

Voir du coté des fonctions texte comme GAUCHE()

Hervé.

Bonjour,

La fonction GAUCHE devrait effectivement t'aider.

Toutefois, la longueur nom + prénom est-elle toujours la même ?

Si non, il faut considérer que l'adresse mail est ce qui suit le dernier espace.

Dans ce cas, pour isoler les noms et prénoms, cette formule :

=GAUCHE(A1;TROUVE("µ";SUBSTITUE(A1;" ";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";""))))-1)

et pour isoler l'adresse mail :

=STXT(A1;TROUVE("µ";SUBSTITUE(A1;" ";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";""))))+1;99)

Le principe consiste à repérer le rang du dernier espace grace à la fonction SUBSTITUE.

Si pas ça, reviens avec plus de précisions et un petit bout de fichier exemple (dans lequel tu auras remplacé les données confidentielles par des données bidon)

@+

Merci Messieurs pour ces deux réponses

Malheureusement, je n'ai pas réussis à faire, malgré les nombreuses précisions données, je vous en remercie.

J'ai mis en pièce jointe deux bouts de fichiers.

'exemple-contact', c'est le fichier tel que je l'ai au départ..

'exemple-contact - espace' , le même fichier auquel j'ai simplement effectué un remplacement de tous les ,"", pour plus de clareté.

L'objectif est toujours de séparer nom, prénom et mail dans trois cases différentes.

Merci d'avance pour le temps passé sur mon cas !

re,

Sur la base du fichier avec espaces :

=GAUCHE(SUPPRESPACE(A2);TROUVE("µ";SUBSTITUE(SUPPRESPACE(A2);" ";"µ";NBCAR(SUPPRESPACE(A2))-NBCAR(SUBSTITUE(SUPPRESPACE(A2);" ";""))))-1)

et

=STXT(SUPPRESPACE(A2);TROUVE("µ";SUBSTITUE(SUPPRESPACE(A2);" ";"µ";NBCAR(SUPPRESPACE(A2))-NBCAR(SUBSTITUE(SUPPRESPACE(A2);" ";""))))+1;99)

La fonction SUPPRESPACE permet de supprimer les espaces de début ou de fin de chaine ainsi que les doubles (ou plus) espaces.

@+

Bonjour,

Cela fonctionne parfaitement bien,je te remercie vraiment !!! C'est assez incroyable comme formule, du moins pour un novice =)

Je ne pensais pas avoir une réponse au problème aussi rapidement, je suis vraiment satisfait ! Merci au forum et surtout à thibo !

à très bientôt.

Arthur