Prendre la dernière cellule pleine la plus à droite

Bonjour,

J'ai une formule et je ne sais pas comment la modifier pour quel me prenne la dernière cellule pleine.

Actuellement, cette formule me fait un retour d'une colonne "3" ciblé.

=SI(C17="";"";RECHERCHEV(C17;Tableau2;3;FAUX))

Il faudrait je pense ajouter cette formule : =RECHERCHE(9^9;1:1) mais je n'y arrive pas. Tout en sachant que le tableau2 est évolutif au niveau colonne.

Le tableau :

Colonne B : ref client
Colonne C : Désignation
Colonne D : Prix U 1
Colonne E : Prix U 2
Colonne F vide actuellement mais lors d'une revue de prix, celle-ci sera renseignée.

Merci à vous pour votre aide.

Bonjour

Tableau2 est un tableau structuré ? le tableau commence en B et non en A ?

Remplacer 3 par

NBVAL(Tableau2[#En-têtes])

Bonjour et Merci 78Chris,

Sa fonctionne si toute la colonne est renseignée mais pas si la cellule est vide.

Ci dessous des images

Une autres image, se sont 2 onglets différents

RE

J'aurais du comme d'habitude exiger à minima une copie d'écran pour éviter que nous perdions du temps tous 2 !

=INDEX(DECALER(Tableau2[[#En-têtes];[Ref client]];EQUIV(C14;Tableau2[Ref client];0);;;NB.SI(Tableau2[#En-têtes];"<>"));;NB.SI(DECALER(Tableau2[[#En-têtes];[Ref client]];EQUIV(C14;Tableau2[Ref client];0);;;NBVAL(Tableau2[#En-têtes]));"<>0"))

ou

=INDEX(DECALER(Tableau2[[#En-têtes];[Soumission]];EQUIV(C14;Tableau2[Ref client];0);;;NBVAL(Tableau2[#En-têtes])-2);;EQUIV(9^9;DECALER(Tableau2[[#En-têtes];[Soumission]];EQUIV(C14;Tableau2[Ref client];0);;;NBVAL(Tableau2[#En-têtes])-2);1))

Merci beaucoup 78Chris,

Le 2ème solution fonctionne parfaitement.

Bonne fin de journée.

RE

les deux fonctionnent, normalement

La 1ere formule se réfère dans tous les cas a la dernière colonne sans tenir compte si elle est pleine ou vide je pense.

RE

Non mais effectivement le résultat n'est pas toujours le même.

Pour info avec 2021 ou 365

=LET(cl;FILTRE(Tableau2;Tableau2[Ref client]=C14);px;FILTRE(cl;cl<>0);INDEX(px;;NBVAL(px)))

Merci à vous 78chris.

Une 3ème formule selon les cas. Je sens un passionné et j'aime.

Si vous voulez me former, je suis dispo !

Je vous souhaite tout de bon.
Un grand merci.