Mon tableau, Réducteur

Je recherche à extraire du tableau A dans le tableau B,

Les trios qui ont au moins un des numéros dans la Base,

Tout en faisant en sorte que ces numéros (O5 a S5) soient interchangeables

Et idem pour les NP et principalement en AE5, interchangeables aussi

Le chiffre dans K2 CHANGE AUSSI, de 18 il peut descendre à 12 etc.

Je vous remercie d’avance, MERCI, mes salutations

Salut,

je te propose de rajouter ceci en A10 pour indiquer le nombre de n° (entre B10 et D10) présents dans la base ;

=NB.SI($O$5:$S$5;B10)+NB.SI($O$5:$S$5;C10)+NB.SI($O$5:$S$5;D10)

Et ces matricielles pour M10, N10 et O10 ;

=INDEX($B$10:$B$825;PETITE.VALEUR(SI($A$10:$A$825>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)))

=INDEX($C$10:$C$825;PETITE.VALEUR(SI($A$10:$A$825>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)))

=INDEX($D$10:$D$825;PETITE.VALEUR(SI($A$10:$A$825>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)))

Toutes les 4 à incrémenter (d'abord celle en A10 jusque A825 sinon les autres ne fonctionneront pas).

Bonjour, et merci d'avoir regardé mon fichier réducteur, je viens de faire un test, et soit je n'est pas compris ou pas compris, je vous envoie le fichier avec les formule que vous m'avais donner, si vous pouvez contrôlé, ou j'ai commis une erreur, merci d'avance, encore merci d'avoir regarder mon fichier, mes salutations

pour info, le chiffre dans AE5, et cote etc dois suivre, je ne cherche pas a copie coller le tableau A dans B, merci

Ton fichier fait bien ce que j'avais proposé, il me semblait qu'il fallait copier les lignes du tableau A vers le tableau B si au moins un des 3 numéros est dans la Base, c'est ce que font mes formules.

Quand il y a un 0 dans la colonne A, les chiffres de cette ligne ne sont pas pris en compte et les 3 formules (en M, N et O) vont chercher les 3 chiffres (des colonnes B, C et D) de la prochaine ligne où il y a un chiffre autre que 0 dans la colonne A.

Ce n'est pas ce qu'il fallait faire ?

Bonsoir, et non , les 3 chiffres de la même ligne doit changer avec la cote automatiquement, si exemple le chiffre 7 n'est pas dans la base toute les combinaison en 7 ne vont pas dans le tableau B , la je viens de modifié dans le fichier les bases et le 1 reste en place, qu'il ne doit pas être dans le tableau B , et j'ai modifié le case AE5 et pas bon, pour moi il y as une (blague)(une couille dans le potage) juste pour rire, merci, mes salutations

Désolé mais je ne comprends plus ce qu'il faut faire, essaye de reformuler ça plus clairement en disant ce qu'on doit obtenir dans les colonnes M, N et O selon les cotes.

Donne un exemple de chiffres qui doivent apparaître en M, N et O.

Bonsoir, je viens de mettre des exemple dans le tableau B, je recherche 1 dans la base (ordre ou désordre) et plus petit que la cote, voir fichier normalement vous devriez mieux comprendre, et la ligne complète change avec la cote si pas bon, voir fichier, merci ,mes salutations

Si j'ai bien compris, les formules que j'ai données sont bonnes MAIS il faut rajouter comme critère que le total en J soit inférieur ou égal au contenu de AE5, c'est juste ?

Bonjour, merci encore de suivre mon fichier, normalement les formules sont bonne, il manque juste dans P10, le total qui correspond a chaque ligne, exemple MNO 1.2.14 = 94 (qui ne doit pas être la car supérieur a AE5) une bonne et : 1.12.15 AVEC Total de 48, j'ai mis OK dans le fichier avec des flèches, encore merci pour le suivi de mon fichier, mes salutations

petite chose que j'avais mis dans mon premier message, ne pas oublier K2 le chiffre change aussi merci, mes salutations

Et il faut faire quoi si K2 change ?

En attendant je te propose ces 4 matricielles pour M10, N10, O10 et P10 ;

=SIERREUR(INDEX($B$10:$B$825;PETITE.VALEUR(SI(($A$10:$A$825>0)*($J$10:$J$825<=$AE$5)>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)));"")

=SIERREUR(INDEX($C$10:$C$825;PETITE.VALEUR(SI(($A$10:$A$825>0)*($J$10:$J$825<=$AE$5)>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)));"")

=SIERREUR(INDEX($D$10:$D$825;PETITE.VALEUR(SI(($A$10:$A$825>0)*($J$10:$J$825<=$AE$5)>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)));"")

=SIERREUR(INDEX($J$10:$J$825;PETITE.VALEUR(SI(($A$10:$A$825>0)*($J$10:$J$825<=$AE$5)>0;LIGNE($A$10:$A$825)-(LIGNE($A$10)-1));LIGNE(1:1)));"")

Dans le dernier fichier que tu as transmis, ces formules ne remplissent que 32 lignes (de 10 à 41) puisque seules 32 lignes remplissent les conditions, ensuite ça met du vide pour éviter un message d'erreur.

Bonjour dans K2 actuellement il y as 18 (=18 partants) si je change et passe a 12 (=12 partants) les chiffres au dessus de 12 ne doivent pas venir dans les combinaison du tableau B. je teste les formules et vous tiens au courant dans l’après midi, merci encore pour votre aide, mes salutations

Les chiffres au dessus de 12 de quelles colonnes, A B C ?

Si oui, tu mets ceci en A10 et tu gardes les 4 dernières matricielles que j'ai postées, elles restent bonnes ;

=(NB.SI($O$5:$S$5;B10)+NB.SI($O$5:$S$5;C10)+NB.SI($O$5:$S$5;D10))*SI(NB.SI(B10:D10;">"&$K$2)=0;1;0)

Et bien sûr à incrémenter jusque A825.

Tu changes le chiffre en K2 et tu vois le changement dans le tableau B.

Bonjour, merveilleux les formules impeccables, tout fonctionne, un très très grand MERCI a Doux Rêveur, MERCI MERCI , un vrai pro, de Excel, Doux Rêveur encore MERCI bonne journée a vous, mes salutations

MERCI DOUX RÊVEUR

De rien, content d'avoir pu aider