Calculer du nombre de jours d'absence consécutifs

Bonjour

On m'a posé une colle sur Excel 365 : Existe-t-il une formule pour calculer le nombre de jours d'absence consécutifs sur un planning ? Et question subsidiaire : déduction faite des week-ends...

Je vous remercie par avance de votre aide.

Cordialement

Salut,

comment se présente ce planning et comment sont indiqués les jours d'absence ?

Les week-ends sont indiqués mais on doit en faire abstraction ?

Les jours, week-end compris, sont en colonnes, les noms des personnes en ligne.

On souhaite calculer le nombre de jours consécutifs d'absence au travail, donc hors week-end.

Merci

Ok, mais comment sont indiqués les jours d'absence ? Le nom de la personne est simplement absent de la liste ? Et c'est un nom par cellule et un par colonne (chaque employé a sa colonne) ?

Les personnes figurent toutes systématiquement dans le planning. On indique les incidences à enregistrer avec différents codes en fonction de la nature de l'absence. En l'occurrence ici : MAL.

Cette matricielle m'a l'air de fonctionner ;

=MAX(FREQUENCE(SI(((F32:N32<>"sam")*(F32:N32<>"dim")*(F34:N34="MAL"))*COLONNE(F34:N34)<>0;COLONNE(F34:N34));SI(((F32:N32<>"sam")*(F32:N32<>"dim")*(F34:N34<>"MAL"))*COLONNE(F34:N34)<>0;COLONNE(F34:N34))))

Ligne 32 = les jours

Ligne 34 = le statut, en l'occurrence on cherche MAL.

Pour mon exemple je n'ai rien mis à la ligne 34 pour mardi (donc la personne n'était pas malade mardi) et j'ai rajouté un lundi 9 après le dimanche 8, ce qui fait que la formule renvoie 4 (6 jours de MAL sans tenir compte des sam et dim).

Bonjour à tous !

Pourquoi ne pas joindre un classeur représentatif à votre demande ?

Avec Microsoft 365, les fonctions utilisables facilitent grandement la chose.

Je te remercie.

Je transmets à ma collègue pour qu'elle transpose et teste.

Bonjour JFL

Voilà le fichier transmis, j'hésitais à le joindre.

Merci

Ah oui mais ça c'est différent, les cellules de jours contiennent en réalité des dates avec un format personnalisé qui n'affiche que le jour, donc ma formule ne marche pas. Elle marcherait s'il était bien mis lun, mar, ...

De plus, ce genre de tableau serait plus simple à manipuler si les jours étaient en lignes au lieu de colonnes.

Ceci fonctionne, à mettre en NC4, à condition d'écrire MAL en NC1 ;

=MAX(FREQUENCE(SI(((TEXTE($B$2:$NB$2;"jjjj")<>"samedi")*(TEXTE($B$2:$NB$2;"jjjj")<>"dimanche")*($B4:$NB4=NC$1))*COLONNE($B4:$NB4)<>0;COLONNE($B4:$NB4));SI(((TEXTE($B$2:$NB$2;"jjjj")<>"samedi")*(TEXTE($B$2:$NB$2;"jjjj")<>"dimanche")*($B4:$NB4<>NC$1))*COLONNE($B4:$NB4)<>0;COLONNE($B4:$NB4))))

A sauver en mode matriciel.

Vous pouvez faire une colonne de total par catégorie (MAL, RTT, ...), il suffit d'écrire à droite de MAL les autres intitulés et d'étirer la formule vers la droite et jusqu'à la ligne 29.

Détail de la fin ;

Vous pouvez bien sûr écrire MAL en NC3 au lieu de NC1 et remplacer NC$1 par NC$3 dans la formule.

Je rappelle que c'est le MAX de jours consécutifs (moins les week-ends), pas le total de chaque catégorie.

Bonsoir à tous !

Pour un code absence porté en NC1 (voir liste de validation), la formule suivante devrait vous retourner le résultat attendu :

=LET(d; $B$2:$NB$2; NB(FILTRE(d; ($B4:$NB4 = $NC$1) * (JOURSEM(d; 2) < 6); "")))

Merci à tous les 2. Je transmets et vous dirai en retour ce que ma collègue en aura retenu.

Bonjour,
Merci pour les éléments de réponse, @Doux rêveur j'aimerais rajouter une subtilité à ma demande. Si je considère que la notion de consécutive est égale à 5 jours, est-il possible de connaitre pour le collaborateur "A" le nombre de fois où il a été absent 5 jours consécutifs pour MAL dans l'année?

La collègue de hatusu :)

Bonjour la collègue de hatusu

Est-ce que ces 5 jours peuvent être à cheval sur 2 semaines, donc par exemple du mercredi au mardi (ce qui fait 7 jours moins les 2 du w-e) ou pas ?

Si oui, on utilise la même formule qu'au-dessus sauf qu'au lieu de choisir la valeur MAX, on va voir combien il y a de 5 dedans.

A mettre en NE4 et étirer vers le bas ;

=SOMMEPROD((FREQUENCE(SI(((TEXTE($B$2:$NB$2;"jjjj")<>"samedi")*(TEXTE($B$2:$NB$2;"jjjj")<>"dimanche")*($B4:$NB4=NC$1))*COLONNE($B4:$NB4)<>0;COLONNE($B4:$NB4));SI(((TEXTE($B$2:$NB$2;"jjjj")<>"samedi")*(TEXTE($B$2:$NB$2;"jjjj")<>"dimanche")*($B4:$NB4<>NC$1))*COLONNE($B4:$NB4)<>0;COLONNE($B4:$NB4)))=5)*1)

Renvoie 1 pour les lignes 11 et 22 et renvoie 0 pour les autres.

On peut bien sûr mettre 5 en haut de la colonne, par exemple en NE1 et mettre NE$1 au lieu de 5 dans la formule.

Bonjour à tous !

Houlà....

Ma perception du besoin était fort différente.....

Question : Pour une absence (MAL) de 2 semaines complètes consécutives, le résultat attendu est 2 (car deux fois cinq jours) ?

@JFL, hahaa merci quand même. L'idéal serait de compter 1 seule fois la MAL si elle est sur 2 semaines consécutives en incluant le WE.

@Doux Rêveur, les 5 jours jours peuvent effectivement être à cheval sur 2 semaines. J'ai bien appliqué la formule SOMMEPROD mais le résultat n'est pas au rendez vous.
Le salarié A est absent 2 semaines consécutives en juillet, pourquoi le résultat n'est pas de 1?

Parce que ça compte pour 10 jours consécutifs, puisqu'au départ tu demandais de déduire les w-e et donc de considérer que le lundi est consécutif au vendredi.

Mais il est vrai que dans ce cas les 2 jours du w-e ne sont pas remplis et donc il faut considérer que ce sont 2 périodes de 5 jours, alors il faut une autre formule.

Je comprends mieux.

Merci beaucoup pour votre aide.

Bon weekend

Merci.

Faire abstraction des w-e tout en tenant compte du fait qu'ils puissent être remplis ou non me paraît difficile, mais il y a peut-être moyen.

En attendant on peut faire une formule plus simple qui n'exclut pas les w-e et va donc compter les jours consécutifs, mais alors on aura 12 au lieu de 10 si qqn part du lundi au vendredi suivant (7 + 5). Et ensuite on peut toujours en déduire les w-e.