Incrémenter une série de trimestres Excel
Pour la création d'un fichier de reporting de projet, je cherche à créer une série de trimestres à partir d'une date de démarrage.
On entre la date de démarrage du projet en C4 sous le format jj/mm/aaaa
Je voudrais en F5 une formule qui me permet d'obtenir le prochain trimestre auquel reporter, sous le format QX-AAAA. Par ex, si la date de démarrage est le 02/08/2024, alors la première date de trimestre à laquelle reporter est le 30/09/2024, à faire apparaitre sous le format Q3-2024.
Je voudrais ensuite incrémenter une suite de trimestres en ligne à partir de F5 en G5, H5, I5, etc., qui dans ce cas seraient Q4-2024, Q1-2025, Q2-2025, etc.
Cela fonctionne très bien avec des mois avec la fonction MOIS.DECALER, mais je ne trouve pas d'équivalent pour les trimestres.
Est-ce que quelqu'un a une formule magique?
Merci !
Bonjour,
Si la date est en A5:
Formule en F5:
="Q" & SI(CHOISIR(MOIS($A5);1;1;1;2;2;2;3;3;3;4;4;4)=4; "1-" & ANNEE($A5)+1;CHOISIR(MOIS($A5);1;1;1;2;2;2;3;3;3;4;4;4)&"-"& ANNEE($A5))Puis en G5 et à tirer sur la droite:
="Q" & SI(STXT(F5;2;1)="4";"1-"& DROITE(F5;4)*1+1;STXT(F5;2;1)*1+1 &"-" & DROITE(F5;4))Cdlt
Bonjour @Arturo83
Merci beaucoup c'est presque parfait, mais si j'entre une date comprise entre le 01/10/2023 et le 31/12/2023 en A5, le premier trimestre renvoyé est Q1 2024 alors que ça devrait être Q4 2023.
Que faut-il changer pour que cela fonctionne ?
Bonjour à tous,
Un essai avec d'autres formules
En D5, la date de départ
En E5, une formule unique : ="Q"&ARRONDI.SUP((MOIS(D5))/3;0)&"-"&ANNEE(D5)
En F5 une formule à recopier vers la droite :
="Q"&ARRONDI.SUP((MOIS(DATE(DROITE(E5;4);3*STXT(E5;2;1)+4;0)))/3;0)&"-"&ANNEE(DATE(DROITE(E5;4);3*STXT(E5;2;1)+4;0))
.
Re,
Avec O365, un LET permet de raccourcir l’écriture de la formule n° 2 en F5 (à recopier vers la droite) :
=LET(xx;DATE(DROITE(E5;4);3*STXT(E5;2;1)+4;0);"Q"&ARRONDI.SUP((MOIS(xx))/3;0)&"-"&ANNEE(xx))
...
Merci beaucoup c'est presque parfait, mais si j'entre une date comprise entre le 01/10/2023 et le 31/12/2023 en A5, le premier trimestre renvoyé est Q1 2024 alors que ça devrait être Q4 2023.
Ah, ok, j'ai cru que la valeur en F5 devait indiquer le prochain trimestre, donc voici la formule corrigée en F5:
="Q"&CHOISIR(MOIS($A5);1;1;1;2;2;2;3;3;3;4;4;4)&"-"&ANNEE($A5)Les autres restent inchangées
ou avec une formule unique qui condense les 2 précédentes:
="Q"&SI(COLONNE()=6;CHOISIR(MOIS($A5);1;1;1;2;2;2;3;3;3;4;4;4)&"-"&ANNEE($A5);SI(STXT(E5;2;1)="4";"1-"&DROITE(E5;4)*1+1;STXT(E5;2;1)*1+1&"-"&DROITE(E5;4)))Cdlt
Merci à tous c'est parfait cela fonctionne très bien !