Probleme de plusieurs macro avec la formule MAINTENANT

Bonsoir à tous,

je voudrais créer un tableau de suivi d'intervention de plusieurs équipes et pour se faire, j'ai créé des boutons à l'aide de FORME auxquels j'affecte une macro qui me permet d'écrire l'heure de départ du véhicule sur sa ligne correspondante.

Mon problème avec cette méthode, des que j'appuie sur n'importe quels boutons , il m'inscrit l'heure sur toutes les équipes or je voudrais que le bouton heure équipe 1 écrit seulement sur la ligne de l'équipe 1 et bouton équipe 2 écrit sur la case de l'équipe 2 ainsi de suite.

je vous transmet mon fichier pour que cela soit claire

Merci d'avance pour votre aide

Bonsoir,

première chose si vous mettez "=Now()" dans les cellules, vous mettez en place une formule dynamique qui sera alors mise à jour à chaque recalcul de la feuille ou du classeur ! Donc oui en cliquant sur n'importe quel bouton, vous allez inscrire une donnée dans une cellule ce qui va lancer le "Calculate" de la feuille et tous les "Now()" se mettrons à jour avec la date et l'heure actuelle !

Si vous voulez que votre code VBA inscrive une heure dans la cellule, ce n'est pas une formule qu'il faut mais une donnée :
Au lieu de : ActiveCell.FormulaR1C1 = "=NOW()"
écrire : ActiveCell.Value = Now

Deuxième chose il vous faut "mutualiser les codes afin de ne pas les multiplier, vous pouvez faire ceci soit en fonction de la ligne où se trouve le bouton cliqué, soit en utilisant son nom...

Ensuite pourquoi autant de ligne pour chaque équipe ? Il vous faut faire le ménage là dedans, pour la mise en forme si une ligne est trop étroite alors il vous suffit de l'agrandir ! Il en est évidemment de même avec les colonnes !

@ bientôt

LouReeD

Voilà deux propositions sur un seul fichier :

La première avec les boutons de couleur : On détecte le numéro de ligne du bouton cliqué ce qui permet en fonction de celui-ci d'inscrire l'info dans la bonne cellule ou bien les effacer.

La deuxième avec les boutons violet : vous sélectionnez la ligne à modifier en activant une de ses cellules, puis vous cliquez sur l'un des boutons.

Les codes des différents boutons :

Sub LRD_AffHeure()
    ActiveSheet.Cells(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Row, 3) = Now
End Sub

Sub LRD_EffHeure()
    ActiveSheet.Cells(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Row, 3).Resize(, 3) = ""
End Sub

Sub LRD_ProDepart()
    ActiveSheet.Cells(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Row, 4) = "Prochain départ"
End Sub

Sub LRD_AffHeure_U()
    ActiveSheet.Cells(ActiveCell.Row, 3) = Now
End Sub

Sub LRD_EffHeure_U()
    ActiveSheet.Cells(ActiveCell.Row, 3).Resize(, 3) = ""
End Sub

Sub LRD_ProDepart_U()
    ActiveSheet.Cells(ActiveCell.Row, 4) = "Prochain départ"
End Sub

Le fichier :

@ bientôt

LouReeD

Merci beaucoup LouReeD d'avoir pris le temps de lire et de répondre à mon problème.

J'ai mis autant de ligne car normalement car elles contiennent des numéros de téléphone et autre indicatif de véhicule que je n'ai pas mis sur mon exemple pour cause de confidentialité.

en tout cas merci beaucoup de votre réponse car je pense que je n'aurais pas du tout penser à cette solution.

Bonsoir,

Ensuite pour plusieurs numéro sur une même cellule et ce "facilement" vous pouvez utiliser [Alt] + [Entrée] afin de faire un retour à la ligne forcé du texte de la cellule.

Merci de votre retour et remerciement.

@ bientôt

LouReeD